#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libedit
_pkgver=20221030-3.1
pkgver=${_pkgver/-/_}
pkgrel=01
pkgdesc='Command line editor library providing generic line editing, history, and tokenization functions'
url='https://thrysoee.dk/editline/'
arch=(x86_64)
depends=('glibc' 'ncurses' 'libncursesw.so')
provides=('libedit.so')
# options=('debug')   ## uncomment this for debug pkg
source=(${url}/${pkgname}-${_pkgver}.tar.gz)

build() {
  cd ${pkgname}-${_pkgver}
  ./configure --prefix=/usr
  make V=1
}

package() {
  cd ${pkgname}-${_pkgver}
  make DESTDIR="${pkgdir}" install

  rm "${pkgdir}"/usr/share/man/man3/history.3 # conflicts with readline
  install -Dm 644 "${pkgdir}"/usr/share/man/man3/editline.3 "${pkgdir}"/usr/share/man/man3/el.3

  install -Dm 644 ChangeLog -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

#---- license gpg-key sha256sums ----

license=('BSD')

sha256sums=(f0925a5adf4b1bf116ee19766b7daa766917aec198747943b1c4edf67a4be2bb) # libedit-20221030-3.1.tar.gz

##  75a6c2eec0f78b1633541d5062330690c095ef7e03bda403aaff048a673cb806  libedit-20221030_3.1-01-x86_64.pkg.tar.lz


