#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=usbutils
pkgver=015
pkgrel=03
pkgdesc="A collection of USB tools to query connected USB devices w/o systemd"
url="https://git.kernel.org/pub/scm/linux/kernel/git/gregkh/usbutils.git/"
depends=(glibc hwdata)
#makedepends=(git libusb)
makedepends=(libusb)
optdepends=('python: for lsusb.py usage'
            'coreutils: for lsusb.py usage'
	'sh: for usb-devices')
#source=("git+https://git.kernel.org/pub/scm/linux/kernel/git/gregkh/usbutils.git#commit=79b796f9")
source=(https://www.kernel.org/pub/linux/utils/usb/usbutils/$pkgname-$pkgver.tar{.xz,.sign})

prepare() {
#  cd "$pkgname"
  cd $pkgname-$pkgver
  autoreconf -fiv
}

build() {
#  cd "$pkgname"
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
              --datadir=/usr/share/hwdata \
	  --with-systemd=no
  make
}

package() {
  depends+=('libusb-1.0.so' 'libudev.so')
#  cd "$pkgname"
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -vDm 755 usbreset -t "$pkgdir/usr/bin"
  install -vDm 644 NEWS -t "${pkgdir}/usr/share/doc/${pkgname}/"
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('GPL2' 'GPL3')

validpgpkeys=('647F28654894E3BD457199BE38DBBDC86092693E') # Greg Kroah-Hartman <gregkh@linuxfoundation.org>

sha512sums=('cda0070138400703d7429d39dee49130aedaa704292531e6af57b347cc62422ca609540650926e74335f71d67d7d4655418be4824e1eb8a2b065c7b395feaa87'
            'SKIP')
b2sums=('1074c7159e9e6729f03f98e1f38fa0b3fef3e744b5297e6d97a5fc44ea374e2d5a0c481e14b2a034bca201048b1305c3877dbb15e3c4c04b228b4036048d8904'
        'SKIP')

sha256sums=(c3b451bb1f4ff9f6356cac5a6956a9ac8e85d81651af56a29e689f94fa6fda6e  # usbutils-015.tar.xz
	6d01cfd835f504e1e0f0dbc09bbcf99c7abf6de6bd446af957771b2b6f8bc742) # usbutils-015.tar.sign

##  88b3d3cdd22aa7d37c0f37bf21fface5630f6ceca196a6df1a78fd7a6417524f  usbutils-015-03-x86_64.pkg.tar.lz
