#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=efibootmgr
_commit=712aeb81311de28a3fcfea7465dcb93743f07a53  # refs/tags/18
pkgver=18
pkgrel=02
pkgdesc="Linux user-space application to modify the EFI Boot Manager"
url="https://github.com/rhboot/efibootmgr"
depends=(glibc popt)
makedepends=(efivar git)
source=($pkgname::git+$url#tag=$_commit?signed)

build() {
  make libdir=/usr/lib sbindir=/usr/bin EFIDIR=arch -C $pkgname
}

package() {
  depends+=(libefiboot.so libefivar.so)

  make DESTDIR="$pkgdir" libdir=/usr/lib sbindir=/usr/bin EFIDIR=arch install -C $pkgname
  install -vDm 644 $pkgname/{AUTHORS,README,README.md,TODO} -t "$pkgdir/usr/share/doc/$pkgname/"
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=(GPL2)

validpgpkeys=(B00B48BC731AA8840FED9FB0EED266B70F4FEF10  # Peter Jones <pjones@redhat.com>
	  039A9CEA19DE9508C36875AA2532F9176A95A442) # Robbie Harwood (work) <rharwood@redhat.com>

sha256sums=(SKIP)

##  f7751f0332a0c1c9de088149dade13ab3d0741a212d65428be331ea2e0a0ee17  efibootmgr-18-02-x86_64.pkg.tar.lz


