#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=man-pages
_commit=324e1d8289644e5159d43a04945df0841c45b966 # 2022-10-09 =  6.00 release
pkgver=6.01
_posixver=2017-a
pkgrel=01
pkgdesc="Linux man pages"
arch=('any')
url="https://www.kernel.org/doc/man-pages/"
makedepends=('man2html' 'git')
# https://git.kernel.org/pub/scm/docs/man-pages/man-pages.git/
source=(https://www.kernel.org/pub/linux/docs/man-pages/$pkgname-$pkgver.tar.{xz,sign}
        #"git+https://git.kernel.org/pub/scm/docs/man-pages/man-pages#commit=$_commit" # no tarball release for 6.00
        https://www.kernel.org/pub/linux/docs/man-pages/man-pages-posix/$pkgname-posix-${_posixver}.tar.{xz,sign})
# https://www.kernel.org/pub/linux/docs/man-pages/sha256sums.asc

prepare() {
  cd "${srcdir}"/$pkgname-$pkgver
  
#  sed -i "s|prefix := /usr/local|prefix := /usr|g" Makefile

  # included in shadow
  rm man5/passwd.5
  rm man3/getspnam.3
  # included in tzdata
  rm man5/tzfile.5 man8/{tzselect,zdump,zic}.8
  # included in libxcrypt
  rm man3/crypt*.3
}

package() {
  cd "${srcdir}"/$pkgname-$pkgver

  # install man-pages
  make DESTDIR="${pkgdir}" prefix=/usr install 

  # install posix pages
  pushd "${srcdir}"/$pkgname-posix-${_posixver%-*}
  make DESTDIR="${pkgdir}" install 
  popd
  
  # posix pages have a custom license
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 "${srcdir}"/$pkgname-posix-${_posixver%-*}/POSIX-COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/POSIX-COPYRIGHT"
}

#---- license gpg-key sha256sums ----

license=('GPL' 'custom')

validpgpkeys=(E522595B52EDA4E6BFCCCB5E856199113A35CE5E) # Michael Kerrisk (Linux man-pages maintainer) <mtk.manpages@gmail.com>
validpgpkeys+=(A9348594CE31283A826FBDD8D57633D441E25BB5) # Alejandro Colomar Andres <alx.manpages@gmail.com>

sha256sums=(8be5177b2788c480a984517947d602ffaa64edeaed83edf4bd04f35163cb5c0b  # man-pages-6.01.tar.xz
	20cb1e37baa85263d02e5976f876f52f3973c3070113b87ecc197cd2211d981c  # man-pages-6.01.tar.sign
	ce67bb25b5048b20dad772e405a83f4bc70faf051afa289361c81f9660318bc3  # man-pages-posix-2017-a.tar.xz
	a754077b66853702059a7ae8ff520fadf42ab7484da6df991207343e8b7c5eff) # man-pages-posix-2017-a.tar.sign


