#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=flex
pkgver=2.6.4
pkgrel=03
pkgdesc="A tool for generating text-scanning programs"
arch=('x86_64')
url="https://github.com/westes/flex"
groups=( jobbot )
depends=('glibc' 'm4' 'sh')
makedepends=('help2man')
source=("https://github.com/westes/flex/releases/download/v$pkgver/flex-$pkgver.tar.gz"{,.sig}
        "flex-pie.patch")

prepare() {
  cd "$pkgname-$pkgver"
  patch -p1 -i "$srcdir"/flex-pie.patch
  autoreconf
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr
  make
}

check() {
  cd "$pkgname-$pkgver"

  # cxx_restart fails - https://github.com/westes/flex/issues/98
  make -k check || true
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
  ln -s flex "${pkgdir}/usr/bin/lex"

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/license.txt"
}


#---- license gpg-key sha256sums ----

license=('custom')

validpgpkeys=('56C67868E93390AA1039AD1CE4B29C8D64885307') # Will Estes

sha256sums=(e87aae032bf07c26f85ac0ed3250998c37621d95f8bd748b31f15b33c45ee995 # flex-2.6.4.tar.gz
	c61ccc11286e1eb2ceeb0f0a8f8437e86f1e41840991566351f438de7eb5a9a2  #flex-2.6.4.tar.gz.sig
	20f3cce6b0ea6ab67a902a46b89c292b959994dedcbe6ee5d187f9bba1408b0e) # flex-pie.patch
