#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=xfsprogs
pkgver=6.3.0
pkgrel=02
pkgdesc="XFS filesystem utilities w/o systemd"
# url="https://xfs.org"
url="https://xfs.wiki.kernel.org"
depends=('sh' 'util-linux-libs' 'device-mapper' 'libinih' 'liburcu')
optdepends=('icu: for xfs_scrub'
	'python: for xfs_scrub_all script'
            'smtp-forwarder: for xfs_scrub_fail script')
makedepends=(git
	device-mapper
	libinih
	liburcu
	automake
	autoconf
	gettext
	icu)
options=('!makeflags')
#source=("git+https://git.kernel.org/pub/scm/fs/xfs/xfsprogs-dev.git#tag=v${pkgver}")
source=("git+https://git.kernel.org/pub/scm/fs/xfs/xfsprogs-dev.git?signed#tag=v${pkgver}")

build() {
  cd ${pkgname}-dev
  make configure
  export OPTIMIZER="-march=${CARCH/_/-} -O1"
  export DEBUG=-DNDEBUG
  ./configure --prefix=/usr --sbindir=/usr/bin --with-systemd-unit-dir=no
  make
}

package() {
  cd ${pkgname}-dev
  make DIST_ROOT="${pkgdir}" PKG_ROOT_SBIN_DIR="/usr/bin" install install-dev
  chown -R root "$pkgdir"
  chgrp -R root "$pkgdir"
  # add hack as we cannot set rootlibdir
  mv "${pkgdir}"/lib/libhandle.so* "${pkgdir}/usr/lib/"
  rm -rf "${pkgdir}/lib"
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('LGPL')

validpgpkeys=(2B8185919E8D248981869DED20AE1692E13DDEE0  # Eric Sandeen <sandeen@sandeen.net>
	4020459E58C1A52511F5399113F703E6C11CF6F0) # Carlos Maiolino <cem@kernel.org>

sha256sums=(SKIP)

##  fc43c824708d3acc43bb1e5eafd318e304d4542309596f146385e4f5e550f7d5  xfsprogs-6.3.0-02-x86_64.pkg.tar.lz

