guix
/
guix
mirror of git://git.savannah.gnu.org/guix.git
3
4
Fork 0
Code Issues Releases Wiki Activity

build-system: Add renpy-build-system. 

* guix/build/renpy-build-system.scm: New file.
* guix/build-system/renpy.scm: New file.
* Makefile.am (MODULES): Add them here.
* doc/guix.texi (Build Systems): Document renpy-build-system.
This commit is contained in:
Leo Prikler 2021-01-24 11:47:15 +01:00
parent 4db5addbdd
commit e1bdab4f0f
No known key found for this signature in database
GPG Key ID: 442A84B8C70E2F87
4 changed files with 245 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

2
Makefile.am
View File

@ -150,6 +150,7 @@ MODULES = \
guix/build-system/node.scm \
guix/build-system/perl.scm \
guix/build-system/python.scm \
guix/build-system/renpy.scm \
guix/build-system/ocaml.scm \
guix/build-system/qt.scm \
guix/build-system/waf.scm \
@ -205,6 +206,7 @@ MODULES = \
guix/build/ocaml-build-system.scm \
guix/build/qt-build-system.scm \
guix/build/r-build-system.scm \
guix/build/renpy-build-system.scm \
guix/build/rakudo-build-system.scm \
guix/build/ruby-build-system.scm \
guix/build/scons-build-system.scm \

13
doc/guix.texi
View File

