#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------
# Maintainer	: Eric Vidal <eric@obarun.org>

pkgname=s6-linux-utils
pkgdesc="A set of tiny Linux-specific utilities"
_pkgver=v2.6.1.0
pkgver=2.6.1.0
pkgrel=01
url="http://skarnet.org/software/${pkgname}/"
arch=(x86_64)
depends=('skalibs>=2.13.1.0')
makedepends=(git 'skalibs>=2.13.1.0')
groups=('s6-suite')
# commit=2d46f7275ca14573f018d4951de595c3188de48d # refs/tags/v2.6.0.1
source=("$pkgname::git+git://git.skarnet.org/s6-linux-utils#tag=$_pkgver")

_pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

build() {
  cd ${srcdir}/${pkgname}
  ./configure --prefix=/usr \
              --bindir=/usr/bin \
              --sbindir=/usr/bin \
              --datadir=/etc \
              --disable-shared \
              --with-lib=/usr/lib/skalibs
  make
}

package() {
  cd ${srcdir}/${pkgname}

  DESTDIR=${pkgdir} make install

  # add doc
  install -dm 0755 $pkgdir/usr/share/doc/$pkgname/
  cp -R doc/* $pkgdir/usr/share/doc/$pkgname/

  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

}

#---- license gpg-key sha256sums ----

license=(ISC)

sha256sums=(SKIP)

