54 lines
2.0 KiB
Plaintext
54 lines
2.0 KiB
Plaintext
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
|
|
|
|
pkgname=tzdata
|
|
pkgver=2023c
|
|
_tzcode=2023c
|
|
_tzdata=2023c
|
|
pkgrel=2
|
|
pkgdesc="Sources for time zone and daylight saving time data"
|
|
arch=('x86_64')
|
|
url="https://www.iana.org/time-zones"
|
|
license=('custom: public domain')
|
|
optdepends=('bash: for tzselect'
|
|
'glibc: for zdump, zic')
|
|
options=('!emptydirs')
|
|
source=(https://www.iana.org/time-zones/repository/releases/tzcode${_tzcode}.tar.gz{,.asc}
|
|
https://www.iana.org/time-zones/repository/releases/${pkgname}${_tzdata}.tar.gz{,.asc})
|
|
sha512sums=('fa18bae9c0e7c061bc9d5f5f2eb9967f0e4ddb2baafdee9887fa30cd0c60f4aa6f21eacffb17df0d59d26ff54d08c5dcefa98159309eba497e86443624913a82'
|
|
'SKIP'
|
|
'608bd286ebcbd0004cfdc1da183273f08aff61f90c8867661154453d77a05d421e4c46ad6d066a1fe2e87d5c82ec0f1c0224667a3b35f3180a3eb7f6ff84cbf5'
|
|
'SKIP')
|
|
validpgpkeys=('7E3792A9D8ACF7D633BC1588ED97E90E62AA7E34') # Paul Eggert <eggert@cs.ucla.edu>
|
|
|
|
_timezones=('africa' 'antarctica' 'asia' 'australasia'
|
|
'europe' 'northamerica' 'southamerica'
|
|
'etcetera' 'backward' 'factory')
|
|
|
|
prepare() {
|
|
sed -i "s:sbin:bin:g" Makefile
|
|
}
|
|
|
|
build() {
|
|
make LFLAGS="${LDFLAGS} ${LTOFLAGS}"
|
|
}
|
|
|
|
package() {
|
|
cd "${srcdir}"
|
|
# install tzcode stuff
|
|
make DESTDIR="${pkgdir}" install
|
|
|
|
# install tzdata stuff
|
|
./zic -b fat -d "${pkgdir}"/usr/share/zoneinfo ${_timezones[@]}
|
|
./zic -b fat -d "${pkgdir}"/usr/share/zoneinfo/posix ${_timezones[@]}
|
|
./zic -b fat -d "${pkgdir}"/usr/share/zoneinfo/right -L leapseconds ${_timezones[@]}
|
|
# This creates the posixrules file. We use New York because POSIX requires the daylight savings time rules to be in accordance with US rules.
|
|
./zic -b fat -d "${pkgdir}"/usr/share/zoneinfo -p America/New_York
|
|
install -m644 -t "${pkgdir}"/usr/share/zoneinfo iso3166.tab leap-seconds.list zone1970.tab zone.tab SECURITY # zone.tab is depricated and will go soon
|
|
|
|
# cleanup
|
|
rm "${pkgdir}/etc/localtime"
|
|
|
|
# install license
|
|
install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
|
|
}
|