#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=wireless-regdb
pkgver=2023.05.03
pkgrel=01
pkgdesc="Central Regulatory Domain Database"
url="https://wireless.wiki.kernel.org/en/developers/regulatory/wireless-regdb"
replaces=(crda)
provides=(crda)
conflicts=(crda)
backup=(etc/conf.d/wireless-regdom)
depends=(bash iw)
source=(https://www.kernel.org/pub/software/network/wireless-regdb/${pkgname}-${pkgver}.tar.{xz,sign}
        wireless-regdom
        set-wireless-regdom
        85-regulatory.rules)

package() {
  install -Dm644 wireless-regdom -t "${pkgdir}"/etc/conf.d
  install -Dm644 85-regulatory.rules -t "${pkgdir}"/usr/lib/udev/rules.d
  install -Dm755 set-wireless-regdom -t "${pkgdir}"/usr/bin

  cd ${pkgname}-${pkgver}
  make install DESTDIR="${pkgdir}" MANDIR=usr/share/man FIRMWARE_PATH=usr/lib/firmware

  for dom in $(grep ^country db.txt | cut -d' ' -f2 | sed 's|:||g'); do
      echo "#WIRELESS_REGDOM=\"${dom}\"" >> "${pkgdir}"/etc/conf.d/wireless-regdom.tmp
    done
    sort -u "${pkgdir}"/etc/conf.d/wireless-regdom.tmp >> "${pkgdir}"/etc/conf.d/wireless-regdom
    rm "${pkgdir}"/etc/conf.d/wireless-regdom.tmp

  install -D -m644 "${srcdir}"/${pkgname}-${pkgver}/LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('custom')

validpgpkeys=('2ABCA7498D83E1D32D51D3B5AB4800A62DB9F73A') # Seth Forshee <seth.forshee@canonical.com>

sha256sums=(f254d08ab3765aeae2b856222e11a95d44aef519a6663877c71ef68fae4c8c12  # wireless-regdb-2023.05.03.tar.xz
	c278056c95f7680d21659ed5ea3cf15ccdcf22542e1d810417a60c2e457efec1  # wireless-regdb-2023.05.03.tar.sign
	192428fd959806705356107bffc97b8b379854e79bd013c4ee140e5202326e2b # wireless-regdom
	603ce97da5cce3f5337e99007ce04e2f295bb33a36b308794884011f7bcabaf3 # set-wireless-regdom
	f5055dfe7584757a11b419836320bcdcd1d3d1e5caf26e20c63a0c64779f3376) # 85-regulatory.rules

##  782b8a02ca077da2d91649728bf8b44e4ce0e0bdf9580081d10031a557962e50  wireless-regdb-2023.05.03-01-x86_64.pkg.tar.lz
