#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libinput
pkgver=1.22.1
pkgrel=01
pkgdesc="Input device management and event handling library - unsigned source"
#url="https://www.freedesktop.org/wiki/Software/libinput/"
url="https://gitlab.freedesktop.org/libinput"
arch=(x86_64)
depends=('mtdev' 'libevdev' 'libwacom')
# upstream doesn't recommend building docs
makedepends=('gtk4' 'meson' 'wayland-protocols' 'cmake' 'gtk4' 'check') # 'doxygen' 'graphviz' 'python-sphinx' 'python-recommonmark'
optdepends=('gtk4: libinput debug-gui'
            'python-pyudev: libinput measure'
            'python-libevdev: libinput measure')
#source=(https://freedesktop.org/software/$pkgname/$pkgname-$pkgver.tar.xz{,.sig})
#source=($url/libinput/-/archive/$pkgver/$pkgname-$pkgver{,.sig}.tar.bz2) #  .tar.bz2 #
# Arch is using a source that during June 12th-13th was down, the entire site, not just the link.
# The sum reported for this tar ball does not match to this of the alternative site (common for freedesktop tar balls)
# and no signature file is provided to check the validity of the source.
#
### options=(debug)   ### uncomment this to build the debug pkg
#source=(https://github.com/wayland-project/libinput/archive/refs/tags/$pkgver.tar.gz)
source=(https://gitlab.freedesktop.org/libinput/libinput/-/archive/$pkgver/$pkgname-$pkgver.tar.bz2)

build() {
  arch-meson $pkgname-$pkgver build \
    -D udev-dir=/usr/lib/udev \
    -D documentation=false

  # Print config
  meson configure build

  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"

  install -Dvm644 $pkgname-$pkgver/COPYING \
    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

#---- license gpg-key sha256sums ----

license=(custom:X11)

validpgpkeys=('3C2C43D9447D5938EF4551EBE23B7E70B467F0BF') # Peter Hutterer (Who-T) <office@who-t.net>

sha256sums=(e13f6f118cfbbdc0b6e0edd5e3504abd96a8d0e33dc67cba31c6942c449f77af) #  libinput-1.22.1.tar.bz2

##  cd79057d5187671c41f3a8961c9cd1efcd81f16300c9ec4344adbafda93409c6  libinput-1.22.1-01-x86_64.pkg.tar.xz
