#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=neon
pkgver=0.32.4
pkgrel=02
pkgdesc="HTTP and WebDAV client library with a C interface"
arch=('x86_64')
url="https://notroj.github.io/neon/"
depends=('krb5' 'expat' 'ca-certificates' 'zlib')
makedepends=('xmlto' 'docbook-xsl')
options=('libtool') # FS#16067
source=(https://notroj.github.io/neon/$pkgname-$pkgver.tar.gz)

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
    --with-expat \
    --enable-shared \
    --disable-static \
    --with-ssl=openssl \
    --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}

#---- license gpg-key sha256sums ----

license=('GPL' 'LGPL')

validpgpkeys=('190555472DCC589BEF01609C608A86DF9833CC49') # Joe Orton

sha256sums=(b1e2120e4ae07df952c4a858731619733115c5f438965de4fab41d6bf7e7a508) # neon-0.32.4.tar.gz


 
 
