#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

##  rebuild after any libbpf upgrade ##
pkgname=iproute2
pkgver=6.0.0
pkgrel=01
pkgdesc='IP Routing Utilities'
arch=('x86_64')
url='https://git.kernel.org/pub/scm/network/iproute2/iproute2.git'
depends=('glibc' 'iptables' 'libelf' 'libbpf')
optdepends=('db: userspace arp daemon'
            'libcap: tipc'
            'linux-atm: ATM support')
provides=('iproute')
backup=('etc/iproute2/bpf_pinning'
	'etc/iproute2/ematch_map'
	'etc/iproute2/group'
	'etc/iproute2/nl_protos'
	'etc/iproute2/rt_dsfield'
	'etc/iproute2/rt_protos' 
	'etc/iproute2/rt_realms' 
	'etc/iproute2/rt_scopes' 
	'etc/iproute2/rt_tables')

makedepends=('linux-atm' 'bison' 'gettext')
#options=('staticlibs' 'debug') ##  uncomment this and comment the following to have the debug pkg produced
options=('staticlibs')
source=("https://www.kernel.org/pub/linux/utils/net/${pkgname}/${pkgname}-${pkgver}.tar."{xz,sign}
        '0001-make-iproute2-fhs-compliant.patch')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # set correct fhs structure
  patch -Np1 -i "${srcdir}"/0001-make-iproute2-fhs-compliant.patch
  # do not treat warnings as errors
  sed -i 's/-Werror//' Makefile
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  export CFLAGS+=' -ffat-lto-objects'

  ./configure
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" SBINDIR="/usr/bin" install

  # libnetlink isn't installed, install it FS#19385
  install -Dm0644 include/libnetlink.h "${pkgdir}/usr/include/libnetlink.h"
  install -Dm0644 lib/libnetlink.a "${pkgdir}/usr/lib/libnetlink.a"
}

#---- license gpg-key sha256sums ----

license=('GPL2')

validpgpkeys=('9F6FC345B05BE7E766B83C8F80A77F6095CDE47E') # Stephen Hemminger

sha256sums=(523139e9e72aec996374fa2de74be4c53d2dd05589488934d21ff97bae19580a # iproute2-6.0.0.tar.xz
	391efc43ca1b2748d687c94b5bda47d874efa4ba82a565daa9c1f396c309591b # iproute2-6.0.0.tar.sign
	758b82bd61ed7512d215efafd5fab5ae7a28fbfa6161b85e2ce7373285e56a5d) #  0001-make-iproute2-fhs-compliant.patch


