#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=gdbm
pkgver=1.23
pkgrel=01
pkgdesc="GNU database library"
arch=(x86_64)
url="https://www.gnu.org/software/gdbm/gdbm.html"
depends=(glibc sh)
makedepends=(readline)
provides=(libgdbm_compat.so libgdbm.so)
#options=(debug)
source=("https://ftp.gnu.org/gnu/gdbm/$pkgname-$pkgver.tar.gz"{,.sig})

prepare() {
  cd $pkgname-$pkgver
  autoreconf -fiv
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
              --enable-libgdbm-compat
  make
}

check() {
  make check -C $pkgname-$pkgver
}

package() {
  depends+=(libreadline.so)

  make DESTDIR="$pkgdir" install -C $pkgname-$pkgver
  install -vDm 644 $pkgname-$pkgver/{NOTE-WARNING,AUTHORS,NEWS,README,ChangeLog} -t "$pkgdir/usr/share/doc/$pkgname"
}

#---- license gpg-key sha256sums ----

license=(GPL3)

validpgpkeys=('325F650C4C2B6AD58807327A3602B07F55D0C732') # Sergey Poznyakoff <gray@gnu.org>

sha256sums=(74b1081d21fff13ae4bd7c16e5d6e504a4c26f7cde1dca0d963a484174bbcacd # gdbm-1.23.tar.gz
	64ebb68cc68e8915d62cb20ea40323c00b56051f844589ee0a52169fff34cecb) #  gdbm-1.23.tar.gz.sig