@ -7880,6 +7880,19 @@ passes flags specified by the @code{#:make-maker-flags} or
Which Perl package is used can be specified with @code{#:perl}.
@end defvr
@defvr {Scheme Variable} renpy-build-system
This variable is exported by @code{(guix build-system renpy)}. It implements
the more or less standard build procedure used by Ren'py games, which consists
of loading @code{#:game} once, thereby creating bytecode for it.
It further creates a wrapper script in @code{bin/} and a desktop entry in
@code{share/applications}, both of which can be used to launch the game.
Which Ren'py package is used can be specified with @code{#:renpy}.
Games can also be installed in outputs other than ``out'' by using
@code{#:output}.
@end defvr
@defvr {Scheme Variable} qt-build-system
This variable is exported by @code{(guix build-system qt)}. It
is intended for use with applications using Qt or KDE.

131
guix/build-system/renpy.scm Normal file
View File

@ -0,0 +1,131 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2021 Leo Prikler <leo.prikler@student.tugraz.at>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build-system renpy)
#:use-module (guix store)
#:use-module (guix utils)
#:use-module (guix memoization)
#:use-module (guix packages)
#:use-module (guix derivations)
#:use-module (guix search-paths)
#:use-module (guix build-system)
#:use-module (guix build-system gnu)
#:use-module (ice-9 match)
#:use-module (srfi srfi-1)
#:use-module (srfi srfi-26)
#:export (%renpy-build-system-modules
default-renpy
renpy-build
renpy-build-system))
(define (default-renpy)
"Return the default Ren'py package."
;; Lazily resolve the binding to avoid a circular dependency.
(let ((module (resolve-interface '(gnu packages game-development))))
(module-ref module 'renpy)))
(define %renpy-build-system-modules
;; Build-side modules imported by default.
`((guix build renpy-build-system)
(guix build json)
(guix build python-build-system)
,@%gnu-build-system-modules))
(define* (lower name
#:key source inputs native-inputs outputs system target
(renpy (default-renpy))
#:allow-other-keys
#:rest arguments)
"Return a bag for NAME."
(define private-keywords
'(#:source #:target #:renpy #:inputs #:native-inputs))
(and (not target) ;XXX: no cross-compilation
(bag
(name name)
(system system)
(host-inputs `(,@(if source
`(("source" ,source))
'())
,@inputs
;; Keep the standard inputs of 'gnu-build-system'.
,@(standard-packages)))
(build-inputs `(("renpy" ,renpy)
,@native-inputs))
(outputs outputs)
(build renpy-build)
(arguments (strip-keyword-arguments private-keywords arguments)))))
(define* (renpy-build store name inputs
#:key
(phases '(@ (guix build renpy-build-system)
%standard-phases))
(configure-flags ''())
(outputs '("out"))
(output "out")
(game "game")
(search-paths '())
(system (%current-system))
(guile #f)
(imported-modules %renpy-build-system-modules)
(modules '((guix build renpy-build-system)
(guix build utils))))
"Build SOURCE using RENPY, and with INPUTS."
(define builder
`(begin
(use-modules ,@modules)
(renpy-build #:name ,name
#:source ,(match (assoc-ref inputs "source")
(((? derivation? source))
(derivation->output-path source))
((source)
source)
(source
source))
#:configure-flags ,configure-flags
#:system ,system
#:phases ,phases
#:outputs %outputs
#:output ,output
#:game ,game
#:search-paths ',(map search-path-specification->sexp
search-paths)
#:inputs %build-inputs)))
(define guile-for-build
(match guile
((? package?)
(package-derivation store guile system #:graft? #f))
(#f ; the default
(let* ((distro (resolve-interface '(gnu packages commencement)))
(guile (module-ref distro 'guile-final)))
(package-derivation store guile system #:graft? #f)))))
(build-expression->derivation store name builder
#:inputs inputs
#:system system
#:modules imported-modules
#:outputs outputs
#:guile-for-build guile-for-build))
(define renpy-build-system
(build-system
(name 'renpy)
(description "The Ren'py build system")
(lower lower)))

99
guix/build/renpy-build-system.scm Normal file
View File

@ -0,0 +1,99 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2021 Leo Prikler <leo.prikler@student.tugraz.at>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (guix build renpy-build-system)
#:use-module ((guix build gnu-build-system) #:prefix gnu:)
#:use-module ((guix build python-build-system) #:prefix python:)
#:use-module (guix build json)
#:use-module (guix build utils)
#:use-module (ice-9 match)
#:use-module (ice-9 ftw)
#:use-module (srfi srfi-1)
#:use-module (srfi srfi-26)
#:export (%standard-phases
renpy-build))
(define* (build #:key game #:allow-other-keys)
(for-each make-file-writable
(find-files game (lambda (pred stat)
(eq? (stat:type stat) 'directory))))
(invoke "renpy"
"--json-dump" (string-append game "/renpy-build.json")
game
;; should be "compile", but renpy wants to compile itself really
;; badly if we do
"quit")
#t)
(define* (install #:key outputs game (output "out") #:allow-other-keys)
(let* ((out (assoc-ref outputs output))
(json-dump (call-with-input-file (string-append game
"/renpy-build.json")
read-json))
(build (assoc-ref json-dump "build"))
(executable-name (assoc-ref build "executable_name"))
(directory-name (assoc-ref build "directory_name")))
(let ((launcher (string-append out "/bin/" executable-name))
(data (string-append out "/share/renpy/" directory-name)))
(mkdir-p (string-append out "/bin"))
(copy-recursively game data)
;; We don't actually want the metadata to be dumped in the output
;; directory
(delete-file (string-append data "/renpy-build.json"))
(call-with-output-file launcher
(lambda (port)
(format port "#!~a~%~a ~a \"$@\""
(which "bash")
(which "renpy")
data)))
(chmod launcher #o755)))
#t)
(define* (install-desktop-file #:key outputs game (output "out")
#:allow-other-keys)
(let* ((out (assoc-ref outputs output))
(json-dump (call-with-input-file (string-append game
"/renpy-build.json")
read-json))
(build (assoc-ref json-dump "build"))
(directory-name (assoc-ref build "directory_name"))
(executable-name (assoc-ref build "executable_name")))
(make-desktop-entry-file
(string-append out "/share/applications/" executable-name ".desktop")
#:name (assoc-ref json-dump "name")
#:generic-name (assoc-ref build "display_name")
#:exec (string-append (which "renpy") " "
out "/share/renpy/" directory-name)
#:categories '("Game" "Visual Novel")))
#t)
(define %standard-phases
(modify-phases gnu:%standard-phases
(add-after 'unpack 'enable-bytecode-determinism
(assoc-ref python:%standard-phases 'enable-bytecode-determinism))
(delete 'bootstrap)
(delete 'configure)
(replace 'build build)
(delete 'check)
(replace 'install install)
(add-after 'install 'install-desktop-file install-desktop-file)))
(define* (renpy-build #:key inputs (phases %standard-phases)
#:allow-other-keys #:rest args)
"Build the given Ren'py package, applying all of PHASES in order."
(apply gnu:gnu-build #:inputs inputs #:phases phases args))