#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=dialog
pkgver=1.3_20230209
pkgrel=01
epoch=1
pkgdesc="A tool to display dialog boxes from shell scripts"
arch=('x86_64')
url="https://invisible-island.net/dialog/"
depends=('sh' 'ncurses')
provides=('libdialog.so')
source=(https://invisible-mirror.net/archives/$pkgname/$pkgname-${pkgver/_/-}.tgz{,.asc})

build() {
  cd "$srcdir/$pkgname-${pkgver/_/-}"

  ./configure \
    --prefix=/usr \
    --enable-nls \
    --with-libtool \
    --with-ncursesw
  make
}

package() {
  cd "$srcdir/$pkgname-${pkgver/_/-}"
  make DESTDIR="$pkgdir" install-full
}

#---- license gpg-key sha256sums ----

license=('LGPL2.1')

validpgpkeys=('19882D92DDA4C400C22C0D56CC2AF4472167BE03') # Thomas E. Dickey (self-signed w/o SHA1) <dickey@invisible-island.net>

sha256sums=(0c26282305264be2217f335f3798f48b1dce3cf12c5a076bf231cadf77a6d6a8  # dialog-1.3-20230209.tgz
	355495d1aa1de5951307c44b9de36200edd0df1f1ef737682e2b3e694f4a9331) # dialog-1.3-20230209.tgz.asc


##  c4654fdca6e9dd687e0071efbbe7ad7e5ad86c2a0b54bee1adfbc3bae17451e9  dialog-1:1.3_20230209-01-x86_64.pkg.tar.lz


