#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=nvme-cli
pkgver=2.2.1
pkgrel=02
pkgdesc="NVM-Express user space tooling for Linux w/o systemd"
arch=(x86_64)
url="https://github.com/linux-nvme/nvme-cli"
# git is needed to provide the source with a workaround file to cover for the absense of libnvme.so 
makedepends=('meson' 'asciidoc' 'xmlto' 'python-nose2' 'autopep8' 'python-flake8-isort' 'git' 'mypy')
depends=('util-linux')
#options=(debug strip)  ##  uncomment this line to produce debug pkg
options=(strip)
install=nvme-cli.install
# checkdepends=('python2-nose' 'python-nose')
source=("$pkgname-$pkgver.tar.gz::https://github.com/linux-nvme/${pkgname}/archive/v${pkgver}.tar.gz")

build() {
	cd "${pkgname}-${pkgver}"
	meson setup \
	--prefix /usr \
	--libexecdir lib \
	--sbindir bin \
	--buildtype plain \
	--auto-features enabled \
	-D b_lto=true -D b_pie=true \
	-D docs=man -D docs-build=true \
	-D systemddir=no \
	-D udevrulesdir=lib/udev/rules.d \
	.build
}

# Tests require a working NVME disk.
# check() {
# 	cd "${pkgname}-${pkgver}"
# 	make test
# }

package() {
	cd "${pkgname}-${pkgver}"
	DESTDIR="$pkgdir" meson install -C .build
}

#---- license gpg-key sha256sums ----

license=('GPL')

sha256sums=(68720bc25c68adb93dafe1186de4fabbe40f8390ff1416256b52fe74f78259ae) # v2.2.1.tar.gz


