43 lines
1.4 KiB
Plaintext
43 lines
1.4 KiB
Plaintext
# Maintainer: Felix Yan <felixonmars@archlinux.org>
|
|
# Contributor: Caleb Maclennan <caleb@alerque.com>
|
|
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
|
|
# Contributor: Thomas Dziedzic < gostrc at gmail >
|
|
# Contributor: Denis Martinez <deuns.martinez AT gmail.com>
|
|
# Contributor: Bogdan Burlacu <bogdan.burlacu AT pm.me>
|
|
|
|
pkgname=onetbb
|
|
pkgver=2021.12.0
|
|
pkgrel=2
|
|
pkgdesc='High level abstract threading library (oneAPI Threading Building Blocks)'
|
|
arch=('x86_64')
|
|
url='https://oneapi-src.github.io/oneTBB/'
|
|
license=('Apache')
|
|
depends=('gcc-libs' 'hwloc')
|
|
makedepends=('cmake' 'inetutils' 'ninja' 'python' 'swig' 'python-setuptools')
|
|
conflicts=('intel-tbb' 'tbb')
|
|
provides=("intel-tbb=$pkgver" "tbb=$pkgver")
|
|
replaces=('intel-tbb' 'tbb')
|
|
source=(https://github.com/oneapi-src/oneTBB/archive/v$pkgver/$pkgname-$pkgver.tar.gz)
|
|
sha512sums=('64022bcb61cf7b2030a1bcc11168445ef9f0d69b70290233a7febb71cc7a12cc2282dddc045f84e30893efe276342f02fd78d176706268eeaefe9aac7446d4e9')
|
|
|
|
build() {
|
|
cmake -B build -S oneTBB-$pkgver -GNinja \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DTBB_STRICT=OFF \
|
|
-DTBB4PY_BUILD=ON \
|
|
-DCMAKE_BUILD_TYPE=None
|
|
cmake --build build
|
|
}
|
|
|
|
check() {
|
|
cd build
|
|
ninja test
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="$pkgdir" cmake --install build
|
|
rm -r "$pkgdir"/usr/lib/python*
|
|
cd oneTBB-$pkgver/python
|
|
TBBROOT="$pkgdir"/usr python setup.py install --root="$pkgdir"
|
|
}
|