#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=attr
pkgver=2.5.2
pkgrel=01
pkgdesc='Extended attribute support library for ACL support'
url='https://savannah.nongnu.org/projects/attr'
depends=('glibc')
makedepends=('gettext')
replaces=('xfsattr')
provides=('xfsattr' 'libattr.so')
#options=('debug')
conflicts=('xfsattr')
backup=('etc/xattr.conf')
source=("https://download.savannah.gnu.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.xz"{,.sig})

prepare() {
  # remove the nfs entries from /etc/xattr.conf
  # http://lists.gnu.org/archive/html/bug-coreutils/2019-03/msg00008.html
  sed -i '/nfs/d' $pkgname-$pkgver/xattr.conf
}

build() {
  cd $pkgname-$pkgver

  ./configure \
    --libdir=/usr/lib \
    --libexecdir=/usr/lib \
    --prefix=/usr \
    --sysconfdir=/etc
  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="${pkgdir}" install
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('LGPL')

validpgpkeys=('600CD204FBCEA418BD2CA74F154343260542DF34'  # Brandon Philips <brandon@ifup.co>
              'B902B5271325F892AC251AD441633B9FE837F581'  # Frysinger <vapier@gentoo.org>
              '259B3792B3D6D319212CC4DCD5BF9FEB0313653A') # Andreas Gruenbacher <andreas.gruenbacher@gmail.com>

sha256sums=(f2e97b0ab7ce293681ab701915766190d607a1dba7fae8a718138150b700a70b  # attr-2.5.2.tar.xz
	70f1dece465a08abb91c44a969edba82408af3b44419d4c80808d6c6ac3b7645) # attr-2.5.2.tar.xz.sig

##  ca07c8942cb7e95ca3ef4b845ff92131ddc31ea0c6214fda3496ead8d1124936  attr-2.5.2-01-x86_64.pkg.tar.lz
