#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=dash
pkgver=0.5.12
pkgrel=01
pkgdesc='POSIX compliant shell that aims to be as small as possible'
url='http://gondor.apana.org.au/~herbert/dash/'
arch=('x86_64')
depends=('glibc' 'libedit' 'libedit.so')
install=dash.install
#options=(debug)
source=(https://git.kernel.org/pub/scm/utils/dash/dash.git/snapshot/${pkgname}-${pkgver}.tar.gz)

prepare() {
  cd ${pkgname}-${pkgver}
  autoreconf -fiv
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --bindir=/usr/bin \
    --mandir=/usr/share/man \
    --exec-prefix="" \
    --with-libedit
  make V=1
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

#---- license gpg-key sha256sums ----

license=('BSD')

sha256sums=(0d632f6b945058d84809cac7805326775bd60cb4a316907d0bd4228ff7107154) # dash-0.5.12.tar.gz

##  5ec08a13378ada3386f3b51bac93bc3ccf5c216267447ec3861cc18f5964a9eb  dash-0.5.12-01-x86_64.pkg.tar.lz


