#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=obs-studio-git
pkgver=29.0.0.beta1
#pkgver=${_pkgver//-/_}
pkgrel=03
#epoch=3
pkgdesc="Free and open source software for video recording and live streaming. w/o systemd dependencies"
arch=("x86_64")
url="https://github.com/obsproject/obs-studio"
depends=("ffmpeg" "jansson" "libxinerama" "libxkbcommon-x11" "mbedtls" "rnnoise" "pciutils"
         "qt6-svg" "curl" "jack" "gtk-update-icon-cache"
         "speexdsp" "pciutils" "libajantv2" "librist")
makedepends=("cmake" "git" "libfdk-aac" "libxcomposite" "x264"
             "vlc" "swig" "luajit" "python" "cef-minimal-obs-bin" "wayland"
             "qt6-wayland" "xdg-desktop-portal" "pipewire")
optdepends=("libfdk-aac: FDK AAC codec support"
            "libxcomposite: XComposite capture support"
            "libva-intel-driver: hardware encoding"
            "libva-mesa-driver: hardware encoding"
            "vlc: VLC Media Source"
            "luajit: Lua scripting"
            "python: Python scripting"
            "v4l2loopback-dkms: Virtual webcam"
            "pipewire: Pipewire capture"
            "pipewire-media-session: Pipewire capture"
            "xdg-desktop-portal: Pipewire capture")
provides=("obs-studio=$pkgver")
conflicts=("obs-studio")
#84adab45cba45fb55526f1b46d0a73006317f65c refs/tags/28.0.3
#^d21891b3ca1a8607de479687cd2e12a4455525d7
_commit=84adab45cba45fb55526f1b46d0a73006317f65c  # tags/28.0.3
source=("$pkgname::git+https://github.com/obsproject/obs-studio.git#commit=$_commit"
        "git+https://github.com/Mixer/ftl-sdk.git"
        "git+https://github.com/obsproject/obs-browser.git"
        "git+https://github.com/obsproject/obs-vst.git"
        "git+https://github.com/obsproject/obs-websocket.git"
        "git+https://github.com/chriskohlhoff/asio.git"
        "git+https://github.com/nlohmann/json.git"
        "git+https://github.com/nayuki/QR-Code-generator.git"
        "git+https://github.com/zaphoyd/websocketpp.git"
        "fix_python_binary_loading.patch")

#pkgver() {
#  cd $pkgname
#  git describe --long --tags | cut -d- -f1-2 | sed "s/-/\./"
#}

prepare() {
  gitconf="protocol.file.allow=always"

  cd $pkgname
  patch -Np1 < "$srcdir"/fix_python_binary_loading.patch
  git config submodule.plugins/obs-outputs/ftl-sdk.url $srcdir/ftl-sdk
  git config submodule.plugins/obs-browser.url $srcdir/obs-browser
  git config submodule.plugins/obs-vst.url $srcdir/obs-vst
  git config submodule.plugins/obs-websocket.url $srcdir/obs-websocket
  git -c $gitconf submodule update

  cd plugins/obs-websocket
  git config submodule.deps/asio.url $srcdir/asio
  git config submodule.deps/json.url $srcdir/json
  git config submodule.deps/qr.url $srcdir/QR-Code-generator
  git config submodule.deps/websocketpp.url $srcdir/websocketpp
  git -c $gitconf submodule update
}

build() {
  cd $pkgname

  mkdir -p build; cd build

  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_BROWSER=ON \
    -DCEF_ROOT_DIR="/opt/cef-obs" \
    ..
  make
}

package() {
  cd $pkgname/build

  make install DESTDIR="$pkgdir"
}

#---- license gpg-key sha256sums ----

license=("GPL2")

sha256sums=(SKIP SKIP SKIP SKIP SKIP SKIP SKIP SKIP SKIP 
	bdfbd062f080bc925588aec1989bb1df34bf779cc2fc08ac27236679cf612abd) #  fix_python_binary_loading.patch

