#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libnl
pkgver=3.9.0
pkgrel=01
pkgdesc='Library for applications dealing with netlink sockets'
url='https://github.com/thom311/libnl/'
depends=('glibc' 'gcc-libs')
#options=('debug') # uncomment this to produce the debug package for libnl
provides=('libnl-3.so' 'libnl-cli-3.so' 'libnl-genl-3.so' 'libnl-idiag-3.so'
          'libnl-nf-3.so' 'libnl-route-3.so' 'libnl-xfrm-3.so')
makedepends=(bison)
backup=(etc/libnl/classid 
	etc/libnl/pktloc)
source=(https://github.com/thom311/libnl/releases/download/libnl${pkgver//./_}/${pkgname}-${pkgver}.tar.gz{,.sig})

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --sbindir=/usr/bin \
    --disable-ipv6 \
    --disable-static
  make
}

check() {
  make -C $pkgname-$pkgver check
}

package() {
  make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=(GPL)

validpgpkeys=('49EA7C670E0850E7419514F629C2366E4DFC5728') # Thomas Haller

sha256sums=(aed507004d728a5cf11eab48ca4bf9e6e1874444e33939b9d3dfed25018ee9bb  # libnl-3.9.0.tar.gz
	673a014ae2405ee7c1877c407c669b35fe36ae56ab0497a2b3443b3e8aa73a59) # libnl-3.9.0.tar.gz.sig

##  6e7c3122b738b5b0befb103849d9444dea824266b9b050f943d01e27d507fac9  libnl-3.9.0-01-x86_64.pkg.tar.lz

