#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libisl
pkgver=0.26
pkgrel=01
pkgdesc='Library for manipulating sets and relations of integer points bounded by linear constraints'
url='https://libisl.sourceforge.io'
depends=('gmp')
provides=('isl' 'libisl.so')
replaces=('isl')
options=(staticlibs)
source=("https://libisl.sourceforge.io/isl-${pkgver}.tar.xz")

build() {
  cd "${srcdir}"/${pkgname#lib}-${pkgver}
  ./configure --prefix=/usr
  make
}

check() {
  cd "${srcdir}"/${pkgname#lib}-${pkgver}
  make check || true
}

package() {
  cd "${srcdir}"/${pkgname#lib}-${pkgver}

  make DESTDIR="${pkgdir}" install

  install -dm755 "${pkgdir}"/usr/share/gdb/auto-load/usr/lib/
  mv "${pkgdir}"/usr/lib/libisl.so.*-gdb.py "${pkgdir}"/usr/share/gdb/auto-load/usr/lib/
  
  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('MIT')

sha256sums=(a0b5cb06d24f9fa9e77b55fabbe9a3c94a336190345c2555f9915bb38e976504) # isl-0.26.tar.xz

##  12f3af79e28e642eea91dabd47ca5cc99de88f76f621fc6c5660304b31279418  libisl-0.26-01-x86_64.pkg.tar.lz
