55 lines
1.8 KiB
Plaintext
55 lines
1.8 KiB
Plaintext
|
|
# Contributor: Felix Yan <felixonmars@archlinux.org
|
|
# Contributor: Maxim Baz <$pkgname at maximbaz dot com>
|
|
# Contributor: Pablo Arias <pabloariasal@gmail.com>
|
|
# Contributor: John Jenkins <twodopeshaggy@gmail.com>
|
|
|
|
pkgname=nnn-nerd
|
|
pkgver=4.9
|
|
pkgrel=1
|
|
pkgdesc="The fastest terminal file manager ever written (with icon support using a patched nerd font)."
|
|
arch=('x86_64')
|
|
depends=('bash')
|
|
optdepends=(
|
|
'atool: for more archive formats'
|
|
'libarchive: for more archive formats'
|
|
'zip: for zip archive format'
|
|
'unzip: for zip archive format'
|
|
'trash-cli: to trash files'
|
|
'sshfs: mount remotes'
|
|
'rclone: mount remotes'
|
|
'fuse2: unmount remotes'
|
|
'xdg-utils: desktop opener'
|
|
)
|
|
url="https://github.com/jarun/nnn"
|
|
license=('BSD')
|
|
provides=(nnn)
|
|
conflicts=(nnn)
|
|
source=("nnn-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
|
|
sha512sums=('3c16ed1cbc5466b05306e38c6f5d8eb7ade9cf5ad766f9ff3bf7d20d5bfb9bdf1564527e27191e2cd85542c25245f338e1236630de3d1c8e5fbd10d54d628a14')
|
|
|
|
prepare() {
|
|
sed -i 's/install: all/install:/' "${provides}-${pkgver}/Makefile"
|
|
}
|
|
|
|
build() {
|
|
cd "${provides}-${pkgver}"
|
|
make O_NERD=1
|
|
}
|
|
|
|
package() {
|
|
cd "${provides}-${pkgver}"
|
|
make DESTDIR="${pkgdir}" PREFIX=/usr install
|
|
make DESTDIR="${pkgdir}" PREFIX=/usr install-desktop
|
|
|
|
install -Dm644 misc/auto-completion/fish/nnn.fish "${pkgdir}/usr/share/fish/vendor_completions.d/nnn.fish"
|
|
install -Dm644 misc/auto-completion/bash/nnn-completion.bash "${pkgdir}/usr/share/bash-completion/completions/nnn"
|
|
install -Dm644 misc/auto-completion/zsh/_nnn "${pkgdir}/usr/share/zsh/site-functions/_nnn"
|
|
|
|
install -Dm644 -t "${pkgdir}/usr/share/nnn/quitcd/" misc/quitcd/*
|
|
|
|
cp -a plugins "${pkgdir}/usr/share/nnn/plugins/"
|
|
|
|
install -Dm644 -t "${pkgdir}/usr/share/licenses/${provides}/" LICENSE
|
|
}
|