#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=net-tools
pkgver=2.10
pkgrel=01
pkgdesc="Configuration tools for Linux networking"
arch=('x86_64')
url="http://net-tools.sourceforge.net/"
depends=('glibc')
source=("https://downloads.sourceforge.net/project/net-tools/$pkgname-$pkgver.tar.xz")
options=(!makeflags)

build() {
  cd ${pkgname}-${pkgver}
  export BINDIR='/usr/bin' SBINDIR='/usr/bin'
  yes "" | make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  # the following is provided by yp-tools
  rm "${pkgdir}"/usr/bin/{nis,yp}domainname
  # hostname is provided by inetutils
  rm "${pkgdir}"/usr/bin/{hostname,dnsdomainname,domainname}
  rm -r "${pkgdir}"/usr/share/man/man1
}

#---- license gpg-key sha256sums ----

license=('GPL2')

sha1sums=('4080baab0486dc882c3b293d5559c27251ae4268')

sha256sums=(b262435a5241e89bfa51c3cabd5133753952f7a7b7b93f32e08cb9d96f580d69) # net-tools-2.10.tar.xz
