#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=man-db
pkgver=2.11.2
pkgrel=01
pkgdesc="A utility for reading man pages w/o systemd"
arch=('x86_64')
#url="https://www.nongnu.org/man-db/"
url="https://gitlab.com/cjwatson/man-db"
depends=( 'bash' 'gdbm' 'zlib' 'groff' 'libpipeline' 'less' 'libseccomp')
makedepends=('po4a')
optdepends=('gzip') # covered by virtual "base" package
backup=('etc/man_db.conf')
conflicts=('man')
provides=('man')
replaces=('man')
#options=('debug')  # uncomment this to have the man-db-debug pkg built
install=${pkgname}.install
source=(https://savannah.nongnu.org/download/man-db/$pkgname-$pkgver.tar.xz{,.asc}
        # fallback should be used within first 24h after a release
        #https://download-mirror.savannah.gnu.org/releases/man-db/$pkgname-$pkgver.tar.xz{,.asc} 
        #snapdir.diff
        convert-mans
)

#prepare() {
#  cd ${pkgname}-${pkgver}
#  # fix default Add MANDB_MAP entry mapping /snap/man to /var/cache/man/snap
#  # Arch needs /var/lib/snapd/snap/man to /var/cache/man/snap
#  patch -Np0 -i ../snapdir.diff
#}
#

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
    --sbindir=/usr/bin \
    --sysconfdir=/etc \
    --libexecdir=/usr/lib \
    --with-systemdsystemunitdir=no \
    --with-snapdir=/var/lib/snapd/snap \
    --with-db=gdbm \
    --disable-setuid \
    --enable-cache-owner=root \
    --enable-mandirs=GNU \
    --with-sections="1 1p n l 8 3 3p 0 0p 2 3type 5 4 9 6 7"
  make
}

#check() {
#  cd ${pkgname}-${pkgver}
#  make check
#}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install

  # part of groff pkg
  rm -f ${pkgdir}/usr/bin/zsoelim

  # script from LFS to convert manpages, see
  # http://www.linuxfromscratch.org/lfs/view/6.4/chapter06/man-db.html
  install -D -m755 ${srcdir}/convert-mans  ${pkgdir}/usr/bin/convert-mans

}

#---- license gpg-key sha256sums ----

license=('GPL' 'LGPL')

validpgpkeys=('AC0A4FF12611B6FCCF01C111393587D97D86500B') # Colin Watson <cjwatson@debian.org>

sha256sums=(cffa1ee4e974be78646c46508e6dd2f37e7c589aaab2938cc1064f058fef9f8d  # man-db-2.11.2.tar.xz
	9ae5e922206cd905c64347437385026e70d0955d35222cde4c66f178790b2c3d  # man-db-2.11.2.tar.xz.asc
	affab3adc4b83d011ed83060d8ac579211c932e6c0900b92e12779c092ad5df3) # convert-mans


