#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=gmp
pkgver=6.2.1
pkgrel=02
pkgdesc='A free library for arbitrary precision arithmetic'
arch=(x86_64)
url='https://gmplib.org/'
#options=(debug)   ## uncomment this line to have the debug pkg produced
depends=(gcc-libs sh)
source=(https://gmplib.org/download/gmp/gmp-$pkgver.tar.lz{,.sig})

build() {
  cd $pkgname-$pkgver

  ./configure --build=${CHOST} \
    --prefix=/usr \
    --enable-cxx \
    --enable-fat
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
}

#---- license gpg-key sha256sums ----

license=(LGPL3 GPL)

validpgpkeys=('343C2FF0FBEE5EC2EDBEF399F3599FF828C67298')   # Niels Möller

md5sums=('03a31d8cbaf29d136252f8f38875ed82'
         'SKIP')

sha256sums=(2c7f4f0d370801b2849c48c9ef3f59553b5f1d3791d070cffb04599f9fc67b41 # gmp-6.2.1.tar.lz
	1e01bee28a3ac6ccce3d7b91eaa62c07f43f572565729ed0e0c50948b81c2b14) # gmp-6.2.1.tar.lz.sig


