#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=lzo
pkgver=2.10
pkgrel=03
pkgdesc="Portable lossless data compression library"
arch=('x86_64')
url="https://www.oberhumer.com/opensource/lzo"
depends=('glibc')
source=(https://www.oberhumer.com/opensource/lzo/download/lzo-${pkgver}.tar.gz)

build() {
  cd lzo-${pkgver}
  ./configure --prefix=/usr --enable-shared
  make

  # build minilzo
  gcc $CPPFLAGS $CFLAGS -fpic -Iinclude/lzo -o minilzo/minilzo.o -c minilzo/minilzo.c
  gcc $LDFLAGS -shared -o libminilzo.so.0 -Wl,-soname,libminilzo.so.0 minilzo/minilzo.o
}

check() {
  cd lzo-${pkgver}
  make test # Larger test
  make check
}

package() {
  cd lzo-${pkgver}
  make DESTDIR="${pkgdir}" install

  # install minilzo
  install -m 755 libminilzo.so.0 "${pkgdir}"/usr/lib
  install -p -m 644 minilzo/minilzo.h ${pkgdir}/usr/include/lzo
  cd "${pkgdir}"/usr/lib
  ln -s libminilzo.so.0 libminilzo.so
}

#---- license gpg-key sha256sums ----

license=('GPL')

sha256sums=(c0f892943208266f9b6543b3ae308fab6284c5c90e627931446fb49b4221a072) #  lzo-2.10.tar.gz
