#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun/jobcore/$pkgname"
# PkgSource		: url="https://gittea.disroot.org/joborun/jobextra/$pkgname"
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=gtk-doc
pkgver=1.33.2+7+g7e3f546
pkgrel=01
pkgdesc="Documentation tool for public library API"
url="https://www.gtk.org/gtk-doc/"
arch=(any)
depends=(docbook-xsl docbook-xml glib2-docs python-lxml python-pygments
         python-anytree)
makedepends=(dblatex git yelp-tools meson)
checkdepends=(bc gtk3 python-six python-parameterized)
optdepends=('dblatex: PDF support')
provides=(gtk-doc=$pkgver)
conflicts=(gtk-doc)
source=("git+https://gitlab.gnome.org/GNOME/gtk-doc.git"
         fix.diff)
#161c6d94e41e2d2ec2358ac6be8233f8d1698f57 refs/tags/1.33.2
#^14391142ee9d43da116f0f530746ae34cc46930a

pkgver() {
  cd $pkgname
  git describe --tags | sed -e 's/GTK_DOC_//' -e 's/_/\./g' -e 's/-/+/g'
}

prepare() {
  cd $pkgname
  patch -Np1 -i ../fix.diff
}

build() {
  arch-meson $pkgname build
  ninja -C build
}

check() {
  # Tests don't work yet
  meson test -C build --print-errorlogs || :
}

package() {
  DESTDIR="$pkgdir" meson install -C build
  python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
}

#---- license gpg-key sha256sums ----

license=(GPL FDL)
sha512sums=(SKIP
            '6d5dd328f784986c1bc46e8bdd800226c5e7eaec2b2b921e0b930435cbe42d73283dd1f87272e1c1cfec9e24e21b7d551f5609d20e4838ba4d3eba1bb1479d43')

sha256sums=(SKIP
	0391f47af6bd11bdc870ba826836612c68f538a12bc12fe0b4f34e6c11482baf) #  fix.diff
