#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libpcap
pkgver=1.10.1
pkgrel=02
pkgdesc='A system-independent interface for user-level packet capture - no ipv6'
arch=(x86_64)
url="https://www.tcpdump.org/"
depends=(glibc libnl sh)
makedepends=(bluez-libs dbus)
provides=(libpcap.so)
#options=(debug)
source=("https://www.tcpdump.org/release/${pkgname}-${pkgver}.tar.gz"{,.sig})

prepare() {
  cd $pkgname-$pkgver
  autoreconf -fiv
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
              --disable-ipv6 \
              --enable-bluetooth \
              --enable-usb \
              --with-libnl
  make
}

package() {
  depends+=('libdbus-1.so')
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 {CHANGES,{CONTRIBUTING,README}.md} -t "${pkgdir}/usr/share/doc/${pkgname}/"
}

#---- license gpg-key sha256sums ----

license=('BSD')

validpgpkeys=('1F166A5742ABB9E0249A8D30E089DEF1D9C15D0D') # The Tcpdump Group

sha256sums=(ed285f4accaf05344f90975757b3dbfe772ba41d1c401c2648b7fa45b711bdd4 # libpcap-1.10.1.tar.gz
	7c85dad0244778e67e421603bfb98b91515c94702ad798a8348733add68fe7c7) # libpcap-1.10.1.tar.gz.sig
