#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=sdparm
pkgver=1.12
pkgrel=01
pkgdesc="An utility similar to hdparm but for SCSI devices"
arch=('x86_64')
url="http://sg.danny.cz/sg/sdparm.html"
depends=('glibc' 'bash')
source=(http://sg.danny.cz/sg/p/${pkgname}-${pkgver}.tar.xz)

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

#---- license gpg-key sha256sums ----

license=('BSD')

sha256sums=(c4c9efafdbeb662e2f9712707ec490932bd4d010bb1129ae7a99526546eeadbe) #  sdparm-1.12.tar.xz
