corrections
This commit is contained in:
parent
43982eee0d
commit
4312d78eb3
|
@ -1,108 +0,0 @@
|
|||
# Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
|
||||
pkgname=dracut
|
||||
pkgver=060
|
||||
pkgrel=2
|
||||
pkgdesc="An event driven initramfs infrastructure"
|
||||
arch=('x86_64')
|
||||
url="https://github.com/dracut-ng/dracut-ng"
|
||||
license=('GPL-2.0-or-later')
|
||||
depends=(
|
||||
'bash'
|
||||
'coreutils'
|
||||
'cpio'
|
||||
'filesystem'
|
||||
'findutils'
|
||||
'gawk'
|
||||
'grep'
|
||||
'kmod'
|
||||
'pkgconf'
|
||||
'procps-ng'
|
||||
'sed'
|
||||
'systemd'
|
||||
'util-linux'
|
||||
)
|
||||
makedepends=(
|
||||
'asciidoc'
|
||||
'bash-completion'
|
||||
'git'
|
||||
)
|
||||
optdepends=(
|
||||
'binutils: --uefi option support'
|
||||
'bluez: bluetooth (keyboard)'
|
||||
'btrfs-progs: scan for Btrfs on block devices'
|
||||
'busybox: allows use of busybox (on your own risk)'
|
||||
'bzip2: bzip2 compression'
|
||||
'cifs-utils: support CIFS'
|
||||
'connman: support for connman networking'
|
||||
'cryptsetup: support for encrypted with LUKS filesystems'
|
||||
'dash: allows use of dash (on your own risk)'
|
||||
'dhclient: legacy networking support'
|
||||
'dmraid: dmraid dracut module support'
|
||||
'e2fsprogs: ext2/3/4 filesystem support'
|
||||
'elfutils: strip binaries to reduce initramfs size'
|
||||
'f2fs-tools: fsfs filesystem support'
|
||||
'fuse3: live on NTFS (dmsquash-live-ntfs module)'
|
||||
'gzip: gzip compression'
|
||||
'iproute2: legacy networking support'
|
||||
'iputils: networking support'
|
||||
'lvm2: support Logical Volume Manager'
|
||||
'lzop: lzop compression'
|
||||
'mdadm: support MD devices, also known as software RAID devices'
|
||||
'multipath-tools: dmraid dracut module support'
|
||||
'nbd: support network block devices'
|
||||
'ndctl: NVDIMM support'
|
||||
'networkmanager: networkmanager support'
|
||||
'nfs-utils: support NFS'
|
||||
'ntfs-3g: live on NTFS (dmsquash-live-ntfs module)'
|
||||
'nvme-cli: NVMe-oF support (nvmf module)'
|
||||
'open-iscsi: support iSCSI (iscsi module)'
|
||||
'openssh: install ssh and scp along with config files and specified keys (ssh-client module)'
|
||||
'pigz: faster gzip compression'
|
||||
'plymouth: plymouth boot splash'
|
||||
'rng-tools: enable rngd service to help generating entropy early during boot'
|
||||
'sbsigntools: uefi_secureboot_cert/key configuration option support'
|
||||
'squashfs-tools: support for building a squashed initramfs'
|
||||
'tar: live tar image'
|
||||
'tpm2-tools: tpm2 support for e.g. LUKS'
|
||||
'xz: xz compression'
|
||||
)
|
||||
provides=('initramfs')
|
||||
backup=('etc/dracut.conf')
|
||||
source=(
|
||||
"${pkgname}-${pkgver}::git+${url}#tag=${pkgver}"
|
||||
dracut-systemd-255-pcrphase.patch::https://github.com/dracut-ng/dracut-ng/commit/b63e90ab4e34b35ba0ce009992b0fc019eca3761.patch
|
||||
dracut-systemd-255-hibernate-resume.patch::https://github.com/dracutdevs/dracut/pull/2527/commits/a2fe89116db4b286fbf515f26bd1773b5e6ee8ad.patch
|
||||
)
|
||||
sha512sums=('8dbdd67d0b86555aac4c2f315c809861c82358d3899ecdf3008e6203b9f32eac2e8a969fe972e9ce63316aeb0d3242e0e997d21c24bee8666ef3d3e7ddda067e'
|
||||
'6b00c3d37440feb294219477f79edcbb074b69863e0234edbc7966df11cb6e7d51cf1ea3c086b3014748f6e96bbeab5e4f1916c3b14316e1b2a8aa1e4f4ee563'
|
||||
'bba154e13463fb759e1cfd5f461b2b4e786ad8c6f4cacacbd918e911efc7d5a5368300676d6e6d8e9b7b2f4333314886bb1e34daac9f0c73c1c441baf7918063')
|
||||
b2sums=('41593a6205cf0a66ad49d903cf73e20b6a0b90628e185f93eb29d09df7d7dbcc342759901d204fb3d2c98ec6b8550ac14dbaef43c8243c0d9190b06a56a92a91'
|
||||
'863a685ab41ed9d891257c4b18e311e5d6849c8eb30ba489252b4d9cda462c4c6d50bfcc8edece891c34f012b6dd7120c1d3cc8cb08758ef6696d3b15c0f0d81'
|
||||
'bd8dc23e1dafa9a76b79af40be5267ee96934c08950b6eae70d5794a9f3038cb0cb7d54593463f42325ddae637cb6ddf21af52bd9fd6e639f7fdc7acc5abf21e')
|
||||
|
||||
prepare() {
|
||||
cd ${pkgname}-${pkgver}
|
||||
|
||||
patch -Np1 < ../dracut-systemd-255-pcrphase.patch
|
||||
patch -Np1 < ../dracut-systemd-255-hibernate-resume.patch
|
||||
}
|
||||
|
||||
build() {
|
||||
local prefix=/usr sysconfdir=/etc
|
||||
|
||||
cd ${pkgname}-${pkgver}
|
||||
|
||||
./configure \
|
||||
--sysconfdir=${sysconfdir} \
|
||||
--prefix=${prefix} \
|
||||
--libdir=${prefix}/lib \
|
||||
--systemdsystemunitdir=${prefix}/lib/systemd/system \
|
||||
--bashcompletiondir=$(pkg-config --variable=completionsdir bash-completion)
|
||||
make
|
||||
}
|
||||
|
||||
package() {
|
||||
cd ${pkgname}-${pkgver}
|
||||
|
||||
DESTDIR="$pkgdir" make install
|
||||
}
|
|
@ -1,104 +0,0 @@
|
|||
# Maintainer: Florian Pritz <bluewind@xinu.at>
|
||||
# Contributor: Eric Bélanger <eric@archlinux.org>
|
||||
|
||||
pkgname=syslog-ng
|
||||
pkgver=4.6.0
|
||||
pkgrel=2
|
||||
pkgdesc="Next-generation syslogd with advanced networking and filtering capabilities"
|
||||
arch=('x86_64')
|
||||
url="https://www.syslog-ng.com/products/open-source-log-management/"
|
||||
license=('GPL2' 'LGPL2.1')
|
||||
depends=(
|
||||
'awk'
|
||||
'bash'
|
||||
'curl'
|
||||
'glib2'
|
||||
'glibc'
|
||||
'grpc'
|
||||
'json-c'
|
||||
'libcap'
|
||||
'libnet'
|
||||
'libnsl'
|
||||
'openssl'
|
||||
'pcre2'
|
||||
'protobuf'
|
||||
'systemd-libs'
|
||||
)
|
||||
makedepends=('libxslt' 'mongo-c-driver' 'librabbitmq-c' 'python' 'libesmtp' 'hiredis'
|
||||
'libdbi' 'libmaxminddb' 'net-snmp' 'librdkafka' 'systemd')
|
||||
checkdepends=('python-nose' 'python-ply')
|
||||
optdepends=('logrotate: for rotating log files'
|
||||
'libdbi: for the SQL plugin'
|
||||
'librabbitmq-c: for the AMQP plugin'
|
||||
'mongo-c-driver: for the MongoDB plugin'
|
||||
'libesmtp: for the SMTP plugin'
|
||||
'hiredis: for the Redis plugin'
|
||||
'libmaxminddb: for the GeoIP2 plugin'
|
||||
'net-snmp: for the SNMP plugin'
|
||||
'librdkafka: for the Kafka C plugin'
|
||||
'python: for Python-based plugins'
|
||||
'python-ply: for debugger CLI')
|
||||
conflicts=('eventlog')
|
||||
replaces=('eventlog')
|
||||
# The default scl.conf moved in 4.3.0, but it is still supported here for overrides so we keep this entry. See https://github.com/syslog-ng/syslog-ng/pull/4534 for details.
|
||||
backup=('etc/syslog-ng/scl.conf'
|
||||
'etc/syslog-ng/syslog-ng.conf'
|
||||
'etc/logrotate.d/syslog-ng'
|
||||
'etc/default/syslog-ng@default')
|
||||
source=(https://github.com/balabit/syslog-ng/releases/download/syslog-ng-$pkgver/$pkgname-$pkgver.tar.gz
|
||||
syslog-ng.conf syslog-ng.logrotate)
|
||||
sha512sums=('7c4fbf1ac5377240afa7a1db8d72772399d2c62657fffc3c59e82b2dea6f12031f02320c4f567f981311bd1d8bbfd98962aeb59720ca857867a51b6bf83afb4b'
|
||||
'432154be20858721c2dcfee65a608cb65760479c9b78b7751fa1e00fc0276c1b34bdff8bc1bee8a6e5c0138f3034531034401fcbb9cc3c70f1b984225a9c6240'
|
||||
'cd39f545a6a855c866a466bf846e33940b2c2dd1fc2eaf50cce29c68e1a5753c7c4b56411e4f01c152f32e155104a98dd755a96319767f47c73a8853f720b2cc')
|
||||
|
||||
prepare() {
|
||||
cd $pkgname-$pkgver
|
||||
sed -i -e 's,/bin/,/usr/bin/,' -e 's,/sbin/,/bin/,' contrib/systemd/syslog-ng@.service
|
||||
sed -i -e 's|/var/run|/run|g' contrib/systemd/syslog-ng@default
|
||||
}
|
||||
|
||||
build() {
|
||||
cd $pkgname-$pkgver
|
||||
|
||||
# https://archlinux.org/todo/lto-fat-objects/
|
||||
export CFLAGS+=" -ffat-lto-objects"
|
||||
export CXXFLAGS+=" -ffat-lto-objects"
|
||||
|
||||
|
||||
_source_version=$(sed -rn 's#.*define VERSION_STR_CURRENT.* "(.*)"#\1#p' lib/versioning.h)
|
||||
_config_version=$(head -1 "$srcdir/syslog-ng.conf" | cut -d\ -f2)
|
||||
|
||||
if [[ "$_source_version" != "$_config_version" ]]; then
|
||||
echo "Version in example config at '$srcdir/syslog-ng.conf' is: $_config_version"
|
||||
echo "Expected version from code is: $_source_version"
|
||||
echo "Check if config format has incompatible changes and adjust the"
|
||||
echo "example config file and bump the version to continue the build."
|
||||
echo "Usually simply bumping is fine since our config is simple enough"
|
||||
return 1
|
||||
fi
|
||||
|
||||
./autogen.sh
|
||||
./configure --prefix=/usr --sysconfdir=/etc/syslog-ng --libexecdir=/usr/lib \
|
||||
--sbindir=/usr/bin --localstatedir=/var/lib/syslog-ng --datadir=/usr/share \
|
||||
--with-pidfile-dir=/run --enable-spoof-source --enable-ipv6 \
|
||||
--enable-systemd --with-systemdsystemunitdir=/usr/lib/systemd/system \
|
||||
--enable-manpages --enable-all-modules --disable-java --disable-java-modules \
|
||||
--disable-mqtt --disable-riemann --with-python=3 --with-jsonc=system
|
||||
# prevent excessive overlinking due to libtool
|
||||
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
||||
make
|
||||
}
|
||||
|
||||
# TODO: package criterion
|
||||
# check() {
|
||||
# cd $pkgname-$pkgver
|
||||
# make check
|
||||
# }
|
||||
|
||||
package() {
|
||||
make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
|
||||
install -dm755 "$pkgdir/var/lib/syslog-ng" "$pkgdir/etc/syslog-ng/patterndb.d"
|
||||
install -Dm644 "$srcdir/syslog-ng.conf" "$pkgdir/etc/syslog-ng/syslog-ng.conf"
|
||||
install -Dm644 "$srcdir/syslog-ng.logrotate" "$pkgdir/etc/logrotate.d/syslog-ng"
|
||||
install -Dm644 "$srcdir"/$pkgname-$pkgver/contrib/systemd/syslog-ng@default -t "$pkgdir"/etc/default
|
||||
}
|
Loading…
Reference in New Issue