#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/skarnet/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=s6-networking
_pkgver=v2.5.1.3
pkgver=2.5.1.3
pkgrel=02
pkgdesc="Small network and client-server tools"
url="http://skarnet.org/software/s6/"
makedepends=(git 'skalibs>=2.13.1.1' 'execline>=2.9.3.0' 's6>=2.11.3.2' 's6-dns>=2.3.5.5' )
depends=('skalibs>=2.13.1.1' 'execline>=2.9.3.0' 's6>=2.11.3.2' 's6-dns>=2.3.5.5' )
optdepends=('libressl: For build a secure communication tools')
groups=(s6-suite)
#_commit=4cf18919482e3495810c8e3693ea368bdc5753a1 # refs/tags/v2.5.1.2
#source=("$pkgname::git+git://git.skarnet.org/s6-networking#commit=$_commit")
source=("$pkgname::git+git://git.skarnet.org/s6-networking#tag=${_pkgver}")

_pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

build() {
  cd ${srcdir}/${pkgname}
  ./configure --prefix=/usr \
              --bindir=/usr/bin \
              --sbindir=/usr/bin \
              --datadir=/etc \
              --disable-shared \
              --with-lib=/usr/lib/skalibs \
              --with-lib=/usr/lib/s6 \
              --with-lib=/usr/lib/s6-dns
  make
}

package() {
  cd ${srcdir}/${pkgname}

  DESTDIR=${pkgdir} make install

  # add doc
  install -dm 0755 $pkgdir/usr/share/doc/$pkgname/
  cp -R doc/* $pkgdir/usr/share/doc/$pkgname/

  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('ISC')

sha256sums=(SKIP)

##  a4088a0e705368bfed8b205fcdba7aa77aad7da777006b0d707e2e399636ba17  s6-networking-2.5.1.3-02-x86_64.pkg.tar.lz
