#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=btrfs-progs
pkgver=6.6.3
pkgrel=01
pkgdesc='Btrfs filesystem utilities w/o systemd'
makedepends=('asciidoc' 'xmlto' 'python' 'python-setuptools' 'e2fsprogs'
	'reiserfsprogs' 'python-sphinx' 'python-sphinx_rtd_theme')
depends=('glibc' 'util-linux-libs' 'lzo' 'zlib' 'zstd' 'libgcrypt')
optdepends=('python: libbtrfsutil python bindings'
            'e2fsprogs: btrfs-convert'
            'reiserfsprogs: btrfs-convert')
#url='https://btrfs.wiki.kernel.org'
url='https://btrfs.readthedocs.io'
replaces=('btrfs-progs-unstable')
conflicts=('btrfs-progs-unstable')
provides=('btrfs-progs-unstable')
#options=(!staticlibs debug)  ## uncomment this to have the debug pkg produced
options=(!staticlibs)
source=("https://www.kernel.org/pub/linux/kernel/people/kdave/btrfs-progs/btrfs-progs-v$pkgver.tar."{xz,sign}
        'initcpio-install-btrfs'
        'initcpio-hook-btrfs')
install=btrfs-progs.install

prepare() {
  cd $pkgname-v$pkgver
  # apply patch from the source array (should be a pacman feature)
  local src
  for src in "${source[@]}"; do
    src="${src%%::*}"
    src="${src##*/}"
    [[ $src = *.patch ]] || continue
    echo "Applying patch $src..."
    patch -Np1 < "../$src"
  done
}

build() {
  cd $pkgname-v$pkgver
  ./configure --prefix=/usr --with-crypto=libgcrypt
  make
}

check() {
  cd $pkgname-v$pkgver
 ./btrfs filesystem show
}

package() {
  cd $pkgname-v$pkgver
  make DESTDIR="$pkgdir" install install_python

  # install bash completion (FS#44618)
  install -Dm644 btrfs-completion "$pkgdir/usr/share/bash-completion/completions/btrfs"

  # install mkinitcpio hooks
  cd "$srcdir"
  install -Dm644 initcpio-install-btrfs "$pkgdir/usr/lib/initcpio/install/btrfs"
  install -Dm644 initcpio-hook-btrfs "$pkgdir/usr/lib/initcpio/hooks/btrfs"
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('GPL-2.0-only')

validpgpkeys=('F2B41200C54EFB30380C1756C565D5F9D76D583B')

sha256sums=(f41ce53f6673ff551ee4a3fe7dc9601e5a0dde6b6d09177d1fab62718abc6d9a  # btrfs-progs-v6.6.3.tar.xz
	9a813085b7ee30b54ad153907444e8664c04a7bd7046211064a02dea6158f721  # btrfs-progs-v6.6.3.tar.sign
	bbe60b35d1b1e2efc1308a8f54f1fdc6808240a81c5f5b4d75321b7ee86e41f4  # initcpio-install-btrfs
	35efeee8590d6d60c711ae9cdc918e4841ab61d10cb02359e65e36ebff95ffc5) # initcpio-hook-btrfs


##  476df34a943273de682cf27b3843882619497ecfe794c3c761c72693c7f423a4  btrfs-progs-6.6.3-01-x86_64.pkg.tar.lz

