#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=pptpclient
pkgver=1.10.0
pkgrel=03
pkgdesc="Client for the proprietary Microsoft Point-to-Point Tunneling Protocol, PPTP."
arch=('x86_64')
url="http://pptpclient.sourceforge.net/"
depends=('ppp' 'iproute2' 'perl')
backup=('etc/ppp/options.pptp')
source=("https://downloads.sourceforge.net/sourceforge/pptpclient/pptp-$pkgver.tar.gz")

prepare() {
  cd pptp-$pkgver

  # use our CFLAGS and LDFLAGS
  sed -i -e "/CFLAGS  =/ c\CFLAGS = ${CFLAGS}" Makefile
  sed -i -e "/LDFLAGS =/ c\LDFLAGS = ${LDFLAGS}" Makefile

  # adjust ip path
  sed -i 's#/bin/ip#/usr/bin/ip#' routing.c

  # put binaries in /usr/bin
  sed -i "/BINDIR/s#/sbin#/bin#" Makefile
}

build() {
  cd pptp-$pkgver
  make 
}

package() {
  cd pptp-$pkgver
  make DESTDIR="$pkgdir" install
}

#---- license gpg-key sha256sums ----

license=('GPL')

sha256sums=(82492db8e487ce73b182ee7f444251d20c44f5c26d6e96c553ec7093aefb5af4) #  pptp-1.10.0.tar.gz

#  70205433e9cd2027dc5592ef7c27ca3a5d375c121876cb0a0742a45a78e6d8dc  pptpclient-1.10.0-03-x86_64.pkg.tar.xz


