#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer		: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Maintainer:	ArchStrike <team[at]archstrike[dot]org>
#-----------------------------------------| DESCRIPTION |---------------------------------------

#buildarch=1
pkgname=mat
pkgver=0.6.1
pkgrel=03
pkgdesc="Metadata Anonymisation Toolkit"
url="https://mat.boum.org/"
depends=('python2-mutagen' 'python2-pyexiftool-git' 'python2-pdfrw' 'python2-gobject'
         'python2-cairo' 'poppler' 'poppler-glib')
makedepends=('python2' 'python2-setuptools' 'python2-distutils-extra')
arch=('any')
source=("https://mat.boum.org/files/mat-${pkgver}.tar.xz")

prepare() {
  cd "${pkgname}-${pkgver}" || exit
  sed -i 's|python$|python2|' libmat/mat.py nautilus/nautilus-mat.py
}

build() {
    cd "${pkgname}-${pkgver}" || exit
    python2 setup.py build
}

package() {
    cd "${pkgname}-${pkgver}" || exit
    python2 setup.py install --root="${pkgdir}" --optimize=1 
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

#---- license gpg-key sha256sums ----

license=('custom')

sha256sums=(0782e7db554ad1dddefd71c9c81e36a05464d73ab54ee2a474ea6ac90e8e51b9) #  mat-0.6.1.tar.xz
