#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun/jobcore/elfutils"
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgbase=elfutils
pkgname=('debuginfod' 'elfutils' 'libelf')
pkgver=0.186
pkgrel=02
pkgdesc='Handle ELF object files and DWARF debugging information'
arch=('x86_64')
url="https://sourceware.org/elfutils/"
makedepends=('bzip2' 'curl' 'gcc-libs' 'libarchive' 'libmicrohttpd' 'sqlite'
'xz' 'zlib' 'zstd' 'gettext' 'autoconf' 'automake')

options=('staticlibs')
source=("https://sourceware.org/${pkgbase}/ftp/${pkgver}/${pkgbase}-${pkgver}.tar.bz2"{,.sig})

prepare() {
  cd "$pkgbase-$pkgver"
  autoreconf -fiv
}

build() {
  cd "$pkgbase-$pkgver"
  CFLAGS+=" -g"  # required for test-suite success
  ./configure --prefix=/usr \
              --sysconfdir=/etc \
              --program-prefix="eu-" \
              --enable-deterministic-archives
  make
}

check() {
  cd "$pkgbase-$pkgver"
  # Some tests fail due to limited capabilities of build chroot
  make check || echo "Known problem: The build environment might lack enough resources."
}

package_libelf() {
  pkgdesc+=" (libraries)"
  depends=('gcc-libs' 'libbz2.so' 'libcurl.so' 'xz' 'zlib' 'zstd')
  # NOTE: the shared objects can not be added to provides as they are not versioned

  cd "$pkgbase-$pkgver"
  make DESTDIR="$pkgdir" install
  # remove files provided by elfutils or debuginfod
  rm -rvf "${pkgdir}"{/etc,/usr/{bin,share}}
  install -vDm 644 {AUTHORS,ChangeLog,NEWS,NOTES,README} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
}

package_elfutils() {
  pkgdesc+=" (utilities)"
  depends=('gcc-libs' 'glibc' "libelf=${pkgver}-${pkgrel}")

  cd "$pkgbase-$pkgver"
  make DESTDIR="$pkgdir" install
  install -vDm 644 {AUTHORS,ChangeLog,NEWS,NOTES,README} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
  # remove files provided by libelf
  rm -rvf "${pkgdir}/usr/"{include,lib}
  # remove files provided by debuginfod
  rm -rvf "${pkgdir}/usr/bin/debuginfod"* \
    "${pkgdir}/usr/share/man/man1/debuginfod"* \
    "${pkgdir}/usr/share/man/man3/debuginfod"* \
    "${pkgdir}/usr/share/man/man8/" \
    "${pkgdir}/etc"
}

package_debuginfod() {
  pkgdesc+=" (debuginfod)"
  depends=('gcc-libs' 'glibc' 'libarchive.so' "libelf=${pkgver}-${pkgrel}"
  'libmicrohttpd.so' 'sqlite')
  optdepends=("elfutils=${pkgver}-${pkgrel}: for translations" )

  cd "$pkgbase-$pkgver"
  make DESTDIR="$pkgdir" install
  install -vDm 644 {AUTHORS,ChangeLog,NEWS,NOTES,README} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
  # remove files provided by libelf
  rm -rvf "${pkgdir}/usr/"{include,lib}
  # remove files provided by elfutils
  rm -rvf "${pkgdir}/usr/bin/eu-"* \
    "${pkgdir}/usr/share/man/man1/eu-"* \
    "${pkgdir}/usr/share/man/man3/elf_"* \
    "${pkgdir}/usr/share/locale"
}


#---- license gpg-key sha512sums ----

license=('LGPL3' 'GPL3')

validpgpkeys=(
  '47CC0331081B8BC6D0FD4DA08370665B57816A6A'  # Mark J. Wielaard <mark@klomp.org>
  'EC3CFE88F6CA0788774F5C1D1AA44BE649DE760A'  # Mark Wielaard <mjw@gnu.org>
)

sha256sums=(7f6fb9149b1673d38d9178a0d3e0fb8a1ec4f53a9f4c2ff89469609879641177 # elfutils-0.186.tar.bz2
	1865a1f8e11ae50d8c3aa130ed5c3d9ca526d78df754d3f04656c372538cc84c) # elfutils-0.186.tar.bz2.sig
