39 lines
1.3 KiB
Plaintext
39 lines
1.3 KiB
Plaintext
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
|
|
# Contributor: Gaetan Bisson <bisson@archlinux.org>
|
|
# Contributor: Vesa Kaihlavirta <vesa@archlinux.org>
|
|
# Contributor: Roman Cheplyaka <roma@ro-che.info>
|
|
|
|
pkgname=libedit
|
|
_pkgver=20210910-3.1
|
|
pkgver=${_pkgver/-/_}
|
|
pkgrel=2
|
|
pkgdesc='Command line editor library providing generic line editing, history, and tokenization functions'
|
|
url='https://thrysoee.dk/editline/'
|
|
arch=('x86_64')
|
|
license=('BSD')
|
|
depends=('glibc' 'ncurses' 'libncursesw.so')
|
|
provides=('libedit.so')
|
|
options=('debug')
|
|
source=(${url}/${pkgname}-${_pkgver}.tar.gz)
|
|
sha256sums=('6792a6a992050762edcca28ff3318cdb7de37dccf7bc30db59fcd7017eed13c5')
|
|
b2sums=('325dc756fc6c6244e336cd6faeed2ab37817bdab8c0684586c44d551074fd2ec84bfcd3f4d5897db3196e783653a042699e5b9a8a3351d653992bb256956b652')
|
|
|
|
build() {
|
|
cd ${pkgname}-${_pkgver}
|
|
./configure --prefix=/usr
|
|
make V=1
|
|
}
|
|
|
|
package() {
|
|
cd ${pkgname}-${_pkgver}
|
|
make DESTDIR="${pkgdir}" install
|
|
|
|
rm "${pkgdir}"/usr/share/man/man3/history.3 # conflicts with readline
|
|
install -Dm 644 "${pkgdir}"/usr/share/man/man3/editline.3 "${pkgdir}"/usr/share/man/man3/el.3
|
|
|
|
install -Dm 644 ChangeLog -t "${pkgdir}/usr/share/doc/${pkgname}"
|
|
install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
|
|
}
|
|
|
|
# vim:set sw=2 sts=-1 et:
|