#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libgssglue
pkgver=0.7
pkgrel=01
pkgdesc="Exports a gssapi interface which calls other random gssapi libraries"
arch=('x86_64')
#url="https://www.citi.umich.edu/projects/nfsv4/linux/"
url="https://gitlab.com/gsasl/libgssglue/"
#options=(debug)  ##  uncomment this to have the debug pkg produced
depends=('glibc')
makedepends=('pkgconfig' 'autoconf')
backup=(etc/gssapi_mech.conf)
#source=(http://www.citi.umich.edu/projects/nfsv4/linux/$pkgname/$pkgname-$pkgver.tar.gz
#        gssapi_mech.conf)
source=(https://gitlab.com/gsasl/$pkgname/-/archive/$pkgname-$pkgver/$pkgname-$pkgname-$pkgver.tar.gz)

prepare() {
  cd $pkgname-$pkgname-$pkgver
  touch ChangeLog
  autoreconf -fiv
}

build() {
  cd $pkgname-$pkgname-$pkgver
  ./configure --prefix=/usr 
  make
}

package() {
  make DESTDIR="$pkgdir/" install -C $pkgname-$pkgname-$pkgver
  install -vDm 644 $pkgname-$pkgname-$pkgver/doc/gssapi_mech.conf -t "$pkgdir/etc/"
  install -vDm 644 $pkgname-$pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 $pkgname-$pkgname-$pkgver/{AUTHORS,README,NEWS} -t "$pkgdir/usr/share/doc/$pkgname/"
}

#---- license gpg-key sha256sums ----

license=('BSD')

sha256sums=(e741fec9c41d78f9d215f8b6aaaa5a0bd1f64f6e2715f09c1d2b0293e093eedb) # libgssglue-libgssglue-0.7.tar.gz
