#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libnsl
pkgver=2.0.1
pkgrel=01
pkgdesc="Public client interface library for NIS(YP)"
url="https://github.com/thkukuk/libnsl"
depends=(glibc libtirpc)
provides=(libnsl.so)
#options=(debug)
source=($url/archive/v$pkgver/$pkgname-v$pkgver.tar.gz)

prepare() {
  cd "$pkgname-$pkgver"
  autoreconf -fiv
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr --disable-static
  make
}

package() {
  make DESTDIR="$pkgdir" install -C $pkgname-$pkgver
  install -vDm 644 $pkgname-$pkgver/{AUTHORS,NEWS,README} -t "${pkgdir}/usr/share/doc/${pkgname}"
}


#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=(LGPL-2.1-only)

sha256sums=(59048b53be8d3904bf939313debf13956a881b0de79da40f7719a77bcd1e9c53) # libnsl-v2.0.1.tar.gz

##  7a540182c7625f8a67f6cc70c27932a59adbc9449e2fd5f703af3855610b5608  libnsl-2.0.1-01-x86_64.pkg.tar.lz
