#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=wpa_supplicant
pkgver=2.10
pkgrel=07
epoch=2
pkgdesc='A utility providing key negotiation for WPA wireless networks w/o systemd'
url='https://w1.fi/wpa_supplicant/'
arch=(x86_64)
depends=(openssl libdbus readline libnl)
backup=('etc/wpa_supplicant/wpa_supplicant.conf')
source=( https://w1.fi/releases/${pkgname}-${pkgver}.tar.gz{,.asc}
  wpa_supplicant_tls.patch                        # More permissive TLS fallback
#  wpa_supplicant_dbus_service_syslog.patch        # Unit improvements from Ubuntu
#  wpa_supplicant_service_ignore-on-isolate.patch  # More unit improvements from Ubuntu
  wpa_supplicant-legacy-server-connect.patch
  lower_security_level_for_tls_1.patch
  wpa_supplicant_config
  add_extra-ies_only_if_allowed_by_driver.patch
)

prepare() {
  cd $pkgname-$pkgver
  patch -p1 -i ../wpa_supplicant_tls.patch                        # More permissive TLS fallback
#  patch -p1 -i ../wpa_supplicant_dbus_service_syslog.patch        # Unit improvements from Ubuntu
#  patch -p1 -i ../wpa_supplicant_service_ignore-on-isolate.patch  # More unit improvements from Ubuntu
  # https://bugzilla.redhat.com/show_bug.cgi?id=2072070#c24
  patch -Np1 -i ../wpa_supplicant-legacy-server-connect.patch

  # http://lists.infradead.org/pipermail/hostap/2022-May/040571.html
  # https://bugs.archlinux.org/task/76474
  patch -Np1 -i ../lower_security_level_for_tls_1.patch

  # http://lists.infradead.org/pipermail/hostap/2022-January/040178.html
  patch -Np1 -i ../add_extra-ies_only_if_allowed_by_driver.patch

  cd $pkgname
  cp "$srcdir/wpa_supplicant_config" ./.config
}

build() {
  cd $pkgname-$pkgver/$pkgname

  make LIBDIR=/usr/lib BINDIR=/usr/bin
  make LIBDIR=/usr/lib BINDIR=/usr/bin eapol_test
}

package() {
  cd $pkgname-$pkgver/$pkgname

  make LIBDIR=/usr/lib BINDIR=/usr/bin DESTDIR="$pkgdir" install

  install -Dm755 eapol_test "$pkgdir/usr/bin/eapol_test"

  install -dm755 "$pkgdir/etc/wpa_supplicant"
  install -Dm644 wpa_supplicant.conf -t "$pkgdir/usr/share/doc/wpa_supplicant"
  install -Dm644 wpa_supplicant.conf "$pkgdir/etc/wpa_supplicant/wpa_supplicant.conf.pacnew"

#  install -Dm644 dbus/fi.w1.wpa_supplicant1.service \
#    -t "$pkgdir/usr/share/dbus-1/system-services"

#  install -Dm644 dbus/dbus-wpa_supplicant.conf \
#    "$pkgdir/usr/share/dbus-1/system.d/wpa_supplicant.conf"

#  install -d -m755 "$pkgdir/usr/share/man/man"{5,8}
  install -Dm644 doc/docbook/*.5 -t "$pkgdir/usr/share/man/man5"
  install -Dm644 doc/docbook/*.8 -t "$pkgdir/usr/share/man/man8"
#  rm "$pkgdir"/usr/share/man/man8/wpa_{priv,gui}.8
}

#---- license gpg-key sha256sums ----

license=(GPL)

validpgpkeys=('EC4AA0A991A5F2464582D52D2B6EF432EFC895FA') # Jouni Malinen

sha256sums=(20df7ae5154b3830355f8ab4269123a87affdea59fe74fe9292a91d0d7e17b2f  # wpa_supplicant-2.10.tar.gz
	5512ef486877b231fe4eef3240c2aec9bfb671c1fe2ceb4e5d9ac1f17caddfac  # wpa_supplicant-2.10.tar.gz.asc
	08915b040d03a3e07cdc8ea6c76b497e00059e01ce85b67413dfe41d4fc68992  # wpa_supplicant_tls.patch
#	60f6a1cf2e124813dfce1da78ee1818e2ff5236aafa4113c7ae3b3f2a0b84006  # wpa_supplicant_dbus_service_syslog.patch
#	d42bdbf3d4980b9f0a819612df0c39843c7e96c8afcb103aa656c824f93790b0  # wpa_supplicant_service_ignore-on-isolate.patch
	8fba11e4a5056d9e710707ded93341f61fdfef6c64ced992e3936cbd2d41a011  # wpa_supplicant-legacy-server-connect.patch
	c3c0fb363f734c1512d24fd749b3ff7515f961b27bfadd04c128434b5c9f4a93  # lower_security_level_for_tls_1.patch
	89dc439b958574e9231c58bea6c83faec469909c9f84476bfc83fa35b3e97bd1  # wpa_supplicant_config
	aaedf87f1530d4e6cb00bf7981d1f868409ed892cc41b83c5613019e7b51f380) # add_extra-ies_only_if_allowed_by_driver.patch


