#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=xdg-desktop-portal
pkgver=1.16.0
pkgrel=01
pkgdesc="Desktop integration portals for sandboxed apps w/o systemd pipewire and flatpak"
url="https://github.com/flatpak/xdg-desktop-portal"
arch=(x86_64)
depends=(glib2 fuse3 geoclue rtkit)
makedepends=(python xmlto docbook-xsl git libportal)
#options=(debug)  ## uncomment this to produce the debug pkg 
_commit=88af6c8ca4106fcf70925355350a669848e9fd5a  # tags/1.16.0^0
source=("git+https://github.com/flatpak/xdg-desktop-portal#commit=$_commit")

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd $pkgname
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname
  ./configure \
  --prefix=/usr \
  --libexecdir=/usr/lib \
  --enable-pipewire=no \
  --with-systemduserunitdir=no \
  --with-systemd=no \
  --with-flatpak=no \
  --with-pipewire=no
  make 
}

package() {
  depends+=(xdg-desktop-portal-impl)

  cd $pkgname
  make DESTDIR="$pkgdir" install
}

#---- license gpg-key sha256sums ----

license=(LGPL)

sha256sums=('SKIP')

#  edf300beb22fb2da34f80382d4a20f8f77c840bc7972a369e7cc49d3cf8f874c  xdg-desktop-portal-1.16.0-01-x86_64.pkg.tar.lz


