#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=libvncserver
pkgver=0.9.14
pkgrel=02
pkgdesc="Cross-platform C libraries that allow you to easily implement VNC server or client functionality w/o systemd"
arch=('x86_64')
url="https://libvnc.github.io/"
depends=('gnutls' 'libgcrypt' 'libjpeg' 'libpng' 'lzo' 'openssl')
makedepends=('sdl2' 'cmake')
source=("https://github.com/LibVNC/libvncserver/archive/LibVNCServer-${pkgver}.tar.gz")

build() {
  cd $pkgname-LibVNCServer-$pkgver
  cmake	-DCMAKE_INSTALL_PREFIX=/usr \
	-DCMAKE_INSTALL_LIBDIR=/usr/lib \
	-DCMAKE_INSTALL_LIBEXECDIR=/usr/libexec \
	-DWITH_SYSTEMD=OFF

  make
}

package() {
  cd $pkgname-LibVNCServer-$pkgver
  make DESTDIR="$pkgdir" install
}

#---- license gpg-key sha256sums ----

license=('GPL')

sha256sums=(83104e4f7e28b02f8bf6b010d69b626fae591f887e949816305daebae527c9a5) # LibVNCServer-0.9.14.tar.gz
