jobextra/libxslt/PKGBUILD

#!/usr/bin/bash
# JOBoRun		: Jwm OpenBox Obarun RUNit
# Maintainer	: Joe Bo Run <joborun@disroot.org>
# PkgSource		: url="https://gittea.disroot.org/joborun-pkg/jobextra/$pkgname"
# Website		: https://pozol.eu
#-----------------------------------------| DESCRIPTION |---------------------------------------

#pkgbase=libxslt
#pkgname=(libxslt libxslt-docs)
pkgname=libxslt
pkgver=1.1.37
pkgrel=03
pkgdesc="XML stylesheet transformation library"
url="https://gitlab.gnome.org/GNOME/libxslt/-/wikis/home"
depends=(libxml2 libgcrypt xz)
makedepends=(git python)
checkdepends=(docbook-xml)
optdepends=('python: Python bindings')
provides=(lib{,e}xslt.so)
#options=(debug)   ##  uncomment this to have the debug pkg produced
_commit=5eca7fb65b7337409a02f9f94fde608edf7d1b0a  # tags/v1.1.37^0
source=("git+https://gitlab.gnome.org/GNOME/libxslt.git#commit=$_commit"
        0001-Make-generate-id-deterministic.patch)

pkgver() {
  cd libxslt
  git describe --tags | sed 's/-rc/rc/;s/^v//;s/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd libxslt

  # Make xsltproc output reproducible for packages which use it to generate documentation
  git apply -3 ../0001-Make-generate-id-deterministic.patch

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd libxslt

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --with-python=/usr/bin/python \
    --disable-static
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd libxslt
  make check
}

#package_libxslt() {
package() {
  cd libxslt
  make DESTDIR="$pkgdir" install

  mkdir -p ../doc/usr/share
  mv "$pkgdir"/usr/share/{doc,gtk-doc} -t ../doc/usr/share

  install -Dm644 Copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}

#package_libxslt-docs() {
#  pkgdesc+=" (documentation)"

#---- arch license gpg-key & sha256sums ----

arch=(x86_64)

license=(custom:MIT)

sha256sums=(SKIP
	605e0a0b2ca385a90226bc5b141d3f6bfeade13e43ab39f8dea863505d7cbf18) #  0001-Make-generate-id-deterministic.patch
 
##  e45a83746ecb19238005bc31c14a5367ada4d350e7948749ef4e50781362f974  libxslt-1.1.37-03-x86_64.pkg.tar.lz