#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libssh2
pkgver=1.11.0
pkgrel=01
pkgdesc="A library implementing the SSH2 protocol as defined by Internet Drafts"
url="https://www.libssh2.org/"
depends=('openssl' 'zlib')
provides=('libssh2.so')
source=("https://www.libssh2.org/download/$pkgname-$pkgver.tar.gz"{,.asc})

build() {
  cd "$pkgname-$pkgver"

  ./configure --prefix=/usr --disable-docker-tests
  make
}

check() {
  make -C "$pkgname-$pkgver" check
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('BSD')

validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2'   # Daniel Stenberg
              '914C533DF9B2ADA2204F586D78E11C6B279D5C91')  # Daniel Stenberg (old key)

sha256sums=(3736161e41e2693324deb38c26cfdc3efe6209d634ba4258db1cecff6a5ad461  # libssh2-1.11.0.tar.gz
	b6a32c85a3f9b6f30f2b3595ba034b48a8508ee9c94708ef811f58fd7adfcdee) # libssh2-1.11.0.tar.gz.asc

##  f50401d328424b3c71692528f0091020097b00768b5a1f6bc5f3c53fb67f7b9d  libssh2-1.11.0-01-x86_64.pkg.tar.lz
