#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=usbutils
pkgver=017
pkgrel=01
pkgdesc="A collection of USB tools to query connected USB devices w/o systemd"
url="https://git.kernel.org/pub/scm/linux/kernel/git/gregkh/usbutils.git/"
depends=(glibc hwdata)
#makedepends=(git libusb)
makedepends=(libusb)
optdepends=('python: for lsusb.py usage'
            'coreutils: for lsusb.py usage'
	'sh: for usb-devices')
#source=("git+https://git.kernel.org/pub/scm/linux/kernel/git/gregkh/usbutils.git#commit=79b796f9")
source=(https://www.kernel.org/pub/linux/utils/usb/usbutils/$pkgname-$pkgver.tar{.xz,.sign})

prepare() {
#  cd "$pkgname"
  cd $pkgname-$pkgver
  autoreconf -fiv
}

build() {
#  cd "$pkgname"
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
              --datadir=/usr/share/hwdata \
	  --with-systemd=no
  make
}

package() {
  depends+=('libusb-1.0.so' 'libudev.so')
#  cd "$pkgname"
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -vDm 755 usbreset -t "$pkgdir/usr/bin"
  install -vDm 644 NEWS -t "${pkgdir}/usr/share/doc/${pkgname}/"
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('GPL-2.0-only' 'GPLG-2.0-or-later' 'GPL-3.0-only')

validpgpkeys=('647F28654894E3BD457199BE38DBBDC86092693E') # Greg Kroah-Hartman <gregkh@linuxfoundation.org>

sha256sums=(a6a25ffdcf9103e38d7a44732aca17073f4e602b92e4ae55625231a82702e05b  # usbutils-017.tar.xz
	1998221ee194efcf7ffb10e6c9af2ff34335872bfb89f88854f560ecdd8776c3) # usbutils-017.tar.sign

##  b0e8b4e410a2cf689c0bdac93ab7f8a0510855ce0d0fc846abc29a450ac38df7  usbutils-017-01-x86_64.pkg.tar.lz

