#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=openssh
pkgver=9.1p1
pkgrel=03
pkgdesc='SSH protocol implementation for remote login, command execution and file transfer w/o systemd'
arch=('x86_64')
url='https://www.openssh.com/portable.html'
depends=(
	'glibc'
	'krb5'
	'ldns'
	'libedit'
	'libxcrypt'
	'openssl'
	'pam'
	'zlib')
makedepends=(linux-lts-headers libfido2 autoconf automake)
optdepends=(
	'libfido2: FIDO/U2F support'
	'x11-ssh-askpass: input passphrase in X'
	'xorg-xauth: X11 forwarding')
# old source
#source=("git://anongit.mindrot.org/openssh.git?signed#tag=V_8_2_P1"
backup=('etc/ssh/ssh_config' 'etc/ssh/sshd_config' 'etc/pam.d/sshd')

#options=('debug')   ## uncomment this to have the debug pkg produced
source=("https://ftp.openbsd.org/pub/OpenBSD/OpenSSH/portable/${pkgname}-${pkgver}.tar.gz"{,.asc}
	"$pkgname-9.0p1-sshd_config.patch"
	'sshd.conf'
	'sshd.pam')


#install=install   ### systemd autostart crap 

prepare() {
  patch -Np1 -d "$pkgname-$pkgver" -i ../$pkgname-9.0p1-sshd_config.patch
}

#prepare() {
#	cd "${srcdir}/${pkgname}-${pkgver}"
#	#  patch goes here
#	patch -p1 -i ../glibc-2.31.patch
#
#	autoreconf
#}

build() {
	cd "${pkgname}-${pkgver}"

	./configure \
		--prefix=/usr \
		--sbindir=/usr/bin \
		--libexecdir=/usr/lib/ssh \
		--sysconfdir=/etc/ssh \
		--disable-strip \
		--with-ldns \
		--with-libedit \
		--with-security-key-builtin \
		--with-ssl-engine \
		--with-pam \
		--with-privsep-user=nobody \
		--with-kerberos5=/usr \
		--with-xauth=/usr/bin/xauth \
		--with-pid-dir=/run \
		--with-default-path='/usr/local/sbin:/usr/local/bin:/usr/bin'

	make
}

check() {
	cd "${pkgname}-${pkgver}"
  # NOTE: make t-exec does not work in our build environment
  make file-tests interop-tests unit
}

package() {
	cd "${pkgname}-${pkgver}"

	make DESTDIR="${pkgdir}" install

	ln -sf ssh.1.gz "${pkgdir}"/usr/share/man/man1/slogin.1.gz
	install -Dm644 LICENCE -t "${pkgdir}/usr/share/licenses/${pkgname}/LICENCE"

#	install -Dm644 ../sshdgenkeys.service -t "${pkgdir}"/usr/lib/systemd/system/sshdgenkeys.service
#	install -Dm644 ../sshd.service -t "${pkgdir}"/usr/lib/systemd/system/sshd.service
	install -Dm644 ../sshd.conf -t "${pkgdir}"/usr/lib/tmpfiles.d/sshd.conf
	install -Dm644 ../sshd.pam "${pkgdir}"/etc/pam.d/sshd

	install -Dm755 contrib/findssl.sh -t "${pkgdir}"/usr/bin/findssl.sh
	install -Dm755 contrib/ssh-copy-id -t "${pkgdir}"/usr/bin/ssh-copy-id
	install -Dm644 contrib/ssh-copy-id.1 -t "${pkgdir}"/usr/share/man/man1/ssh-copy-id.1

}

#---- license gpg-key sha256sums ----

license=('custom:BSD')

validpgpkeys=('7168B983815A5EEF59A4ADFD2A3F414E736060BA') # "Damien Miller <djm@mindrot.org>"

sha256sums=(19f85009c7e3e23787f0236fbb1578392ab4d4bf9f8ec5fe6bc1cd7e8bfdd288 # openssh-9.1p1.tar.gz
	abac4673e0862604ab1f69a4597d191940c0cf58679dc5fc81fbdbd8b28ca267 # openssh-9.1p1.tar.gz.asc
	27e43dfd1506c8a821ec8186bae65f2dc43ca038616d6de59f322bd14aa9d07f # openssh-9.0p1-sshd_config.patch
	4effac1186cc62617f44385415103021f72f674f8b8e26447fc1139c670090f6 # sshd.conf
	64576021515c0a98b0aaf0a0ae02e0f5ebe8ee525b1e647ab68f369f81ecd846) # sshd.pam

