#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=multipath-tools
_tag='3db6872d9a418261b02be4755258a9928b6bb7ac' # git rev-parse ${pkgver}
pkgver=0.9.1
pkgrel=01
pkgdesc='Multipath tools for Linux (including kpartx)'
arch=('x86_64')
url='http://christophe.varoqui.free.fr/'
depends=('libaio' 'device-mapper' 'json-c' 'liburcu')
makedepends=('git')
source=("multipath-tools::git+https://github.com/opensvc/multipath-tools#tag=${_tag}")

prepare() {
  cd "${pkgname}"

  # Fix systemd version detection in Makefile
  sed -i 's/sed -n .*$/head -n1 | cut -d" " -f2\)/g' Makefile.inc

  # Fix bindir in Makefile
  sed -i 's|$(exec_prefix)/sbin|$(exec_prefix)/bin|g' Makefile.inc
}

build() {
  cd "${pkgname}"

  make \
    FORTIFY_OPT=""
}

package() {
  cd "${pkgname}"

  make -j1 \
    DESTDIR="${pkgdir}" \
    exec_prefix="/usr" \
    LIB="/usr/lib" \
    install

  install -D -m0644 -t "${pkgdir}/usr/share/doc/${pkgname}" README*
}

#---- license gpg-key sha256sums ----

license=(GPL2)

sha256sums=(SKIP)
