#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcomm/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=inxi-git
pkgver=3.3.34.r0.gc23f35b8
pkgrel=02
pkgdesc="Full featured CLI system information tool"
url="https://smxi.org/docs/inxi.htm"
depends=(coreutils pciutils perl procps-ng util-linux net-tools)
makedepends=(git)
conflicts=(inxi)
optdepends=(
      "bind: -i wlan IP"
      "binutils: strings: -I sysvinit version"
      "bluez-tools: bt-adapter: -E bluetooth data (if no hciconfig)"
      "bluez-utils-compat: hciconfig: -E bluetooth HCI data"
      "curl: -i (if no dig); -w,-W; -U"
      "dmidecode: inxi -M if no sys machine data"
      'doas: -Dx hddtemp-user; -o file-user (alt for sudo)'
      "file: inxi -o unmounted file system"
      "freeipmi: ipmi-sensors: -s IPMI sensors"
      "hddtemp: inxi -Dx show hdd temp"
      "iproute2: inxi -i ip lan"
      "kmod: modinfo: Ax; -Nx module version"
      "ipmitool: -s IPMI sensors"
      "lvm2: lvs: -L LVM data"
      "kmod: inxi -Ax,-Nx module version"
      "lm_sensors: inxi -s sensors output"
      "mdadm: -Ra advanced mdraid data"
      "mesa-utils: inxi -G glx info"
      "perl-io-socket-ssl: -U; -w,-W; -i (if dig not installed)"
      "perl-cpanel-json-xs: --output json - required for export"
      "perl-json-xs: JSON::XS: --output json (legacy)"
      "perl-xml-dumper: --output xml - Crude and raw"
      "sudo: inxi -Dx hddtemp-user;-o file-user"
      "tree: --debugger 20,21 /sys tree"
      "upower: -sx attached device battery info"
      "usbutils: inxi -A usb audio;-N usb networking"
      "wget: -i (if no dig); -w,-W; -U"
      "wmctrl: -S active window manager (not all wm)"
      "xorg-xdpyinfo: inxi -G multi screen resolution"
      "xorg-xdriinfo: xdriinfo: -G (X) DRI driver (if missing, fallback to Xorg log)"
      "xorg-xprop: inxi -S desktop data"
      "xorg-xrandr: inxi -G single screen resolution"
)
#source=("git+https://github.com/smxi/inxi.git")
source=("git+https://codeberg.org/smxi/inxi.git")

pkgver() {
  cd "$srcdir/${pkgname/-git/}"
  git describe --long --tags | sed 's/1-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

package() {
	cd "$srcdir/${pkgname/-git/}"

	install -Dm755 "${pkgname/-git/}"   "${pkgdir}/usr/bin/${pkgname/-git/}"
	install -Dm644 "${pkgname/-git/}.1" "${pkgdir}/usr/share/man/man1/${pkgname/-git/}.1"
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=(GPL3)

sha256sums=(SKIP)

##  cb44c691c35845e89f23fbaabf74efe75f73191dd9674af5258d0418161d07c3  inxi-git-3.3.34.r0.gc23f35b8-02-x86_64.pkg.tar.lz