#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=archlinux-keyring
_tag='5857f33114c78e3f03fb250c5ce2c12259609ce0' # git rev-parse ${pkgver}
pkgver=20231222
pkgrel=01
pkgdesc='Arch Linux PGP keyring'
url='https://gitlab.archlinux.org/archlinux/archlinux-keyring/'
install=$pkgname.install
groups=(base)
depends=(pacman)
makedepends=('git' 'python' 'sequoia-sq' 'pkgconf')
checkdepends=('python-coverage' 'python-pytest')
source=("archlinux-keyring::git+https://gitlab.archlinux.org/archlinux/archlinux-keyring.git#tag=${_tag}?signed")
##  before 2022 source=(https://sources.archlinux.org/other/$pkgname/${pkgname}-${pkgver}.tar.gz{,.sig})
build() {
  cd archlinux-keyring/

  make build
}

check() {
  cd archlinux-keyring/

  make check
}

package() {
  cd archlinux-keyring/

  make PREFIX='/usr' DESTDIR="${pkgdir}" install
  rm -rf $pkgdir/timers.target.wants
  rm -rf $pkgdir/archlinux-keyring-wkd-sync.timer
  rm -rf $pkgdir/archlinux-keyring-wkd-sync.service
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=(GPL3)

validpgpkeys=('02FD1C7A934E614545849F19A6234074498E9CEE'  # Christian Hesse <eworm@archlinux.org>
              'C7E7849466FE2358343588377258734B41C31549'  # David Runge <dvzrv@archlinux.org>
              '4AA4767BBC9C4B1D18AE28B77F2D434B9741E8AC'  # Pierre Schmitz <pierre@archlinux.org>
              'CFA6AF15E5C74149FC1D8C086D1655C14CE1C13E'  # Florian Pritz <bluewind@archlinux.org>
              'ECCAC84C1BA08A6CC8E63FBBF22FB1D78A77AEAB'  # Giancarlo Razzolini <grazzolini@archlinux.org>
              'E240B57E2C4630BA768E2F26FC1B547C8D8172C8'  # Levente Polyak <anthraxx@archlinux.org>
              'C100346676634E80C940FB9E9C02FF419FECBE16') # Morten Linderud <foxboron@archlinux.org>

sha256sums=(SKIP)

##  d8b391f94462cd34a50cff34333eea07c1b373ab0046ba083f5f18e0cfab6492  archlinux-keyring-20231222-01-x86_64.pkg.tar.lz

