#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=less
pkgver=608
pkgrel=02
epoch=1
pkgdesc='A terminal based program for viewing text files'
arch=('x86_64')
url='https://www.greenwoodsoftware.com/less/'
depends=('glibc' 'ncurses' 'pcre2')
source=("https://www.greenwoodsoftware.com/$pkgname/$pkgname-$pkgver.tar.gz"
        "$pkgname-$pkgver.tar.gz.sig::https://www.greenwoodsoftware.com/$pkgname/$pkgname-$pkgver.sig"
        less-CVE-2022-46663.patch::https://github.com/gwsw/less/commit/a78e1351113cef564d790a730d657a321624d79c.patch)

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 < ../less-CVE-2022-46663.patch
}

build() {
  cd $pkgname-$pkgver
  sh configure --prefix=/usr --sysconfdir=/etc --with-regex=pcre2
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}

#---- license gpg-key sha256sums ----

license=('GPL3')

validpgpkeys=('AE27252BD6846E7D6EAE1DD6F153A7C833235259') # Mark Nudelman

sha256sums=(a69abe2e0a126777e021d3b73aa3222e1b261f10e64624d41ec079685a6ac209  # less-608.tar.gz
	471e673031cc2112422f3827b3ea2e32b619e5b25b1d81b284fe6df6cda2b1b4  # less-608.tar.gz.sig
	3862ce1d6ee0aacefe75274f04afc00a38474d4cf2f6be96feb6aaa226c9bd98) # less-CVE-2022-46663.patch 

##  ec60d23c84e6733d49feec2c6cc5eea495a631659e972530f110548fcf0d3f52  less-1:608-02-x86_64.pkg.tar.lz

