71 lines
1.2 KiB
Text
71 lines
1.2 KiB
Text
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
|
|
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
|
|
# Contributor: Ionut Biru <ibiru@archlinux.org>
|
|
# Contributor: Timm Preetz <timm@preetz.us>
|
|
|
|
pkgname=vala
|
|
pkgver=0.56.4
|
|
pkgrel=1
|
|
pkgdesc='Compiler for the GObject type system'
|
|
url='https://wiki.gnome.org/Projects/Vala'
|
|
arch=(x86_64)
|
|
license=(LGPL)
|
|
depends=(
|
|
gcc
|
|
glib2
|
|
graphviz
|
|
gtk-doc
|
|
pkg-config
|
|
ttf-font
|
|
)
|
|
makedepends=(
|
|
autoconf-archive
|
|
git
|
|
help2man
|
|
libxslt
|
|
vala
|
|
)
|
|
checkdepends=(
|
|
dbus
|
|
gobject-introspection
|
|
libx11
|
|
)
|
|
provides=(
|
|
libvala-${pkgver%.*}.so
|
|
libvaladoc-${pkgver%.*}.so
|
|
valadoc
|
|
)
|
|
conflicts=(valadoc)
|
|
replaces=(valadoc)
|
|
_commit=fbf513c52806e253b3dde68f477e1eca8ac38cd1 # tags/0.56.4^0
|
|
source=("git+https://gitlab.gnome.org/GNOME/vala.git#commit=$_commit")
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd vala
|
|
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd vala
|
|
NOCONFIGURE=1 ./autogen.sh
|
|
}
|
|
|
|
build() {
|
|
cd vala
|
|
./configure --prefix=/usr
|
|
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd vala
|
|
make check
|
|
}
|
|
|
|
package() {
|
|
cd vala
|
|
make DESTDIR="$pkgdir" install
|
|
}
|
|
|
|
# vim:set sw=2 sts=-1 et:
|