#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=wireless_tools
pkgver=30.pre9
_pkgver=${pkgver%.pre*}
pkgrel=03
pkgdesc='Tools allowing to manipulate the Wireless Extensions'
url='https://hewlettpackard.github.io/wireless-tools/Tools.html'
arch=('x86_64')
source=("https://hewlettpackard.github.io/wireless-tools/${pkgname}.${pkgver}.tar.gz")

prepare() {
	cd "${srcdir}/${pkgname}.${_pkgver}"
	sed '/BUILD_STATIC =/d' -i Makefile
}

build() {
	cd "${srcdir}/${pkgname}.${_pkgver}"
	make CFLAGS="${CFLAGS} -I." LDFLAGS="${LDFLAGS}"
}

package() {
	cd "${srcdir}/${pkgname}.${_pkgver}"
	make \
		INSTALL_DIR="${pkgdir}/usr/bin" \
		INSTALL_LIB="${pkgdir}/usr/lib" \
		INSTALL_INC="${pkgdir}/usr/include" \
		INSTALL_MAN="${pkgdir}/usr/share/man" \
		install
}

#---- license gpg-key sha256sums ----

license=('GPL')

sha256sums=(abd9c5c98abf1fdd11892ac2f8a56737544fe101e1be27c6241a564948f34c63) #  wireless_tools.30.pre9.tar.gz
