#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libgpg-error
pkgver=1.47
pkgrel=01
pkgdesc="Support library for libgcrypt"
url="https://www.gnupg.org"
depends=('glibc' 'sh')
makedepends=('autoconf' 'automake' 'gettext')
#options=('debug')   ##### uncomment this line to have the debug pkg produced
source=(https://www.gnupg.org/ftp/gcrypt/libgpg-error/${pkgname}-${pkgver}.tar.bz2{,.sig})
# https://www.gnupg.org/download/integrity_check.html

prepare() {
  cd ${pkgname}-${pkgver}
  autoreconf -vfi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}/" install
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('LGPL')

#validpgpkeys=(D8692123C4065DEA5E0F3AB5249B39D24F25E3B6  # Werner Koch
#	   AC8E115BF73E2D8D47FA9908E98E9B2D19C6C8BD  # NIIBE Yutaka (GnuPG Release Key) <gniibe@fsij.org>
#              031EC2536E580D8EA286A9F22071B08A33BD3F06  # NIIBE Yutaka (GnuPG Release Key) <gniibe@fsij.org>
#              6DAA6E64A76D2840571B4902528897B826403ADA) # "Werner Koch (dist signing 2020)"

validpgpkeys=(6DAA6E64A76D2840571B4902528897B826403ADA # Werner Koch (dist signing 2020)
	AC8E115BF73E2D8D47FA9908E98E9B2D19C6C8BD) # Niibe Yutaka (GnuPG Release Key)

sha256sums=(9e3c670966b96ecc746c28c2c419541e3bcb787d1a73930f5e5f5e1bcbbb9bdb  # libgpg-error-1.47.tar.bz2
	35ea715d5942802d433cedb8dcf2f70b1602ea84529dab67086555a4a29d54ec) # libgpg-error-1.47.tar.bz2.sig

##  134e94a56c32efa2400d92045d0e962f49a00080f1e4743f1f893104f72aa3d9  libgpg-error-1.47-01-x86_64.pkg.tar.lz
