#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libnsl
pkgver=2.0.0
pkgrel=02
pkgdesc="Public client interface library for NIS(YP)"
arch=(x86_64)
url="https://github.com/thkukuk/libnsl"
depends=(glibc libtirpc)
provides=(libnsl.so)
#options=(debug)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")

prepare() {
  cd "$pkgname-$pkgver"
  autoreconf -fiv
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr --disable-static
  make
}

package() {
  make DESTDIR="$pkgdir" install -C $pkgname-$pkgver
  install -vDm 644 $pkgname-$pkgver/{AUTHORS,NEWS,README} -t "${pkgdir}/usr/share/doc/${pkgname}"
}

#---- license gpg-key sha256sums ----

license=('LGPL2.1')

sha256sums=(eb37be57c1cf650b3a8a4fc7cd66c8b3dfc06215b41956a16325a9388171bc40) #  libnsl-2.0.0.tar.gz

