189 lines
6.8 KiB
Plaintext
189 lines
6.8 KiB
Plaintext
# Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
|
|
# Maintainer: Robin Broda <robin@broda.me>
|
|
# Contributor: Christian Rebischke <chris.rebischke@archlinux.org>
|
|
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
|
|
# Contributor: Jonathan Wiersma <archaur at jonw dot org>
|
|
|
|
pkgname=(libvirt libvirt-storage-gluster libvirt-storage-iscsi-direct)
|
|
epoch=1
|
|
pkgver=10.1.0
|
|
pkgrel=1
|
|
pkgdesc="API for controlling virtualization engines (openvz,kvm,qemu,virtualbox,xen,etc)"
|
|
arch=('x86_64')
|
|
url="https://libvirt.org/"
|
|
license=('LGPL-2.1-or-later'
|
|
'GPL-3.0-or-later') # libvirt_parthelper links to libparted
|
|
depends=('libpciaccess' 'yajl' 'fuse3' 'gnutls' 'parted' 'libssh' 'libxml2'
|
|
'numactl' 'polkit' 'libnbd' 'libnl')
|
|
makedepends=('meson' 'libxslt' 'python-docutils' 'lvm2' 'open-iscsi' 'libiscsi' 'glusterfs'
|
|
'bash-completion' 'dnsmasq' 'iproute2' 'qemu-base')
|
|
optdepends=('libvirt-storage-gluster: Gluster storage backend'
|
|
'libvirt-storage-iscsi-direct: iSCSI-direct storage backend'
|
|
'gettext: required for libvirt-guests.service'
|
|
'openbsd-netcat: for remote management over ssh'
|
|
'dmidecode: DMI system info support'
|
|
'dnsmasq: required for default NAT/DHCP for guests'
|
|
'radvd: IPv6 RAD support'
|
|
'iptables-nft: required for default NAT networking'
|
|
'qemu-desktop: QEMU/KVM support'
|
|
'qemu-emulators-full: Support of additional QEMU architectures'
|
|
'lvm2: Logical Volume Manager support'
|
|
'open-iscsi: iSCSI support via iscsiadm'
|
|
'swtpm: TPM emulator support')
|
|
|
|
backup=(
|
|
'etc/libvirt/libvirt-admin.conf'
|
|
'etc/libvirt/libvirt.conf'
|
|
'etc/libvirt/libvirtd.conf'
|
|
'etc/libvirt/lxc.conf'
|
|
'etc/libvirt/nwfilter/allow-arp.xml'
|
|
'etc/libvirt/nwfilter/allow-dhcp-server.xml'
|
|
'etc/libvirt/nwfilter/allow-dhcpv6-server.xml'
|
|
'etc/libvirt/nwfilter/allow-dhcp.xml'
|
|
'etc/libvirt/nwfilter/allow-dhcpv6.xml'
|
|
'etc/libvirt/nwfilter/allow-incoming-ipv4.xml'
|
|
'etc/libvirt/nwfilter/allow-incoming-ipv6.xml'
|
|
'etc/libvirt/nwfilter/allow-ipv6.xml'
|
|
'etc/libvirt/nwfilter/allow-ipv4.xml'
|
|
'etc/libvirt/nwfilter/clean-traffic-gateway.xml'
|
|
'etc/libvirt/nwfilter/clean-traffic.xml'
|
|
'etc/libvirt/nwfilter/no-arp-ip-spoofing.xml'
|
|
'etc/libvirt/nwfilter/no-arp-mac-spoofing.xml'
|
|
'etc/libvirt/nwfilter/no-arp-spoofing.xml'
|
|
'etc/libvirt/nwfilter/no-ip-multicast.xml'
|
|
'etc/libvirt/nwfilter/no-ipv6-multicast.xml'
|
|
'etc/libvirt/nwfilter/no-ip-spoofing.xml'
|
|
'etc/libvirt/nwfilter/no-ipv6-spoofing.xml'
|
|
'etc/libvirt/nwfilter/no-mac-spoofing.xml'
|
|
'etc/libvirt/nwfilter/no-mac-broadcast.xml'
|
|
'etc/libvirt/nwfilter/no-other-l2-traffic.xml'
|
|
'etc/libvirt/nwfilter/no-other-rarp-traffic.xml'
|
|
'etc/libvirt/nwfilter/qemu-announce-self-rarp.xml'
|
|
'etc/libvirt/nwfilter/qemu-announce-self.xml'
|
|
'etc/libvirt/qemu.conf'
|
|
'etc/libvirt/qemu-lockd.conf'
|
|
'etc/libvirt/qemu/networks/default.xml'
|
|
'etc/libvirt/virtchd.conf'
|
|
'etc/libvirt/virtinterfaced.conf'
|
|
'etc/libvirt/virtlockd.conf'
|
|
'etc/libvirt/virtlogd.conf'
|
|
'etc/libvirt/virt-login-shell.conf'
|
|
'etc/libvirt/virtlxcd.conf'
|
|
'etc/libvirt/virtnetworkd.conf'
|
|
'etc/libvirt/virtnodedevd.conf'
|
|
'etc/libvirt/virtnwfilterd.conf'
|
|
'etc/libvirt/virtproxyd.conf'
|
|
'etc/libvirt/virtqemud.conf'
|
|
'etc/libvirt/virtsecretd.conf'
|
|
'etc/libvirt/virtstoraged.conf'
|
|
'etc/libvirt/virtvboxd.conf'
|
|
'etc/logrotate.d/libvirtd'
|
|
'etc/logrotate.d/libvirtd.lxc'
|
|
'etc/logrotate.d/libvirtd.qemu'
|
|
'etc/sasl2/libvirt.conf'
|
|
)
|
|
source=(
|
|
"https://libvirt.org/sources/$pkgname-$pkgver.tar.xz"{,.asc}
|
|
)
|
|
sha256sums=('36d9077e2b0ef6b0c6df3b42e42a67411b6ce3b1564b427b55e65019dde60eed'
|
|
'SKIP')
|
|
validpgpkeys=('453B65310595562855471199CA68BE8010084C9C') # Jiří Denemark <jdenemar@redhat.com>
|
|
|
|
prepare() {
|
|
cd "$pkgname-$pkgver"
|
|
|
|
sed -i 's|/sysconfig/|/conf.d/|g' \
|
|
src/remote/libvirtd.service.in \
|
|
tools/{libvirt-guests.service,libvirt-guests.sh,virt-pki-validate}.in \
|
|
docs/manpages/libvirt-guests.rst \
|
|
src/locking/virtlockd.service.in \
|
|
src/logging/virtlogd.service.in
|
|
sed -i 's|/usr/libexec/qemu-bridge-helper|/usr/lib/qemu/qemu-bridge-helper|g' \
|
|
src/qemu/qemu.conf.in \
|
|
src/qemu/test_libvirtd_qemu.aug.in
|
|
}
|
|
|
|
build() {
|
|
cd "$pkgname-$pkgver"
|
|
|
|
arch-meson build \
|
|
--libexecdir=lib/libvirt \
|
|
-Drunstatedir=/run \
|
|
-Dqemu_user=libvirt-qemu \
|
|
-Dqemu_group=libvirt-qemu \
|
|
-Dnetcf=disabled \
|
|
-Dopenwsman=disabled \
|
|
-Dapparmor=disabled \
|
|
-Dapparmor_profiles=disabled \
|
|
-Dselinux=disabled \
|
|
-Dwireshark_dissector=disabled \
|
|
-Ddriver_bhyve=disabled \
|
|
-Ddriver_hyperv=disabled \
|
|
-Ddriver_libxl=disabled \
|
|
-Ddriver_vz=disabled \
|
|
-Dsanlock=disabled \
|
|
-Dsecdriver_apparmor=disabled \
|
|
-Dsecdriver_selinux=disabled \
|
|
-Dstorage_vstorage=disabled \
|
|
-Ddtrace=disabled \
|
|
-Dnumad=disabled \
|
|
-Dstorage_zfs=enabled\
|
|
-Dstorage_rbd=disabled
|
|
|
|
meson compile -C build
|
|
}
|
|
|
|
check() {
|
|
cd "$pkgname-$pkgver"
|
|
|
|
meson test -C build --print-errorlogs
|
|
}
|
|
|
|
package_libvirt() {
|
|
provides=("libvirt=$pkgver" 'libvirt.so' 'libvirt-admin.so' 'libvirt-lxc.so' 'libvirt-qemu.so')
|
|
cd "$pkgname-$pkgver"
|
|
meson install -C build --destdir "$pkgdir"
|
|
|
|
mkdir -p "$pkgdir"/usr/lib/{sysusers,tmpfiles}.d
|
|
echo 'g libvirt - -' > "$pkgdir/usr/lib/sysusers.d/libvirt-qemu.conf"
|
|
echo 'u libvirt-qemu /var/lib/libvirt "Libvirt QEMU user"' >> "$pkgdir/usr/lib/sysusers.d/libvirt.conf"
|
|
echo 'm libvirt-qemu kvm' >> "$pkgdir/usr/lib/sysusers.d/libvirt.conf"
|
|
echo 'z /var/lib/libvirt/qemu 0751' > "$pkgdir/usr/lib/tmpfiles.d/libvirt.conf"
|
|
|
|
chmod 600 "$pkgdir"/etc/libvirt/nwfilter/*.xml \
|
|
"$pkgdir/etc/libvirt/qemu/networks/default.xml"
|
|
chmod 700 "$pkgdir"/etc/libvirt/secrets
|
|
|
|
rm -rf \
|
|
"$pkgdir/run" \
|
|
"$pkgdir/var/lib/libvirt/qemu" \
|
|
"$pkgdir/var/cache/libvirt/qemu" \
|
|
"$pkgdir/etc/logrotate.d/libvirtd.libxl"
|
|
|
|
rm -f "$pkgdir/etc/libvirt/qemu/networks/autostart/default.xml"
|
|
|
|
# move split modules
|
|
mv "$pkgdir"/usr/lib/libvirt/storage-backend/libvirt_storage_backend_gluster.so "$pkgdir/../"
|
|
mv "$pkgdir/usr/lib/libvirt/storage-backend/libvirt_storage_backend_iscsi-direct.so" "$pkgdir/../"
|
|
mv "$pkgdir/usr/lib/libvirt/storage-file/libvirt_storage_file_gluster.so" "$pkgdir/../"
|
|
}
|
|
|
|
package_libvirt-storage-gluster() {
|
|
pkgdesc="Libvirt Gluster storage backend"
|
|
depends=("libvirt=$pkgver" 'glusterfs')
|
|
optdepends=()
|
|
backup=()
|
|
|
|
install -Dv -t "$pkgdir/usr/lib/libvirt/storage-backend" "$pkgdir/../libvirt_storage_backend_gluster.so"
|
|
install -Dv -t "$pkgdir/usr/lib/libvirt/storage-file" "$pkgdir/../libvirt_storage_file_gluster.so"
|
|
}
|
|
|
|
package_libvirt-storage-iscsi-direct() {
|
|
pkgdesc="Libvirt iSCSI-direct storage backend"
|
|
depends=("libvirt=$pkgver" 'libiscsi')
|
|
optdepends=()
|
|
backup=()
|
|
|
|
install -Dv -t "$pkgdir/usr/lib/libvirt/storage-backend" "$pkgdir/../libvirt_storage_backend_iscsi-direct.so"
|
|
}
|