#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=cscope
pkgver=15.9
pkgrel=02
pkgdesc="A developers tool for browsing program code"
src="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
arch=('x86_64')
url="http://cscope.sourceforge.net/"
depends=('ncurses' 'sh')
source=("https://sourceforge.net/projects/cscope/files/cscope/v${pkgver}/${pkgname}-${pkgver}.tar.gz")

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	sed -i 's|/usr/local/lib/cs|/usr/lib/cs|' contrib/ocs

	./configure --prefix=/usr
	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install

	install -d "${pkgdir}"/usr/lib/cs
	install -Dm644 COPYING "${pkgdir}"/usr/share/licenses/"${pkgname}"/LICENSE

	cd contrib/xcscope
	install -Dm644 xcscope.el "${pkgdir}"/usr/share/emacs/site-lisp/xcscope.el
	install -m755 cscope-indexer "${pkgdir}"/usr/bin
}

#---- license gpg-key sha256sums ----

license=('BSD')

sha256sums=(c5505ae075a871a9cd8d9801859b0ff1c09782075df281c72c23e72115d9f159) # cscope-15.9.tar.gz
