#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

###  ***  this is from staging rebuilt on icu from staging DO NOT USE YET *** ###

#pkgbase=libxml2
#pkgname=(libxml2 libxml2-docs)
pkgname=libxml2
pkgver=2.10.4
pkgrel=06
# mixup between jobcore and staging 4/22 rebuild on jobcore used staging PKGBUILD-arch
# so staging pkgrel is bumped up one to distinguish from jobcore's build
pkgdesc="XML C parser and toolkit"
url="https://gitlab.gnome.org/GNOME/libxml2/-/wikis/home"
depends=(zlib xz icu readline ncurses)
makedepends=(python git)
optdepends=('python: Python bindings')
provides=(libxml2.so)
#options=(debug)   ##  uncomment this to have the debug pkg produced
_commit=223cb03a5d27b1b2393b266a8657443d046139d6  # tags/v2.10.4^0
source=(
  "git+https://gitlab.gnome.org/GNOME/libxml2.git#commit=$_commit"
  0001-Fix-python3-unicode-errors.patch
  0002-HACK-Don-t-run-fuzzing-tests.patch
  https://www.w3.org/XML/Test/xmlts20130923.tar.gz
)

pkgver() {
  cd libxml2
  git describe --tags | sed 's/-rc/rc/;s/^v//;s/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd libxml2

  # Use xmlconf from conformance test suite
  ln -s ../xmlconf

  # https://gitlab.gnome.org/GNOME/libxml2/-/issues/64
  git apply -3 ../0001-Fix-python3-unicode-errors.patch
 
  # Do not run fuzzing tests
  git apply -3 ../0002-HACK-Don-t-run-fuzzing-tests.patch

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd libxml2

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --with-history \
    --with-python=/usr/bin/python \
    --with-icu \
    --with-threads \
    --disable-static
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd libxml2
  make check
}

#package_libxml2() {
package() {

  cd libxml2

  make DESTDIR="$pkgdir" install

  mkdir -p ../doc/usr/share
  mv "$pkgdir"/usr/share/{doc,gtk-doc} -t ../doc/usr/share

  install -Dm644 Copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}

#package_libxml2-docs() {
#  pkgdesc+=" (documentation)"
#  depends=()
#
#  mv doc/* "$pkgdir"
#}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

# license=(MIT) ... 2.9.14
license=(custom:MIT)  # 2.10.1

b2sums=('SKIP'
        'ec5a0955906c5fdd4bc65248bdb46f315460f4b2208bf37c49f55ef7468585786bdf563aa3e9357370d4f1ff947a6d4467869eeb2ca6b77ca5e40ffa45213a13'
        'ec247c8caad963307d8f487176fde518cfb087bbff3f10c2a5846b90a04c9909c2f0e6aaf8ded4784f46586eafb16df493caf1debc20ff10014f03b1f1f8241d'
        '63a47bc69278ef510cd0b3779aed729e1b309e30efa0015d28ed051cc03f9dfddb447ab57b07b3393e8f47393d15473b0e199c34cb1f5f746b15ddfaa55670be')

sha256sums=(SKIP
	161208f5f3ca000438c8d55d2f977bbd187205d2e70ce72b3fdbd59df4837a39  # 0001-Fix-python3-unicode-errors.patch
	4c426ffa9c8f397929ff575748fbed9a2db036033a3738d95c1d5309e666de59  # 0002-HACK-Don-t-run-fuzzing-tests.patch
	9b61db9f5dbffa545f4b8d78422167083a8568c59bd1129f94138f936cf6fc1f) # xmlts20130923.tar.gz

##  bfb32da211ceae95615a07a03da970ea8a6b6076f2aa7c6160acaecf9ffa71fd  libxml2-2.10.4-06-x86_64.pkg.tar.lz
bfb32da211ceae95615a07a03da970ea8a6b6076f2aa7c6160acaecf9ffa71fd  libxml2-2.10.4-06-x86_64.pkg.tar.lz
9b61db9f5dbffa545f4b8d78422167083a8568c59bd1129f94138f936cf6fc1f  xmlts20130923.tar.gz
