#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=mpd
pkgver=0.23.11
pkgrel=01
pkgdesc="Flexible, powerful, server-side application for playing music w/o systemd"
arch=(x86_64)
url="https://www.musicpd.org/"
depends=(bzip2 chromaprint gcc-libs glibc lame libcdio libcdio-paranoia
libgcrypt libgme libmad libmms libmodplug libmpcdec libnfs libshout
libsidplayfp libsoxr openal opus smbclient sqlite wavpack wildmidi zlib
zziplib)
makedepends=(alsa-lib audiofile avahi boost curl dbus expat faad2 ffmpeg flac
fluidsynth fmt icu jack libao libid3tag libmikmod libmpdclient libogg
libopenmpt libpulse libsamplerate libsndfile libupnp liburing libvorbis meson
mpg123 pipewire python-sphinx twolame yajl)
backup=(etc/$pkgname.conf)
# options=(debug)  ## uncomment this to produce the debug pkg
source=(
  https://www.musicpd.org/download/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz{,.sig}
  $pkgname.conf
  $pkgname.sysusers
  $pkgname.tmpfiles
#  $pkgname.service.override
)

build() {
  local _meson_options=(
    -D documentation=enabled
    -D adplug=disabled
    -D sndio=disabled
    -D shine=disabled
    -D tremor=disabled
    -D systemd=disabled
    -D b_ndebug=true

  )

  # NOTE: sndio conflicts with alsa
  # TODO: package adplug
  # TODO: package shine
  arch-meson "${_meson_options[@]}" build $pkgname-$pkgver
  ninja -C build
}

check() {
  ninja -C build test
}

package() {
  depends+=(libbz2.so libFLAC.so libao.so libasound.so libaudiofile.so
  libavahi-client.so libavahi-common.so libavcodec.so libavformat.so
  libavutil.so libcurl.so libdbus-1.so libexpat.so libfaad.so libfluidsynth.so
  libfmt.so libicui18n.so libicuuc.so libid3tag.so libjack.so libmikmod.so
  libmpdclient.so libmpg123.so libogg.so libopenmpt.so libpipewire-0.3.so
  libpulse.so libsamplerate.so libsndfile.so libtwolame.so
  libupnp.so liburing.so libvorbis.so libvorbisenc.so libyajl.so libavfilter.so
  libchromaprint.so libixml.so)

  DESTDIR="$pkgdir" ninja -C build install
  install -vDm 644 $pkgname-$pkgver/doc/${pkgname}conf.example -t "$pkgdir/usr/share/doc/$pkgname/"
#  install -vDm 644 $pkgname.service.override "$pkgdir/usr/lib/systemd/system/mpd.service.d/00-arch.conf"
  install -vDm 644 $pkgname.conf -t "$pkgdir/etc/"
  install -vDm 644 $pkgname.sysusers "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
  install -vDm 644 $pkgname.tmpfiles "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
}

#---- license gpg-key sha256sums ----

license=(GPL2)

validpgpkeys=('0392335A78083894A4301C43236E8A58C6DB4512') # Max Kellermann <max@blarg.de>

sha512sums=('971ae6b8ee5bf963a0f2408194fa01089713b606b3a2423081621b80a25e1b480f0e80a6d155ac8c2083960d99681c90f4bf00bf0baffa1f977259f1687c4ceb'
            'SKIP'
            '25a823740d92da8e186916701413114142eb6ad91a172c592e68b569c8e4f50fa99580e555ccf6cd31fc4f55a09bfe0278efa46e4e76ee0fe02846292fadf3c1'
            '6e467481406279767b709ec6d5c06dbd825c0de09045c52ffa2d21d0604dcfe19b7a92bf42bed25163d66a3a0d1dbde6185a648b433eaf5eac56be90491e2e18'
            'db473db27cd68994c3ee26e78e0fb34d13126301d8861563dcc12a22d62ecb14c4ffb1e0798c6aaccdff34e73bae3fbeeff7b42606c901a2d35e278865cdf35d')
#            'c1782b82f9db1d30aece43a07230c5d57370f2494a16e108af03815d83968805472f10f53ea5495cf0e08ff8f245430c3c3bc44025af43aaf9ecd12fcd6afc6c')
b2sums=('70cc22abe78f6457bcec20a8e668647f9a2f38417956133ba5fde286179acaa710337461461d73b907a069fc0cfe6cb3787bc0db6bf61d82ad9fb082cbd2776d'
        'SKIP'
        '0969a3c477b6a3f34b44e067e515d7f306414dd14e0163584417b9d071e3cc825898219f7ff66ead7905b15429b8411304052d3b2b14a72e560bfabf9bf0adcf'
        '4ab6e415284c77802a39d0913d701fe55e56f3c22b19557661fbef77e456b5e1d151da4202695282b956602e716a7afdb994aa2fc17368b9a0d0d051d47a3afb'
        'd7b587c25dd5830c27af475a8fdd8102139d7c8fdd6f04fe23b36be030e4411582e289f575c299255ff8183096f7d47247327276f9a24641cbd032d9675b837a')
#        '753664445d7d5cc0b36f51ac66549beea403b9731cbcb81b0a782974a0a73d90559ba93e6afcaa470b6f2f5a844c09ef695bdf3b1e6dfee97aa080f41b7fe513')

sha256sums=(edb4e7a8f9dff238b5610f9e2461940ea98c727a5462fafb1cdf836304dfdca9  # mpd-0.23.11.tar.xz
	7946bdd660e1f0a6434f22c98640b9fcc1f079710d056dd4c5820ab20a14a61e  # mpd-0.23.11.tar.xz.sig
	f40f68205834ca53cea3372e930bfe6c2f9ecc9df3b1605df2fec63a658b2e03  # mpd.conf
	0b74c6e5db08daab3091dc15a6b0c75210ba2f9e98fa074f6cfd605a461056b6  # mpd.sysusers
	2faa85c12449a5b3ca422ff1c1fa06d057c7e262a74bfa6298c914a92d6f2e7a) # mpd.tmpfiles

