#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=glib-networking
pkgver=2.74.0
pkgrel=01
epoch=1
pkgdesc="Network extensions for GLib w/o systemd"
url="https://gitlab.gnome.org/GNOME/glib-networking"
arch=(x86_64)
depends=(glib2 libproxy gnutls gsettings-desktop-schemas)
makedepends=(meson git)
checkdepends=(ca-certificates)
# options=(debug)  ## uncomment this line to have the debug pkg produced
_commit=d17632fe495c573612dd69e982a0c49af2952178  # tags/2.74.0^0
source=("git+https://gitlab.gnome.org/GNOME/glib-networking.git#commit=$_commit")

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd $pkgname
}

build() {
  arch-meson $pkgname build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
  rm -rf $pkgdir/usr/lib/systemd
}

#---- license gpg-key sha256sums ----

license=(GPL2)

sha256sums=(SKIP)



