#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=keyutils
_tag='5678a1aae8834b5c16b5ed7dc72ef8836a29e122' # git rev-parse v${pkgver}
pkgver=1.6.3
pkgrel=02
pkgdesc='Linux Key Management Utilities'
url='https://www.kernel.org/'
depends=('glibc' 'sh')
makedepends=('git')
provides=('libkeyutils.so')
backup=('etc/request-key.conf')
source=("git+https://git.kernel.org/pub/scm/linux/kernel/git/dhowells/keyutils.git#tag=${_tag}?signed"
        'request-key.conf.patch' 'reproducible.patch')

prepare() {
  cd ${pkgname}
  # fix paths of binaries in /etc/request-key.conf
  patch -Np0 -i ../request-key.conf.patch

  # make keyutils reproducible
  patch -Np1 -i ../reproducible.patch
}

build() {
  cd ${pkgname}
  make CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" SBINDIR='/usr/bin' BINDIR='/usr/bin'
}

package() {
  cd ${pkgname}
  make DESTDIR="${pkgdir}" SBINDIR='/usr/bin' BINDIR='/usr/bin' LIBDIR='/usr/lib' USRLIBDIR='/usr/lib' install
}


#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('GPL2' 'LGPL2.1')

validpgpkeys=('A86E54B0D5E1B4E0AB7C640FFBB7576BA7CB0B6B') # David Howells <dhowells@redhat.com>

sha256sums=(SKIP
	203c602c61ed94ccd423a0a453d74143d678c641a9a4486367576ee8af2cb8d6 # request-key.conf.patch
	7bb7400b2b8c8f0288c86ec9191f8964a1e682745a204013d5fc7c2e1a253d8e) # reproducible.patch

##  94ea85d91380c044343b251d6e10ed3c475fefe193d0fbe8bbddadb5f0510dd8  keyutils-1.6.3-02-x86_64.pkg.tar.lz

94ea85d91380c044343b251d6e10ed3c475fefe193d0fbe8bbddadb5f0510dd8  keyutils-1.6.3-02-x86_64.pkg.tar.lz
