#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgbase=fuse3
pkgname=(fuse-common fuse3)
pkgver=3.13.0
pkgrel=01
pkgdesc='Interface for userspace programs to export a filesystem to the Linux kernel'
arch=('x86_64')
url='https://github.com/libfuse/libfuse'
makedepends=('pkg-config' 'meson' 'eudev')
## options=('!emptydirs' 'debug') ## uncomment this to produce the debug pkg
options=(!emptydirs)
source=(https://github.com/libfuse/libfuse/releases/download/fuse-$pkgver/fuse-$pkgver.tar.xz{,.asc})

build() {
  cd fuse-$pkgver

  rm -rf build
  meson --prefix=/usr --sbindir=bin -D examples=false . build
  cd build
  ninja
}

package_fuse-common() {
  pkgdesc="Common files for fuse2/3 packages"
  backup=(etc/fuse.conf)

  install -Dm644 fuse-${pkgver}/util/fuse.conf "${pkgdir}"/etc/fuse.conf
}

package_fuse3() {
#  pkgdesc="A library that makes it possible to implement a filesystem in a userspace program."
  depends=('fuse-common' 'glibc')

  cd fuse-$pkgver/build

  DESTDIR="${pkgdir}" ninja install

  rm -r "${pkgdir}"/etc/init.d
  rm -r "${pkgdir}"/etc/fuse.conf

  # static device nodes are handled by udev
  rm -r "${pkgdir}"/dev
}

#---- license gpg-key sha256sums ----

license=('GPL2')

validpgpkeys=(ED31791B2C5C1613AF388B8AD113FCAC3C4E599F) # Nikolaus Rath <Nikolaus@rath.org>

sha256sums=(1e54d3ee1d7d04f41e77617c4f7514f611b94332215dd88394bd82803032752a  # fuse-3.12.0.tar.xz
	5ddc2e97df1645b986ed6ff3ac9ddaf1abb1703afde0eb7942a9d81f275dff75) # fuse-3.13.0.tar.xz.asc


