#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=man-pages
#_commit=324e1d8289644e5159d43a04945df0841c45b966 # 2022-10-09 =  6.00 release
pkgver=6.05.01
_posixver=2017-a
pkgrel=02
pkgdesc="Linux man pages"
url="https://www.kernel.org/doc/man-pages/"
makedepends=('man2html' 'git')
# https://git.kernel.org/pub/scm/docs/man-pages/man-pages.git/
source=(https://www.kernel.org/pub/linux/docs/man-pages/$pkgname-$pkgver.tar.{xz,sign}
        #"git+https://git.kernel.org/pub/scm/docs/man-pages/man-pages#commit=$_commit" # no tarball release for 6.00
        https://www.kernel.org/pub/linux/docs/man-pages/man-pages-posix/$pkgname-posix-${_posixver}.tar.{xz,sign}
        sha256sums::https://www.kernel.org/pub/linux/docs/man-pages/sha256sums.asc)

prepare() {
  cd "${srcdir}"/$pkgname-$pkgver
  
#  sed -i "s|prefix := /usr/local|prefix := /usr|g" Makefile

  # included in shadow
  rm man5/passwd.5
  rm man3/getspnam.3
  # included in tzdata
  rm man5/tzfile.5 man8/{tzselect,zdump,zic}.8
  # included in libxcrypt
  rm man3/crypt*.3
  # nscd is dead
  rm man5/nscd.conf.5 man8/nscd.8

}

package() {
  cd "${srcdir}"/$pkgname-$pkgver

  # install man-pages
  make DESTDIR="${pkgdir}" prefix=/usr install 

  # install posix pages
  pushd "${srcdir}"/$pkgname-posix-${_posixver%-*}
  make DESTDIR="${pkgdir}" install 
  popd
  
  # posix pages have a custom license
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 "${srcdir}"/$pkgname-posix-${_posixver%-*}/POSIX-COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/POSIX-COPYRIGHT"
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('GPL' 'custom')

validpgpkeys=(E522595B52EDA4E6BFCCCB5E856199113A35CE5E # Michael Kerrisk (Linux man-pages maintainer) <mtk.manpages@gmail.com>
	A9348594CE31283A826FBDD8D57633D441E25BB5)  # Alejandro Colomar Andres <alx.manpages@gmail.com>

sha256sums=(b96ab6b44a688c91d1b572e52fece519e1cfd2bb4c33fe7014fc3fd1ef3f9cae  # man-pages-6.05.01.tar.xz
	1e739ff2fc5db345e898e72a56ff3bafab1fa3a46ca393d0b55fb4b8872d3bbd  # man-pages-6.05.01.tar.sign
	ce67bb25b5048b20dad772e405a83f4bc70faf051afa289361c81f9660318bc3  # man-pages-posix-2017-a.tar.xz
	a754077b66853702059a7ae8ff520fadf42ab7484da6df991207343e8b7c5eff  # man-pages-posix-2017-a.tar.sign
	3495f725670759f71460c8f44e870e2767101fe9bb87f7e7aade082ae9304e16) # sha256sums

##  9bdce2e51a14eb87f8738f33558a7646be462bde5342fefef2a81b1662a64b43  man-pages-6.05.01-02-x86_64.pkg.tar.lz

