#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=bison
pkgver=3.8.2
pkgrel=06
pkgdesc="The GNU general-purpose parser generator"
url="https://www.gnu.org/software/bison/bison.html"
depends=('glibc' 'm4' 'sh' 'gettext')
source=("https://ftp.gnu.org/gnu/bison/${pkgname}-${pkgver}.tar.xz"{,.sig})

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  CFLAGS+=' -ffat-lto-objects' \
  ./configure --prefix=/usr --datadir=/usr/share
  make
}

check() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make check
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=('GPL3')

validpgpkeys=('7DF84374B1EE1F9764BBE25D0DDCAA3278D5264E')  # Akim Demaille

sha256sums=(9bba0214ccf7f1079c5d59210045227bcf619519840ebfa80cd3849cff5a5bf2 # bison-3.8.2.tar.xz
	aeff6fd7d7d7cad905ba3bc5228a2ccb95500c0f51fb4483e229c47c7c50f835) #  bison-3.8.2.tar.xz.sig


##  dbd5d4fe48b485bab83059f6515930e97e301840d08104af1c191d950602b14e  bison-3.8.2-06-x86_64.pkg.tar.lz
