#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

##  ****    This is not on testing yet, it is not ready to be used till its dependents are built ***
##  the current stable version is 72.1 and the patch is ommitted 

pkgname=icu
pkgver=73.2
pkgrel=01
pkgdesc="International Components for Unicode library"
groups=( jobbot )
url="https://icu.unicode.org"
depends=('gcc-libs' 'glibc' 'sh')
makedepends=('python')
provides=(libicu{data,i18n,io,test,tu,uc}.so)
# options=('debug')   ###  uncomment this for debug pkg
source=(https://github.com/unicode-org/icu/releases/download/release-${pkgver//./-}/${pkgname}4c-${pkgver//./_}-src.tgz{,.asc}
        https://github.com/unicode-org/icu/releases/download/release-73-2/SHASUM512.txt)

#prepare() {
#  cd icu/source
#  # https://unicode-org.atlassian.net/browse/ICU-22356
#  patch -Np3 -i ../../ICU-22356.patch
#}

build() {
  cd icu/source
  ./configure --prefix=/usr \
	--sysconfdir=/etc \
	--mandir=/usr/share/man \
	--sbindir=/usr/bin
  make
}

check() {
  cd icu/source
  make -k check
}

package() {
  cd icu/source
  make -j1 DESTDIR="${pkgdir}" install

  # Install license
  install -Dm644 "${srcdir}"/icu/LICENSE "${pkgdir}"/usr/share/licenses/icu/LICENSE
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('custom:icu')

#validpgpkeys=('BA90283A60D67BA0DD910A893932080F4FB419E3') #  "Steven R. Loomis (filfla-signing) <srloomis@us.ibm.com>" 
#validpgpkeys+=('9731166CD8E23A83BEE7C6D3ACA5DBE1FD8FABF1') #  "Steven R. Loomis (ICU Project) <srl@icu-project.org>" 
validpgpkeys+=('FFA9129A180D765B7A5BEA1C9B432B27D1BA20D7') # "Fredrik Roubert <fredrik@roubert.name>"
#validpgpkeys+=('E4098B78AFC94394F3F49AA903996C7C83F12F11') # "keybase.io/srl295 <srl295@keybase.io>"
#validpgpkeys+=('4569BBC09DA846FC91CBD21CE1BBA44593CF2AE0') # "Steven R. Loomis (codesign-qormi) <srloomis@us.ibm.com>"
#validpgpkeys=('0E51E7F06EF719FBD072782A5F56E5AFA63CCD33') #"Craig Cornelius (For use with ICU releases) <ccornelius@google.com>"
validpgpkeys=('3DA35301A7C330257B8755754058F67406EAA6AB') # Craig Cornelius <ccornelius@google.com>

sha512sums=('76dd782db6205833f289d7eb68b60860dddfa3f614f0ba03fe7ec13117077f82109f0dc1becabcdf4c8a9c628b94478ab0a46134bdb06f4302be55f74027ce62'
            'SKIP'
	SKIP)

## https://github.com/unicode-org/icu/releases/download/release-73-2/SHASUM512.txt
## 76dd782db6205833f289d7eb68b60860dddfa3f614f0ba03fe7ec13117077f82109f0dc1becabcdf4c8a9c628b94478ab0a46134bdb06f4302be55f74027ce62  icu4c-73_2-src.tgz

sha256sums=(818a80712ed3caacd9b652305e01afc7fa167e6f2e94996da44b90c2ab604ce1  # icu4c-73_2-src.tgz
	ee0759320a3093fb3bd55345bfc38acc1b660414b9dde0ce36779616eda76ca7  # icu4c-73_2-src.tgz.asc
	645fb72d95d845bf994724ea7d9c51a9109c0d65abd514e77ec444bc25b22ce2) # SHASUM512.txt

##  d44ea5460e66d83d649329afcabadbff22c182b1fb67b92d5619b31d4e6b210f  icu-73.2-01-x86_64.pkg.tar.lz
