#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/attr"
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=attr
pkgver=2.5.1
pkgrel=02
pkgdesc='Extended attribute support library for ACL support'
arch=('x86_64')
url='https://savannah.nongnu.org/projects/attr'
depends=('glibc')
makedepends=('gettext')
replaces=('xfsattr')
provides=('xfsattr' 'libattr.so')
#options=('debug')
conflicts=('xfsattr')
backup=('etc/xattr.conf')
source=("https://download.savannah.gnu.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.xz"{,.sig})

build() {
  cd $pkgname-$pkgver

  ./configure \
    --libdir=/usr/lib \
    --libexecdir=/usr/lib \
    --prefix=/usr \
    --sysconfdir=/etc
  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="${pkgdir}" install
}

#---- license gpg-key sha256sums ----

license=('LGPL')

validpgpkeys=('600CD204FBCEA418BD2CA74F154343260542DF34'  # Brandon Philips <brandon@ifup.co>
              'B902B5271325F892AC251AD441633B9FE837F581'  # Frysinger <vapier@gentoo.org>
              '259B3792B3D6D319212CC4DCD5BF9FEB0313653A') # Andreas Gruenbacher <andreas.gruenbacher@gmail.com>

sha256sums=(db448a626f9313a1a970d636767316a8da32aede70518b8050fa0de7947adc32 # attr-2.5.1.tar.xz
	31357441f6fe2e8e8ab9c36746b2d3885d153dc88b33930c62eefed12f800954) # attr-2.5.1.tar.xz.sig
