#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=strace
pkgver=6.2
pkgrel=01
pkgdesc='A diagnostic, debugging and instructional userspace tracer'
url='https://strace.io/'
depends=(perl libunwind)
source=(https://github.com/strace/strace/releases/download/v$pkgver/strace-$pkgver.tar.xz{,.asc})

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --with-libunwind --enable-mpers=no
  make
}

check() {
  # tests do not work in chroot environment. TODO: fixit.
  # make -C $pkgname-$pkgver check
  true
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=(BSD)

validpgpkeys=('296D6F29A020808E8717A8842DB5BD89A340AEB7') # Dmitry V. Levin <ldv@altlinux.org>

sha256sums=(0c7d38a449416268d3004029a220a15a77c2206a03cc88120f37f46e949177e8  # strace-6.2.tar.xz
	34f129890436704073e0f4f40b8bde642d5eb0f4c14216e92150683ae711db69) # strace-6.2.tar.xz.asc

##  6d1bac27154870b2a24ef07076236cdc97694eeb0e64a6d934d4b5440c734217  strace-6.2-01-x86_64.pkg.tar.lz

