#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=kbd
pkgver=2.6.4
pkgrel=01
pkgdesc="Keytable files and keyboard utilities"
url="http://www.kbd-project.org"
depends=('glibc' 'pam')
makedepends=('check' 'git' 'gettext' 'autoconf' 'automake')
#makedepends=('check'        'gettext' 'autoconf' 'automake')
source=(git+https://git.kernel.org/pub/scm/linux/kernel/git/legion/kbd.git#tag=v$pkgver?signed
#source=(https://www.kernel.org/pub/linux/utils/${pkgname}/${pkgname}-${pkgver}.tar.{gz,sign}
	'fix-euro2.patch'
	'vlock.pam')
backup=('etc/pam.d/vlock')
provides=('vlock')
conflicts=('vlock')
replaces=('vlock')

prepare() {
#  cd ${pkgname}-${pkgver}
  cd ${pkgname}
  # rename keymap files with the same names
  # this is needed because when only name of keymap is specified
  # loadkeys loads the first keymap it can find, which is bad (see FS#13837)
  # this should be removed when upstream adopts the change
  mv data/keymaps/i386/qwertz/cz{,-qwertz}.map
  mv data/keymaps/i386/olpc/es{,-olpc}.map
  mv data/keymaps/i386/olpc/pt{,-olpc}.map
  mv data/keymaps/i386/fgGIod/trf{,-fgGIod}.map
  mv data/keymaps/i386/colemak/{en-latin9,colemak}.map
  # fix euro2 #28213
  patch -Np1 -i ../fix-euro2.patch
#  # Do not look up include files in the current working directory
#  git cherry-pick -n '8b7f70904343153b658b8640ba14fc7d583cdc57'
  autoreconf -if
}

build() {
#  cd ${pkgname}-${pkgver}
  cd ${pkgname}
  ./configure --prefix=/usr --sysconfdir=/etc --datadir=/usr/share/kbd --mandir=/usr/share/man --enable-optional-progs
  make KEYCODES_PROGS=yes RESIZECONS_PROGS=yes
}

check() {
#  cd ${pkgname}-${pkgver}
  cd ${pkgname}

# This test is expected to fail since kbd-fix-loadkmap-compat.patch modifies the binary format
  sed -e 's|dumpkeys-bkeymap ||' -i tests/Makefile

  make check
}

package() {
#  cd ${pkgname}-${pkgver}
  cd ${pkgname}
  make KEYCODES_PROGS=yes RESIZECONS_PROGS=yes DESTDIR="${pkgdir}" install
  install -Dm644 ../vlock.pam "${pkgdir}"/etc/pam.d/vlock
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('GPL')

validpgpkeys=('7F2A3D07298149A0793C9A4EA45ABA544CFFD434') # Alexey Gladkov

sha256sums=(SKIP
#	6103cfc3760ddc1ea8e7b6a71ff340670b2942c157abae88bdd0fb747bc64907  # kbd-2.6.3.tar.gz
#	3bedb57873d4815862dee0349cebc86ad37b0dd4961913cc174049860d34f630  # kbd-2.6.3.tar.sign
	a5e0167b6a82a9eb4d581d56baab930c2d80f5541dc34630460b73e1115384b8  # fix-euro2.patch
	5c2d377a87121e7c399534fb91e2ffc0cc1e75d44a8f07ee6f55c9c089bc81e4) # vlock.pam

##  1cd7aedfbe8506f5ed280c1765afc54d05465cea437a586d1b743e3b450df819  kbd-2.6.4-01-x86_64.pkg.tar.lz

