#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobcore/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libisl
pkgver=0.24
pkgrel=04
pkgdesc='Library for manipulating sets and relations of integer points bounded by linear constraints'
arch=('x86_64')
url='https://libisl.sourceforge.io'
depends=('gmp')
provides=('isl' 'libisl.so')
replaces=('isl')
options=(staticlibs)
source=("https://libisl.sourceforge.io/isl-${pkgver}.tar.xz")

build() {
  cd "${srcdir}"/${pkgname#lib}-${pkgver}
  ./configure --prefix=/usr
  make
}

check() {
  cd "${srcdir}"/${pkgname#lib}-${pkgver}
  make check || true
}

package() {
  cd "${srcdir}"/${pkgname#lib}-${pkgver}

  make DESTDIR="${pkgdir}" install

  install -dm755 "${pkgdir}"/usr/share/gdb/auto-load/usr/lib/
  mv "${pkgdir}"/usr/lib/libisl.so.*-gdb.py "${pkgdir}"/usr/share/gdb/auto-load/usr/lib/
  
  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}

#---- license gpg-key sha256sums ----

license=('MIT')

b2sums=('39cbfd18ad05778e3a5a44429261b45e4abc3efe7730ee890674d968890fe5e52c73bc1f8d271c7c3bc72d5754e3f7fcb209bd139e823d19cb9ea4ce1440164d')

sha256sums=(043105cc544f416b48736fff8caf077fb0663a717d06b1113f16e391ac99ebad) # isl-0.24.tar.xz