jobcore/gettext/PKGBUILD-arch

60 lines
1.5 KiB
Text
Raw Normal View History

2022-03-20 13:19:37 +01:00
# Maintainer:
pkgname=gettext
2023-07-02 18:39:47 +02:00
pkgver=0.22
pkgrel=1
2022-03-20 13:19:37 +01:00
pkgdesc="GNU internationalization library"
url="https://www.gnu.org/software/gettext/"
arch=(x86_64)
license=(GPL)
2023-04-01 11:22:02 +02:00
depends=(gcc-libs acl sh libunistring libxml2)
makedepends=(gettext emacs git)
2022-03-20 13:19:37 +01:00
optdepends=('git: for autopoint infrastructure updates')
options=(!docs)
source=(https://ftp.gnu.org/pub/gnu/gettext/$pkgname-$pkgver.tar.gz{,.sig}
2023-07-02 18:39:47 +02:00
gettext-0.22-disable-libtextstyle.patch)
sha256sums=('49f089be11b490170bbf09ed2f51e5f5177f55be4cc66504a5861820e0fb06ab'
2022-03-20 13:19:37 +01:00
'SKIP'
2023-07-02 18:39:47 +02:00
'd751adc12a1f1d0b7556b1045f0f427b11345242f2a245542d8baade74177f97')
2022-03-20 13:19:37 +01:00
validpgpkeys=('462225C3B46F34879FC8496CD605848ED7E69871' # Daiki Ueno
'68D94D8AAEEAD48AE7DC5B904F494A942E4616C2'
'9001B85AF9E1B83DF1BDA942F5BE8B267C6A406D') # Bruno Haible (Open Source Development)
prepare() {
cd $pkgname-$pkgver
# Do not build libtextstyle, as it depends on libcroco
# which is now unmaintained and has known security bugs.
# patch from Fedora
2023-07-02 18:39:47 +02:00
patch -p1 -i $srcdir/gettext-0.22-disable-libtextstyle.patch
2022-03-20 13:19:37 +01:00
}
build() {
cd $pkgname-$pkgver
autoreconf --force
./configure \
--prefix=/usr \
--enable-csharp \
--enable-nls \
--with-xz \
--without-included-gettext
sed -e 's/ -shared / -Wl,-O1,--as-needed\0/g' \
-i gettext-{tools,runtime,runtime/libasprintf}/libtool
make
}
check() {
cd $pkgname-$pkgver
make check
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}