#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libffi
pkgver=3.4.4
pkgrel=01
pkgdesc='Portable foreign programming language function interface library'
arch=('x86_64')
url='https://sourceware.org/libffi/'
depends=('glibc')
checkdepends=('dejagnu')
makedepends=('automake' 'autoconf')
provides=('libffi.so')
#options=(debug)  ## uncomment this to produce the debug pkg
source=(https://github.com/libffi/libffi/releases/download/v${pkgver}/libffi-${pkgver}.tar.gz)

#prepare() {
#  cd $pkgname-$pkgver
#  autoreconf -fiv
#}

build() {
  cd $pkgname-$pkgver
  # remove --disable-exec-static-tramp once ghc and gobject-introspection
  # work fine with it enabled (https://github.com/libffi/libffi/pull/647)
  ./configure \
    --prefix=/usr \
    --disable-static \
    --disable-multi-os-directory \
    --disable-exec-static-tramp \
    --enable-pax_emutramp
  make
}

check() {
  make -C $pkgname-$pkgver check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
  install -Dm 644 README.md -t "$pkgdir"/usr/share/doc/$pkgname
}

#---- license gpg-key sha256sums ----

license=('MIT')

sha256sums=(d66c56ad259a82cf2a9dfc408b32bf5da52371500b84745f7fb8b645712df676) #  libffi-3.4.4.tar.gz


