Initial commit

Signed-off-by: ObserverOfTime <chronobserver@disroot.org>
This commit is contained in:
Observer of Time 2020-05-05 15:21:46 +03:00
commit 5f22da4b60
Signed by: chronobserver
GPG Key ID: 8A2DEA1DBAEBCA9E
2 changed files with 50 additions and 0 deletions

19
.SRCINFO Normal file
View File

@ -0,0 +1,19 @@
pkgbase = owo-cli-git
pkgdesc = A bash based file uploader and URL shortener for owo.whats-th.is (git version)
pkgver = 2.0.0+r286.gcf06572
pkgrel = 1
url = https://whats-th.is
arch = any
license = GPL3
makedepends = awk
makedepends = git
depends = curl
depends = grep
depends = awk
provides = owo-cli=2.0.0
conflicts = owo-cli
source = git+https://owo.codes/whats-this/owo.sh.git#branch=posixly-correct
sha256sums = SKIP
pkgname = owo-cli-git

31
PKGBUILD Normal file
View File

@ -0,0 +1,31 @@
# Maintainer: ObserverOfTime <chronobserver@disroot.org>
pkgname=owo-cli-git
pkgver=2.0.0+r286.gcf06572
pkgrel=1
pkgdesc="A bash based file uploader and URL shortener for owo.whats-th.is (git version)"
arch=('any')
url="https://whats-th.is"
license=('GPL3')
depends=('curl' 'grep' 'awk')
makedepends=('awk' 'git')
conflicts=('owo-cli')
provides=("owo-cli=${pkgver%+r*}")
source=('git+https://owo.codes/whats-this/owo.sh.git#branch=posixly-correct')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/owo.sh"
printf '%s+r%s.g%s' \
"$(awk -F\" '/^VERSION=/{print $2}' bin/owo)" \
"$(git rev-list --count HEAD)" \
"$(git rev-parse --short HEAD)"
}
package() {
cd "$srcdir/owo.sh"
install -Dm755 bin/owo "${pkgdir}/usr/bin/owo"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/owo-cli/LICENSE"
install -Dm644 README.adoc "${pkgdir}/usr/share/doc/owo-cli/README.adoc"
install -Dm644 share/man/man1/owo.1 "${pkgdir}/usr/share/man/man1/owo.1"
}