#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgbase=util-linux
pkgname=(util-linux util-linux-libs)
_pkgmajor=2.38
_realver=${_pkgmajor}.1
pkgver=${_realver/-/}
pkgrel=03
pkgdesc='Miscellaneous system utilities for Linux w/o systemd'
url='https://github.com/karelzak/util-linux'
makedepends=('asciidoctor' 'libcap-ng' 'libxcrypt' 'python')
#options=('debug' 'strip')
options=(strip)
source=("https://www.kernel.org/pub/linux/utils/util-linux/v${_pkgmajor}/${pkgbase}-${_realver}.tar."{xz,sign}
        pam-{login,common,runuser,su}
        'util-linux.sysusers'
        '60-rfkill.rules')

#prepare() {
#  cd "${pkgbase}-${_realver}"
#
#  patch -Np1 < ../0001-agetty-resolve-tty-name-even-if-stdin-is-specified.patch
#}


#    --disable-raw \

build() {
  cd "${pkgbase}-${_realver}"

  ./configure \
    --prefix=/usr \
    --libdir=/usr/lib \
    --bindir=/usr/bin \
    --sbindir=/usr/bin \
    --localstatedir=/var \
    --enable-usrdir-path \
    --enable-fs-paths-default=/usr/bin:/usr/local/bin \
    --enable-vipw \
    --enable-newgrp \
    --enable-chfn-chsh \
    --enable-write \
    --enable-mesg \
    --with-python=3 \
    --with-systemdsystemunitdir=no \
    --with-systemd=no

  make
}

package_util-linux() {
  conflicts=('rfkill' 'hardlink')
  provides=('rfkill' 'hardlink')
  replaces=('rfkill' 'hardlink')
  depends=('pam' 'shadow' 'coreutils'
		'libeudev' 'libcap-ng' 'libxcrypt' 'libcrypt.so' 'util-linux-libs'
           'libmagic.so' 'libncursesw.so')
  optdepends=('words: default dictionary for look')
  backup=(etc/pam.d/chfn
          etc/pam.d/chsh
          etc/pam.d/login
          etc/pam.d/runuser
          etc/pam.d/runuser-l
          etc/pam.d/su
          etc/pam.d/su-l)

  make -C "${pkgbase}-${_realver}" DESTDIR="${pkgdir}" usrsbin_execdir=/usr/bin install

  # remove static libraries
  rm "${pkgdir}"/usr/lib/lib*.a*

  # setuid chfn and chsh
  chmod 4755 "${pkgdir}"/usr/bin/{newgrp,ch{sh,fn}}

  # install PAM files for login-utils
  install -Dm0644 pam-common "${pkgdir}/etc/pam.d/chfn"
  install -m0644 pam-common "${pkgdir}/etc/pam.d/chsh"
  install -m0644 pam-login "${pkgdir}/etc/pam.d/login"
  install -m0644 pam-runuser "${pkgdir}/etc/pam.d/runuser"
  install -m0644 pam-runuser "${pkgdir}/etc/pam.d/runuser-l"
  install -m0644 pam-su "${pkgdir}/etc/pam.d/su"
  install -m0644 pam-su "${pkgdir}/etc/pam.d/su-l"

  # TODO(dreisner): offer this upstream?
#  sed -i '/ListenStream/ aRuntimeDirectory=uuidd' "${pkgdir}/usr/lib/systemd/system/uuidd.socket"

  # runtime libs are shipped as part of util-linux-libs
  install -d -m0755 util-linux-libs/lib/
  mv "$pkgdir"/usr/lib/lib*.so* util-linux-libs/lib/
  mv "$pkgdir"/usr/lib/pkgconfig util-linux-libs/lib/pkgconfig
  mv "$pkgdir"/usr/include util-linux-libs/include
  mv "$pkgdir"/usr/lib/python3.10/site-packages util-linux-libs/site-packages
  rmdir "$pkgdir"/usr/lib/python3.10
  mv "$pkgdir"/usr/share/man/man3 util-linux-libs/man3

  ### install sysusers
  install -Dm0644 "${srcdir}/util-linux.sysusers" \
    "${pkgdir}/usr/lib/sysusers.d/util-linux.conf"

  install -Dm0644 "${srcdir}/60-rfkill.rules" \
    "${pkgdir}/usr/lib/udev/rules.d/60-rfkill.rules"

#  install -Dm0644 rfkill-unblock_.service \

#    "${pkgdir}/usr/lib/systemd/system/rfkill-unblock@.service"
#  install -Dm0644 rfkill-block_.service \
#    "${pkgdir}/usr/lib/systemd/system/rfkill-block@.service"
}



















package_util-linux-libs() {
  pkgdesc="util-linux runtime libraries"
  depends=('glibc')
  provides=('libutil-linux' 'libblkid.so' 'libfdisk.so' 'libmount.so' 'libsmartcols.so' 'libuuid.so')
  conflicts=('libutil-linux')
  replaces=('libutil-linux')
  optdepends=('python: python bindings to libmount')
  install -d -m0755 "$pkgdir"/usr/{lib/python3.10/,share/man/}
  mv util-linux-libs/lib/* "$pkgdir"/usr/lib/
  mv util-linux-libs/include "$pkgdir"/usr/include
  mv util-linux-libs/site-packages "$pkgdir"/usr/lib/python3.10/site-packages
  mv util-linux-libs/man3 "$pkgdir"/usr/share/man/man3

}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('GPL2')

validpgpkeys=('B0C64D14301CC6EFAEDF60E4E4B71D5EEC39C284')  # Karel Zak

sha256sums=(60492a19b44e6cf9a3ddff68325b333b8b52b6c59ce3ebd6a0ecaa4c5117e84f # util-linux-2.38.1.tar.xz
	a912d209b40b997bfbe41c9d444fa003fee9fab74b6aaad30d30ecb40466b02f # util-linux-2.38.1.tar.sign
	99cd77f21ee44a0c5e57b0f3670f711a00496f198fc5704d7e44f5d817c81a0f # pam-login
	57e057758944f4557762c6def939410c04ca5803cbdd2bfa2153ce47ffe7a4af # pam-common
	48d6fba767631e3dd3620cf02a71a74c5d65a525d4c4ce4b5a0b7d9f41ebfea1 # pam-runuser
	3f54249ac2db44945d6d12ec728dcd0d69af0735787a8b078eacd2c67e38155b # pam-su
	10b0505351263a099163c0d928132706e501dd0a008dac2835b052167b14abe3 # util-linux.sysusers
	7423aaaa09fee7f47baa83df9ea6fef525ff9aec395c8cbd9fe848ceb2643f37) #  60-rfkill.rules

##  11c802f75ee223e5565844c2480fa65c5abec686744330ae032afb90aeb610bd  util-linux-2.38.1-03-x86_64.pkg.tar.lz
##  8f069ce441cb62a4c96764110c25312d968e18e7f17872aca11717869ed35ff3  util-linux-libs-2.38.1-03-x86_64.pkg.tar.lz

