#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libmicrohttpd
pkgver=0.9.76
pkgrel=01
pkgdesc="a small C library that is supposed to make it easy to run an HTTP server as part of another application."
url="https://www.gnu.org/software/libmicrohttpd/"
depends=('gnutls')
checkdepends=('curl')
provides=('libmicrohttpd.so')
source=("https://ftp.gnu.org/gnu/libmicrohttpd/$pkgname-$pkgver.tar.gz"{,.sig})

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --disable-dependency-tracking \
    --disable-examples \
    --enable-curl \
    --enable-https \
    --enable-largefile \
    --enable-messages \
    --with-pic
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="$pkgdir" install
}

#---- arch license gpg-key and sha256sums ----

arch=(x86_64)

license=('LGPL')

validpgpkeys=('EA812DBEFA5A7EF17DA8F2C1460A317C3326D2AE'  # Evgeny Grin (Karlson2k) <k2k@yandex.ru>
              'D8423BCB326C7907033929C7939E6BE1E29FC3CC') # Christian Grothoff <christian.grothoff@bfh.ch>

sha256sums=(f0b1547b5a42a6c0f724e8e1c1cb5ce9c4c35fb495e7d780b9930d35011ceb4c  # libmicrohttpd-0.9.76.tar.gz
	0b2b316f5f9a0191206f6b8b12a8cca5997237ce6d7a1c6dc487538e7f7cd9f6) # libmicrohttpd-0.9.76.tar.gz.sig

##  e24d98e663d4197f30bb453e687153b820d9127344b80fa071c63fe51832c6ec  libmicrohttpd-0.9.76-01-x86_64.pkg.tar.lz


