#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libarchive
pkgver=3.6.2
pkgrel=02
pkgdesc='Multi-format archive and compression library'
arch=('x86_64')
url='https://libarchive.org/'
depends=('acl' 'libacl.so' 'bzip2' 'expat' 'lz4' 'openssl' 'xz' 'zlib' 'zstd' 'libcrypto.so')
provides=('libarchive.so')
#options=('debug')
source=("https://github.com/${pkgname}/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz"{,.asc})
# temp key server out will try again later and issue pkgrel=02
# again, for 3rd day in a row, this gpg key is a phantom, Arch reisssues and patches a pseudo-signed source
# which is obviously is not checked by their server.
# ... finally after being mentioned in reddit/arch magically the key appeared to verify the source!!!
#source=("https://github.com/${pkgname}/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz") #"{,.asc})

#prepare() {
#  cd "$pkgname-$pkgver"
#
#  patch -Np1 < ../0001-libarchive-Handle-a-calloc-returning-NULL-fixes-1754.patch
#  patch -Np1 < ../0002-Validate-entry_bytes_remaining-in-pax_attribute.patch
#  patch -Np1 < ../0003-libarchive-Do-not-include-sys-mount.h-when-linux-fs..patch
#}

build() {
  cd $pkgname-$pkgver 

  ./configure \
      --prefix=/usr \
      --without-xml2 \
      --without-nettle \
      --disable-static
  make
}

check() {
  cd $pkgname-$pkgver

  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  sed -i "s/iconv //" "$pkgdir"/usr/lib/pkgconfig/libarchive.pc
  install -Dm0644 COPYING "$pkgdir/usr/share/licenses/libarchive/COPYING"
}

#---- license gpg-key sha256sums ----

license=('BSD')

validpgpkeys=(A5A45B12AD92D964B89EEE2DEC560C81CEC2276E  # Martin Matuska <mm@FreeBSD.org>
              DB2C7CF1B4C265FAEF56E3FC5848A18B8F14184B) # Martin Matuska <martin@matuska.org>

sha256sums=(9e2c1b80d5fbe59b61308fdfab6c79b5021d7ff4ff2489fb12daf0a96a83551d  # libarchive-3.6.2.tar.xz
	c6f1cdc29571dd6b09d3776ae98404a81b2dbe970a2bd9dc0bd9ed183ca49b71) # libarchive-3.6.2.tar.xz.asc

