#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=icu
pkgver=72.1
pkgrel=02
pkgdesc="International Components for Unicode library"
arch=(x86_64)
groups=( jobbot )
url="https://icu.unicode.org"
depends=('gcc-libs' 'sh')
makedepends=('python')
provides=(libicu{data,i18n,io,test,tu,uc}.so)
# options=('debug')   ###  uncomment this for debug pkg
source=(https://github.com/unicode-org/icu/releases/download/release-${pkgver//./-}/${pkgname}4c-${pkgver//./_}-src.tgz{,.asc})
# https://github.com/unicode-org/icu/releases/download/release-71-1/SHASUM512.txt

build() {
  cd icu/source
  ./configure --prefix=/usr \
	--sysconfdir=/etc \
	--mandir=/usr/share/man \
	--sbindir=/usr/bin
  make
}

#
#ALL TESTS SUMMARY:
#ok:  testdata intltest iotest
#===== ERRS:  cintltst
#make[1]: *** [Makefile:91: check-recursive] Error 1
#make[1]: Target 'check' not remade because of errors.
#make[1]: Leaving directory '/src/pkg/jobcore/icu/src/icu/source/test'
#make: *** [Makefile:153: check-recursive] Error 2
#make: Target 'check' not remade because of errors.
#
#check() {
#  cd icu/source
#  make -k check
#}
#

package() {
  cd icu/source
  make -j1 DESTDIR="${pkgdir}" install

  # Install license
  install -Dm644 "${srcdir}"/icu/LICENSE "${pkgdir}"/usr/share/licenses/icu/LICENSE
}

#---- license gpg-key sha256sums ----

license=('custom:icu')

#validpgpkeys=('BA90283A60D67BA0DD910A893932080F4FB419E3') #  "Steven R. Loomis (filfla-signing) <srloomis@us.ibm.com>" 
#validpgpkeys+=('9731166CD8E23A83BEE7C6D3ACA5DBE1FD8FABF1') #  "Steven R. Loomis (ICU Project) <srl@icu-project.org>" 
#validpgpkeys+=('FFA9129A180D765B7A5BEA1C9B432B27D1BA20D7') # "Fredrik Roubert <fredrik@roubert.name>"
#validpgpkeys+=('E4098B78AFC94394F3F49AA903996C7C83F12F11') # "keybase.io/srl295 <srl295@keybase.io>"
#validpgpkeys+=('4569BBC09DA846FC91CBD21CE1BBA44593CF2AE0') # "Steven R. Loomis (codesign-qormi) <srloomis@us.ibm.com>"
#validpgpkeys=('0E51E7F06EF719FBD072782A5F56E5AFA63CCD33') #"Craig Cornelius (For use with ICU releases) <ccornelius@google.com>"
validpgpkeys=('3DA35301A7C330257B8755754058F67406EAA6AB') # Craig Cornelius <ccornelius@google.com>

# https://github.com/unicode-org/icu/releases/download/release-71-1/SHASUM512.txt

sha256sums=(a2d2d38217092a7ed56635e34467f92f976b370e20182ad325edea6681a71d68  # icu4c-72_1-src.tgz
	87b6ff610d587292cec0444fa8cbbfb12994cb89bade40578f5ba6470de245c7) # icu4c-72_1-src.tgz.asc
