#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: http://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=base
pkgver=10.0
pkgrel=02
pkgdesc='Minimal set of packages to define a basic JOBORun Linux installation'
url='http://pozol.eu'
groups=( jobbase )
arch=(x86_64)
source=( README.txt )

optdepends=('linux-lts: recommended kernel'
	'linux: alternative latest lts kernel'
	's6-suite: s6 and 66 system and basic booting necessities'
	'grub: bootloader capable of a multiboot system of various OSes'
	'syslinux: alternative bootloader lighter than grub' )

makedepends=('sh' 'glibc')

package() {

  depends=(
	# very very core
	'filesystem' 'gcc-libs' 'glibc' 'bash'

	# distro defined requirements
	'licenses' 'pacman' 'nano' 'zsh' 'jobo-setup' 'arch-install-scripts'

	# keyrings GnuPG keys of repo and pkg signatures
	'archlinux-keyring' 'obarun-keyring' 'joborun-keyring'

	# POSIX tools
	'coreutils' 'file' 'findutils' 'gawk' 'grep' 'procps-ng' 'sed' 'tar'

	# standard linux toolset
	'pciutils' 'psmisc' 'shadow' 'util-linux' 'bzip2' 'gzip' 'xz' 'sudo'

	# init, service supervisors, mdev
	'runit' 'runit-rc' 'joborun66' 'eudev'
	
	# networking, ping, etc
	'inetutils' 'iputils' 'iproute2' 'net-tools' 'dhclient' 'wpa_supplicant' 'ntp'
	
	# service scripts - no dependencies
	'runit-service-scripts'

	# fonts for console
	'terminus-font'
  )

  cd "$pkgdir"
  mkdir -m777 "$pkgdir"/src
  install -Dm644 "$srcdir"/README.txt "$pkgdir"/src/README.txt
}

#---- license gpg-key sha256sums ----

license=('ISC')

sha256sums=(cf5a5b593698d38b717e4c4274c6a1dd6a5b1c93e03b826bbbc18b6872f79c9f) #  README.txt


