#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=logrotate
pkgver=3.20.1
pkgrel=01
pkgdesc="Rotates system logs automatically w/o systemd"
arch=('x86_64')
url="https://github.com/logrotate/logrotate"
depends=('popt' 'gzip' 'acl')
backup=('etc/logrotate.conf')
source=("https://github.com/logrotate/logrotate/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.xz"{,.asc}
        'logrotate.conf')

build() {
	cd "$srcdir/${pkgname}-${pkgver}"

	./configure \
		--prefix=/usr \
		--sbindir=/usr/bin \
		--mandir=/usr/share/man \
		--with-compress-command=/usr/bin/gzip \
		--with-uncompress-command=/usr/bin/gunzip \
		--with-default-mail-command=/usr/bin/mail \
		--with-acl
	make
}

check() {
	cd "$srcdir/${pkgname}-${pkgver}"

	make test
}

package() {
	cd "$srcdir/${pkgname}-${pkgver}"

	make DESTDIR="$pkgdir" install

	install -dm755 "$pkgdir/etc/logrotate.d"
	install -Dm644 "$srcdir/logrotate.conf" "$pkgdir/etc/logrotate.conf"

}

#---- license gpg-key sha256sums ----

license=('GPL')

validpgpkeys=('992A96E075056E79CD8214F9873DB37572A37B36')

sha256sums=(742f6d6e18eceffa49a4bacd933686d3e42931cfccfb694d7f6369b704e5d094 # logrotate-3.20.1.tar.xz
	c63c03c2db626209a1be2653d34ecd1eb6b3aee8da6dc17ab60ae32ef64bc8f2 # logrotate-3.20.1.tar.xz.asc
	42e289081a4d6b144c89dbfc49bde7a01b383055bf90a05a764f8c3dee25a6ce) # logrotate.conf


