#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=patch
pkgver=2.7.6
pkgrel=08
pkgdesc='A utility to apply patch files to original sources'
arch=('x86_64')
url='https://www.gnu.org/software/patch/'
groups=( jobbot )
depends=('glibc' 'attr')
makedepends=('ed' 'autoconf' 'automake')
optdepends=('ed: for patch -e functionality')
source=("https://ftp.gnu.org/gnu/$pkgname/$pkgname-$pkgver.tar.xz"{,.sig}
        'https://github.com/mirror/patch/commit/f290f48a621867084884bfff87f8093c15195e6a.patch' # CVE-2018-6951
        'https://github.com/mirror/patch/commit/b5a91a01e5d0897facdd0f49d64b76b0f02b43e1.patch'
        'https://github.com/mirror/patch/commit/123eaff0d5d1aebe128295959435b9ca5909c26d.patch' # CVE-2018-1000156
        'https://github.com/mirror/patch/commit/3fcd042d26d70856e826a42b5f93dc4854d80bf0.patch'
        '19599883ffb6a450d2884f081f8ecf68edbed7ee.patch' # Fix memory leaks introduced in CVE-2018-1000165
        'https://github.com/mirror/patch/commit/369dcccdfa6336e5a873d6d63705cfbe04c55727.patch'
        'https://github.com/mirror/patch/commit/9c986353e420ead6e706262bf204d6e03322c300.patch' # CVE-2018-6952
        )

prepare() {
  cd $pkgname-$pkgver
  # apply patch from the source array (should be a pacman feature)
  local src
  for src in "${source[@]}"; do
    src="${src%%::*}"
    src="${src##*/}"
    [[ $src = *.patch ]] || continue
    msg2 "Applying patch $src..."
    patch -Np1 < "../$src"
  done
  autoreconf -fiv
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}

#---- license gpg-key sha256sums ----

license=('GPL')

validpgpkeys=('259B3792B3D6D319212CC4DCD5BF9FEB0313653A') # Andreas Gruenbacher

sha256sums=(ac610bda97abe0d9f6b7c963255a11dcb196c25e337c61f94e4778d632f1d8fd # patch-2.7.6.tar.xz
	2398352147c006e0737430247960d1c75ce33377a3278023cdc34ebd4a810cd9 # patch-2.7.6.tar.xz.sig
	38d28c34524c6ac4585d47e0fe8349508e9e4b014872798cb2bf2bc48e5af2d4 # f290f48a621867084884bfff87f8093c15195e6a.patch
	b7829673090bcd74110ac040cc6e503113ef770e48d34758c04418cf9c8bfa87 # b5a91a01e5d0897facdd0f49d64b76b0f02b43e1.patch
	9158cb3cd4bed0c4fe5a7f1254e0e2642e0ad583dc8b5df8ee296a13d695270d # 123eaff0d5d1aebe128295959435b9ca5909c26d.patch
	473f8a7fa8152a3c7803633e2a3072dab545b74377ea618451ceda4283643364 # 3fcd042d26d70856e826a42b5f93dc4854d80bf0.patch
	6d64a8b8ddfb802ec0aa804388eb5ef51ac808c7a5c111d10490c270eb4fe727 # 19599883ffb6a450d2884f081f8ecf68edbed7ee.patch
	e1fc8a8aa2cad71b2a6207241ea71a33a7e3dacb8533ad54af35170c5a6562d1 # 369dcccdfa6336e5a873d6d63705cfbe04c55727.patch
	4b9e81985ca057fa39daed34a4710eb113f08b3d1ce77a7121ddd8e3fae8007a) #  9c986353e420ead6e706262bf204d6e03322c300.patch
