#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/obarun/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------
# Maintainer    : Eric Vidal <eric@obarun.org>

pkgname=66-tools
pkgver=0.0.8.0
pkgrel=07
pkgdesc="small tools and helpers for service scripts execution"
url='https://git.obarun.org/Obarun/66-tools.git'
source=("${pkgname}::git+${url}#tag=v$pkgver")
makedepends=('git' 'skalibs>=2.13.1.1' 'execline>=2.9.3.0' 'oblibs>=0.1.4.0' 'lowdown')
depends=('skalibs>=2.13.1.1' 'execline>=2.9.3.0' 'oblibs>=0.1.4.0')
groups=('s6-suite')

_flags=(
    --bindir=/usr/bin
    --with-lib=/usr/lib/skalibs
    --with-lib=/usr/lib/execline
    --with-lib=/usr/lib/oblibs
    --with-ns-rule=/usr/lib/66/script/ns
    --disable-shared
)

build() {
    cd $pkgname

    ./configure "${_flags[@]}"
    make
}

package() {
    cd $pkgname

    make DESTDIR="$pkgdir" install install-ns-rule

    install -Dm 0644 LICENSE "$pkgdir"/usr/share/licenses/"$pkgname"/LICENSE
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=(ISC)

sha256sums=(SKIP)

##  e293ee65788b417d9f732ada37ba7bacc8624528b24db74936322c1a1352d870  66-tools-0.0.8.0-07-x86_64.pkg.tar.lz
