#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=rpcbind
pkgver=1.2.6
pkgrel=03
pkgdesc="portmap replacement which supports RPC over various protocols w/o systemd"
arch=(x86_64)
backup=('etc/conf.d/rpcbind')
makedepends=()
depends=('bash' 'glibc' 'libtirpc')
#options=('debug')  ######  uncomment to have the debug pkg produced
url="http://rpcbind.sourceforge.net"
replaces=('portmap')
# see also http://git.linux-nfs.org/?p=steved/rpcbind.git;a=summary
source=(https://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.bz2
	rpcbind-sunrpc.patch
	rpcbind.conf
	tmpfiles.d
	sysusers.d
	CVE-2017-8779.diff)

prepare() {
  cd $pkgname-$pkgver
  # patch for iana services file # FS#20273
  patch -Np1 -i ../rpcbind-sunrpc.patch
  # http://seclists.org/oss-sec/2017/q2/209
  patch -Np1 -i ../CVE-2017-8779.diff
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sbindir=/usr/bin \
    --with-rpcuser=rpc \
    --enable-warmstarts \
    --with-statedir=/var/lib/rpcbind \
    --enable-rmtcalls \
    --with-systemdsystemunitdir=no
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  # install rpcbind config file
  install -D -m644 "$srcdir"/rpcbind.conf "$pkgdir"/etc/conf.d/rpcbind
  # install missing man page - https://bugs.archlinux.org/task/21271
  install -m644 man/rpcinfo.8 "$pkgdir"/usr/share/man/man8/
  # systemd sysusers/tempfile
  install -Dm644 ../tmpfiles.d "${pkgdir}"/usr/lib/tmpfiles.d/rpcbind.conf
  install -Dm644 ../sysusers.d "${pkgdir}"/usr/lib/sysusers.d/rpcbind.conf
  # install license
  install -D -m644 COPYING "$pkgdir"/usr/share/licenses/rpcbind/COPYING
}

#---- license gpg-key sha256sums ----

license=('custom')

sha256sums=(5613746489cae5ae23a443bb85c05a11741a5f12c8f55d2bb5e83b9defeee8de # rpcbind-1.2.6.tar.bz2
	7a32111c74e708ad431b7114580c60d7405c591273e6cc00baf5baff05952573 # rpcbind-sunrpc.patch
	7d13186a6dfdc855cf9c6d41de56aa1efd04bd4a6bd7ab36f81bb29e4699a976 # rpcbind.conf
	08b04f4da12b34d66cc8fefa0a6dcac239019b0de0090e08d61cb18cc36a6045 # tmpfiles.d
	288edf4d317dbeb6607a049d4451ae7e708ab2ad284c674bed19f444036d55c1 # sysusers.d
	bfb7f022b44ca83309dec6dfcb1ff4a5e0b0a40078e3688a2c7ceaaaa19a9686) # CVE-2017-8779.diff

