# Maintainer: Eric Vidal <eric@obarun.org>
# based on the original https://aur.archlinux.org/packages/procps-ng-nosystemd
#                       Maintainer: Alexey D. <lq07829icatm@rambler.ru>
#                       Contributor: Gaetan Bisson <bisson@archlinux.org>
#                       Contributor: Eric Bélanger <eric@archlinux.org>

pkgname=procps-ng

pkgver=3.3.17
pkgrel=3

pkgdesc='Utilities for monitoring your system and its processes'

url='https://gitlab.com/procps-ng/procps'

source=(https://downloads.sourceforge.net/project/$pkgname/Production/${pkgname}-${pkgver}.tar.xz{,.asc}
       'sysctl.conf')

options=(!emptydirs)

prepare() {
    cd procps-$pkgver
    sed 's:<ncursesw/:<:g' -i watch.c

}

build() {
    cd  "procps-$pkgver"

    ./configure \
        --prefix=/usr \
        --exec-prefix=/ \
        --sysconfdir=/etc \
        --libdir=/usr/lib \
        --bindir=/usr/bin \
        --sbindir=/usr/bin \
        --enable-watch8bit \
        --disable-kill \
        --disable-modern-top \
        --without-systemd
    make
}

package() {
    cd  "procps-$pkgver"

    make DESTDIR="${pkgdir}" install
    install -Dm644 "${srcdir}/sysctl.conf" "$pkgdir/etc/sysctl.conf"

}

arch=('x86_64')

install=procps-ng.install

depends=(
    'glibc'
    'ncurses'
    'libncursesw.so')

backup=('etc/sysctl.conf')

groups=('base')

conflicts=(
    'procps'
    'sysvinit-tools')

replaces=(
    'procps'
    'sysvinit-tools')

provides=(
    'procps'
    'sysvinit-tools'
    'libprocps.so')

validpgpkeys=(
  '5D3DF0F538B327C0AA7A77A2022166C0FF3C84E3' # Craig Small <csmall@debian.org>
  '5D2FB320B825D93904D205193938F96BDF50FEA5' # Craig Small <csmall@debian.org>
)

license=('GPL' 'LGPL')

sha1sums=('a52952e8bc6aaab812176c00d25adc4d4e1552e2'
          'SKIP'
          '8d43756f7a69b7cbb733b4d93d001ccd1599a0e1')
