#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=apulse
pkgver=0.1.13
pkgrel=01
pkgdesc='PulseAudio emulation for ALSA'
arch=(x86_64)
url='https://github.com/i-rinat/apulse'
depends=(alsa-lib glib2)
makedepends=(cmake)
install=apulse.install
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz"
        'asoundrc.sample')

prepare() {
	cd apulse-${pkgver}

	mkdir -p build
}

build() {
	cd apulse-${pkgver}/build

	cmake .. -DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_BUILD_TYPE=Release
	make
}

package() {
	cd apulse-${pkgver}/build

	make DESTDIR="${pkgdir}/" install

	# sample asoundrc
	install -Dm644 ../../${source[1]} \
		"${pkgdir}/usr/share/${pkgname}/${source[1]}"

	# license
	install -Dm644 ../LICENSE.MIT \
		"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}


#---- license gpg-key sha256sums ----

license=('custom:MIT')

sha256sums=(9234ec4e10e408b9c01d5f4ea768ad1fc15494217c932db2c435202a9c7b5efd # apulse-0.1.13.tar.gz
	e851197ec9ebff528154210751cd6d5c426abfc2b1aa34343580407b1ea789a4) # asoundrc.sample
