#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libnl
pkgver=3.7.0
pkgrel=01
pkgdesc='Library for applications dealing with netlink sockets'
arch=(x86_64)
url='https://github.com/thom311/libnl/'
depends=(glibc)
#options=('debug') # uncomment this to produce the debug package for libnl
makedepends=(bison)
backup=(etc/libnl/classid 
	etc/libnl/pktloc)
source=(https://github.com/thom311/libnl/releases/download/libnl${pkgver//./_}/${pkgname}-${pkgver}.tar.gz{,.sig})

build() {
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --sbindir=/usr/bin \
    --disable-ipv6 \
    --disable-static
  make
}

check() {
  make -C $pkgname-$pkgver check
}

package() {
  make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
}

#---- license gpg-key sha256sums ----

license=(GPL)

validpgpkeys=('49EA7C670E0850E7419514F629C2366E4DFC5728') # Thomas Haller

sha256sums=(9fe43ccbeeea72c653bdcf8c93332583135cda46a79507bfd0a483bb57f65939 # libnl-3.7.0.tar.gz
	abdf098b3a7802a1e77086e5f92835ad25a2da6a59a05d6a5a086d66a323bffc) # libnl-3.7.0.tar.gz.sig
