# Maintainer: Eric Vidal <eric@obarun.org>

pkgname=s6
pkgver=2.11.0.0
pkgrel=1
pkgdesc="A process supervision suite"
arch=(x86_64)
url="http://skarnet.org/software/s6/"
license=('ISC')
makedepends=('git' 'skalibs>=2.11.0.0' 'execline>=2.8.1.0')
depends=('skalibs>=2.11.0.0' 'execline>=2.8.1.0')
groups=('base' 's6-suite')
#_commit=6c65c3dd94ce2e6a054d9358795ba1f17de03cad # tag 2.8.0.0
#source=("$pkgname::git+git://git.skarnet.org/s6#commit=$_commit")
source=("$pkgname::git+git://git.skarnet.org/s6#tag=v${pkgver}")

sha256sums=('SKIP')

#pkgver() {
#  cd $pkgbase
#  git describe --tags | sed 's/-/+/g'
#}

build() {
  cd ${srcdir}/${pkgname}
  ./configure --prefix=/usr \
              --bindir=/usr/bin \
              --sbindir=/usr/bin \
              --datadir=/etc \
              --disable-shared \
              --with-lib=/usr/lib/skalibs \
              --with-lib=/usr/lib/execline
  make
}

package() {
  cd ${srcdir}/${pkgname}

  DESTDIR=${pkgdir} make install

  # add doc
  install -dm 0755 $pkgdir/usr/share/doc/$pkgname/
  cp -R doc/* $pkgdir/usr/share/doc/$pkgname/

  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim:ft=sh ts=2 sw=2 et:
