#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=ethtool
pkgver=6.1
pkgrel=01
epoch=1
pkgdesc="Utility for controlling network drivers and hardware"
arch=('x86_64')
url="https://www.kernel.org/pub/software/network/ethtool/"
depends=('glibc' 'libmnl')
source=(https://www.kernel.org/pub/software/network/$pkgname/$pkgname-$pkgver.tar.{xz,sign})

build() {
    cd $pkgname-$pkgver
    ./configure --prefix=/usr --mandir=/usr/share/man --sbindir=/usr/bin
    make
}

check() {
    cd $pkgname-$pkgver
    make check
}

package() {
    cd $pkgname-$pkgver
    make DESTDIR="$pkgdir" install
}

#---- license gpg-key sha256sums ----

license=('GPL')

validpgpkeys=(CE4A4D080F0D304F23B9EBDD972D5BF4DC613806  # John W. Linville <linville@kernel.org>
              D2CB120AB45957B721CD9596F4554567B91DE934) # Michal Kubecek <mkubecek@suse.cz>

sha256sums=(c41fc881ffa5a40432d2dd829eb44c64a49dee482e716baacf9262c64daa8f90  # ethtool-6.1.tar.xz
	e8907001d696413f13b54110b4614246148c94e6b5e056b5b2809bffe8c84ae9) # ethtool-6.1.tar.sign
