#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

_pkgname=pyudev
pkgname=python-$_pkgname
pkgver=0.24.0
pkgrel=01
arch=('any')
url='https://github.com/pyudev/pyudev'
pkgdesc='Python bindings to libudev w/o systemd'
depends=('python-six')
#makedepends=('python-setuptools' 'python-sphinx' 'python-mock')
#checkdepends=('python-pytest-runner' 'python-docutils' 'python-mock' 'python-hypothesis')
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel' 'python-sphinx' 'python-mock')
checkdepends=('python-pytest' 'python-docutils' 'python-mock' 'python-hypothesis' 'python-pip')
optdepends=('python-pyqt5: PyQt integration'
            'pyside2: PySide integration'
            'python-wxpython: WX integration')
source=("$_pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")

prepare() {
  cd $_pkgname-$pkgver

  # Remove failing tests (we can't test udev inside makepkg)
  rm tests/test_{util,discover,device,monitor,enumerate,observer}.py

  # Fix documentation build
  sed -i "s|os.path.join(doc_directory, os.pardir)|os.path.join(doc_directory, os.pardir, 'src')|
          s|b'autodoc-process-docstring'|'autodoc-process-docstring'|" doc/conf.py
}

build() {
  cd $_pkgname-$pkgver

  python -m build -nw

  # Generate documentation
  sphinx-apidoc -f -e -o doc src/pyudev
  sphinx-build -a -b html doc doc/html
}

check() {
  cd $_pkgname-$pkgver

  PYTHONPATH=src python -m pytest
}

package() {
  cd $_pkgname-$pkgver

  python -m installer -d "$pkgdir" dist/*.whl

  # Install documentation
  install -dm 755 "$pkgdir"/usr/share/doc/$pkgname
  cp -r -a --no-preserve=ownership doc/html "$pkgdir"/usr/share/doc/$pkgname
  rm -rf "$pkgdir"/usr/share/doc/$pkgname/html/.doctrees
}

#---- license gpg-key sha256sums ----

license=('LGPL')

sha256sums=(91fbc62f3a8425871a943cc424bf93d7d2c9cb3c5df4480f81efe23ef3a64603) # pyudev-0.24.0.tar.gz


