#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=alsa-lib
pkgver=1.2.8
pkgrel=01
pkgdesc="An alternative implementation of Linux sound support"
arch=(x86_64)
url="https://www.alsa-project.org"
depends=(glibc alsa-topology-conf alsa-ucm-conf)
provides=(libasound.so libatopology.so)
install=$pkgname.install
# options=(debug)  ## uncomment this like to have the debug pkg produced
source=(https://www.alsa-project.org/files/pub/lib/$pkgname-$pkgver.tar.bz2{,.sig})
#	$pkgname-1.2.7-fix_decoding_for_older_hardware.patch::https://github.com/alsa-project/alsa-lib/commit/89ee61914756a6f8bcafbad7fb1eca674b0a012f.patch)

prepare() {
  cd $pkgname-$pkgver
  autoreconf -fiv
}

build() {
  # -flto=auto is not supported: https://github.com/alsa-project/alsa-lib/issues/110
  CFLAGS+=" -flto-partition=none"
  cd $pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --without-debug
  # prevent excessive overlinking due to libtool
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  export LD_LIBRARY_PATH="$pkgname-$pkgver/src/.libs/:$LD_LIBRARY_PATH"
  make -k check -C $pkgname-$pkgver
}

package() {
  make DESTDIR="$pkgdir" install -C $pkgname-$pkgver
  install -vDm 644 $pkgname-$pkgver/{MEMORY-LEAK,TODO,NOTES,ChangeLog,doc/asoundrc.txt} -t "$pkgdir/usr/share/doc/$pkgname/"
}

#---- license gpg-key sha256sums ----

license=(LGPL2.1)

validpgpkeys=('F04DF50737AC1A884C4B3D718380596DA6E59C91') # ALSA Release Team (Package Signing Key v1) <release@alsa-project.org>

sha256sums=(1ab01b74e33425ca99c2e36c0844fd6888273193bd898240fe8f93accbcbf347  # alsa-lib-1.2.8.tar.bz2
	079a4da0b0276def3b7f816995858be41a46ba5a77097940e7d69469ff8e3cc2) # alsa-lib-1.2.8.tar.bz2.sig

sha512sums=('865ff05a8f589996f8d63d43a91c961f1b64144f3e1d17c7074b7ac16f25b3fd1c371d46ed63a8cc20fa01e63c76b75f1a9802b56889ae1073854dd050d27688'
             'SKIP')
b2sums=('e6171ac557db6265e3f02df7bd269eca62d09afaf2c04dc913d3bb217df23a8e66e808ad453fea5ed90d4d9226feb05065ad5d9b3575241b76675ccd27b9b4d4'
         'SKIP')
  
 
