49 lines
1.4 KiB
Plaintext
49 lines
1.4 KiB
Plaintext
# Maintainer: David Runge <dvzrv@archlinux.org>
|
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
|
|
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
|
|
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
|
|
# Contributor: Jan de Groot <jgc@archlinux.org>
|
|
|
|
pkgname=libffi
|
|
pkgver=3.4.6
|
|
pkgrel=1
|
|
pkgdesc='Portable foreign function interface library'
|
|
arch=(x86_64)
|
|
url='https://sourceware.org/libffi/'
|
|
license=(MIT)
|
|
depends=(glibc)
|
|
checkdepends=(dejagnu)
|
|
provides=(libffi.so)
|
|
source=(https://github.com/libffi/libffi/releases/download/v$pkgver/libffi-$pkgver.tar.gz)
|
|
sha256sums=('b0dea9df23c863a7a50e825440f3ebffabd65df1497108e5d437747843895a4e')
|
|
b2sums=('af8402a09bdbd59b4e9400d2d71bd5ce98f6f1d981d35d1ab40d77a831b13b32c5bd34ca54ff75999e39f0d8a9c066381fae7a8d6c5216d955e064f929f08b88')
|
|
|
|
build() {
|
|
local configure_options=(
|
|
# remove --disable-exec-static-tramp once ghc and gobject-introspection
|
|
# work fine with it enabled (https://github.com/libffi/libffi/pull/647)
|
|
--disable-exec-static-tramp
|
|
--disable-multi-os-directory
|
|
--disable-static
|
|
--enable-pax_emutramp
|
|
--prefix=/usr
|
|
)
|
|
|
|
cd $pkgname-$pkgver
|
|
./configure "${configure_options[@]}"
|
|
make
|
|
}
|
|
|
|
check() {
|
|
make -C $pkgname-$pkgver check
|
|
}
|
|
|
|
package() {
|
|
cd $pkgname-$pkgver
|
|
make DESTDIR="$pkgdir" install
|
|
install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
|
|
install -Dm 644 README.md -t "$pkgdir"/usr/share/doc/$pkgname
|
|
}
|
|
|
|
# vim:set ts=2 sw=2 et:
|