#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libsecret
pkgver=0.20.5
pkgrel=02
pkgdesc="Library for storing and retrieving passwords and other secrets"
url="https://wiki.gnome.org/Projects/Libsecret"
arch=(x86_64)
depends=(glib2 libgcrypt)
checkdepends=(dbus-python dbus-glib python-gobject gjs)
makedepends=(docbook-xsl gobject-introspection vala git gtk-doc meson valgrind)
optdepends=('org.freedesktop.secrets: secret storage backend')
provides=(libsecret-1.so)
_commit=d64530ac70d9723945d68ca079293ea0f9df9e9f  # tags/0.20.5^0
source=("git+https://gitlab.gnome.org/GNOME/libsecret.git#commit=$_commit")

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}


build() {
  arch-meson $pkgname build
  meson compile -C build
}

check() {
  dbus-run-session meson test -C build --print-errorlogs
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}

#---- license gpg-key sha256sums ----

license=(LGPL)

sha256sums=(SKIP)
