#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

pkgname=pacman-contrib
pkgver=1.8.0
pkgrel=01
pkgdesc="Contributed scripts and tools for pacman systems w/o systemd"
url="https://gitlab.archlinux.org/pacman/pacman-contrib"
arch=('x86_64')
groups=( jobbot )
depends=('fakeroot' 'pacman' 'perl')
makedepends=('asciidoc')
optdepends=('diffutils: for pacdiff'
            'findutils: for pacdiff --find'
            'mlocate: for pacdiff --locate'
            'sudo: privilege elevation for several scripts'
            'vim: default merge program for pacdiff')
source=("$url/-/archive/v$pkgver/$pkgname-v$pkgver.tar.gz")

prepare() {
  cd $pkgname-v$pkgver
  ./autogen.sh
}

build() {
  cd $pkgname-v$pkgver

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var
  make
}

check() {
  cd $pkgname-v$pkgver
  make check
}

package() {
  cd $pkgname-v$pkgver
  make DESTDIR="$pkgdir" install
#  rm -rf $pkgdir/usr/lib/systemd
  rm -rf $pkgdir/usr/lib
}

#---- license gpg-key sha256sums ----

license=('GPL')

validpgpkeys=('5134EF9EAF65F95B6BB1608E50FB9B273A9D0BB5'  # Johannes Löthberg <johannes@kyriasis.com>
              '04DC3FB1445FECA813C27EFAEA4F7B321A906AD9') # Daniel M. Capella <polyzen@archlinux.org>

sha256sums=(80fb41d0b79845e4707ab59af9f098450b071bb5d9bb4bf7fb7911535a871658) # pacman-contrib-v1.8.0.tar.gz


