#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=mkinitcpio
pkgver=31
pkgrel=04
pkgdesc='Modular initramfs image creation utility w/o systemd'
#_url='https://github.com/archlinux/mkinitcpio'
url="https://sources.archlinux.org/other"
makedepends=('binutils' 'asciidoc' 'sed')
arch=(x86_64)
install=mkinitcpio.install
depends=('awk' 'mkinitcpio-busybox>=1.35.0' 'kmod' 'util-linux>=2.38' 'libarchive' 'coreutils'
	'bash' 'binutils' 'diffutils' 'findutils' 'grep' 'filesystem>=2022.07-07' 'gzip' 'lz4' 'sed')
optdepends=(
	'bzip2: Use bzip2 compression for the initramfs image'
	'lzop: Use lzo compression for the initramfs image'
	'mkinitcpio-nfs-utils: Support for root filesystem on NFS'
	'zstd: Use zstd compression for the initramfs image'
)
provides=("mkinitcpio=$pkgver-$pkgrel"
	'initramfs')
backup=('etc/mkinitcpio.conf')
source=("$url/$pkgname/$pkgname-$pkgver.tar.gz"{,.sig}
       '001-remove-systemd-and-kept-gzip-as-default.patch'
#       'add_udev_rule_function.patch'
       '0001-Fix-the-warning-about-missing-modules.builtin.modinf.patch')

prepare() {
	cd $pkgname-$pkgver


	patch -Np1 < $srcdir/001-remove-systemd-and-kept-gzip-as-default.patch
#	patch -Np1 < $srcdir/add_udev_rule_function.patch
	patch -Np1 < "$srcdir"/0001-Fix-the-warning-about-missing-modules.builtin.modinf.patch  
}

check() {
	make -C $pkgname-$pkgver check
}

package() {
	make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
}

#---- license gpg-key sha256sums ----

license=(GPL)

validpgpkeys=('ECCAC84C1BA08A6CC8E63FBBF22FB1D78A77AEAB') # Giancarlo Razzolini

sha256sums=(8f2811250b852ab78375bf90e1a7430daa132e57e128b0f6eaadddd9b27bbc63 # mkinitcpio-31.tar.gz
	493e04724241e28d9d089bf09748f36b79fd455cb4e62c2e5c8c3d5fb67b6d62 # mkinitcpio-31.tar.gz.sig
	a7dcad6ec0a3ea32896f2ca218ea4ba1550feaed25d58ed609bfbb7f9fd03619 # 001-remove-systemd-and-kept-gzip-as-default.patch
#	0fd3bc75aeb24d3ac272e2f8500fe289ec8606295b25fa299b80ac0834efdbe8 # add_udev_rule_function.patch
	127816da46476bc37178d1484fb531c97cd269b520f033bcb5841c41d16c34bb) # 0001-Fix-the-warning-about-missing-modules.builtin.modinf.patch


