#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=gnunet-gtk
pkgdesc="A framework for secure peer-to-peer networking (GTK 3 interfaces)"
pkgver=0.15.0.r9.gc06bc0c4
pkgrel=01
arch=('x86_64')
url="http://gnunet.org"
conflicts=('gnunet-gtk-git')
provides=('gnunet-gtk')
depends=('gnunet' 'gtk3' 'glade')
source=("git+https://git.gnunet.org/$pkgname.git")
#             https://git.gnunet.org/gnunet-gtk.git

pkgver() {
    cd $pkgname
    git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
}

build() {
    cd "${srcdir}/$pkgname"
    ./bootstrap
    ./configure --prefix=/usr --with-gnunet=/usr
    make
}

package() {
    cd "${srcdir}/$pkgname"
    make DESTDIR="${pkgdir}/" install
}

#---- license gpg-key sha256sums ----

license=('GPL3')

sha256sums=(SKIP)

