#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=glib-networking
pkgver=2.76.0
pkgrel=01
epoch=1
pkgdesc="Network extensions for GLib w/o systemd"
url="https://gitlab.gnome.org/GNOME/glib-networking"
depends=(glib2 libproxy gnutls gsettings-desktop-schemas)
makedepends=(meson git libxml2)
checkdepends=(ca-certificates)
# options=(debug)  ## uncomment this line to have the debug pkg produced
_commit=eab226398f9872c381033f7cb3af43dcb66600f4  # tags/2.76.0^0
source=("git+https://gitlab.gnome.org/GNOME/glib-networking.git#commit=$_commit")

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd $pkgname
}

build() {
  arch-meson $pkgname build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
  rm -rf $pkgdir/usr/lib/systemd
}

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=(GPL2)

sha256sums=(SKIP)

##  253b3883d4bc41db49b5e69c7a13a619ede0ddd9afe67c5db925dde2d7dacc44  glib-networking-1:2.76.0-01-x86_64.pkg.tar.lz

