40 lines
956 B
Plaintext
40 lines
956 B
Plaintext
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
|
|
# Contributor: Jan de Groot <jgc@archlinux.org>
|
|
|
|
pkgname=yelp
|
|
pkgver=41.2
|
|
pkgrel=1
|
|
pkgdesc="Get help with GNOME"
|
|
url="https://wiki.gnome.org/Apps/Yelp"
|
|
license=(GPL)
|
|
arch=(x86_64)
|
|
depends=(webkit2gtk-4.1 yelp-xsl libxslt xz bzip2)
|
|
makedepends=(gtk-doc itstool autoconf-archive git appstream-glib)
|
|
groups=(gnome)
|
|
_commit=72d73437a3d444739d722e580153f2dd8ee50f1d # tags/41.2^0
|
|
source=("git+https://gitlab.gnome.org/GNOME/yelp.git#commit=$_commit")
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd $pkgname
|
|
git describe --tags | sed 's/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd $pkgname
|
|
NOCONFIGURE=1 ./autogen.sh
|
|
}
|
|
|
|
build() {
|
|
cd $pkgname
|
|
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
|
|
--disable-static --enable-gtk-doc --enable-compile-warnings=minimum
|
|
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
make
|
|
}
|
|
|
|
package() {
|
|
cd $pkgname
|
|
make DESTDIR="$pkgdir" install
|
|
}
|