# Maintainer: Eric Vidal <eric@obarun.org>

pkgname=s6-networking
pkgver=2.5.0.0
pkgrel=1
pkgdesc="Small network and client-server tools"
arch=(x86_64)
url="http://skarnet.org/software/s6/"
license=('ISC')
makedepends=('git' 'skalibs>=2.11.0.0' 'execline>=2.8.1.0' 's6>=2.11.0.0' 's6-dns>=2.3.5.2' )
depends=('skalibs>=2.11.0.0' 'execline>=2.8.1.0' 's6>=2.11.0.0' 's6-dns>=2.3.5.2' )
#optdepends=('libressl: For build a secure communication tools')
groups=(s6-suite)
#_commit=61da214808d289f1521a5bd421e105828229b818 # tag 2.3.0.2
#source=("$pkgname::git+git://git.skarnet.org/s6-networking#commit=$_commit")
source=("$pkgname::git+git://git.skarnet.org/s6-networking#tag=v${pkgver}")
sha256sums=('SKIP')

#pkgver() {
#  cd $pkgbase
#  git describe --tags | sed 's/-/+/g'
#}

build() {
  cd ${srcdir}/${pkgname}
  ./configure --prefix=/usr \
              --bindir=/usr/bin \
              --sbindir=/usr/bin \
              --datadir=/etc \
              --disable-shared \
              --with-lib=/usr/lib/skalibs \
              --with-lib=/usr/lib/s6 \
              --with-lib=/usr/lib/s6-dns
  make
}

package() {
  cd ${srcdir}/${pkgname}

  DESTDIR=${pkgdir} make install

  # add doc
  install -dm 0755 $pkgdir/usr/share/doc/$pkgname/
  cp -R doc/* $pkgdir/usr/share/doc/$pkgname/

  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

}

