55 lines
1.9 KiB
Plaintext
55 lines
1.9 KiB
Plaintext
# Maintainer: David Runge <dvzrv@archlinux.org>
|
|
# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
|
|
# Contributor: Hilton Medeiros <medeiros.hilton@gmail.com>
|
|
# Contributor: Dave Reisner <d@falconindy.com>
|
|
|
|
pkgname=libgit2
|
|
pkgver=1.4.4
|
|
pkgrel=1
|
|
epoch=1
|
|
pkgdesc="A linkable library for Git"
|
|
arch=(x86_64)
|
|
url="https://github.com/libgit2/libgit2"
|
|
license=(GPL2)
|
|
depends=(glibc http-parser openssl pcre zlib)
|
|
makedepends=(cmake libssh2 python)
|
|
provides=(libgit2.so)
|
|
options=(debug)
|
|
source=(
|
|
$pkgname-$pkgver.tar.gz::https://github.com/$pkgname/$pkgname/archive/v$pkgver.tar.gz
|
|
$pkgname-1.2.0-remove_http-parse_incompatible_tests.patch
|
|
)
|
|
sha512sums=('8f4cc43de9b92866ac12e01613efe0ff808deca29ff82b6da98a38c814bb711ff3133145d0219210af7015955fbe381be6f1cb98915811d3c37e92b01eb522e9'
|
|
'01bf3a960b2e6d441017af363bff267bd1513915ebefda95012d7feb38f7020778ea0908664cc479da82f441a4dd2788772005006a9c19e87cfc234268dc3785')
|
|
b2sums=('2668e351521e1cd9d2998c45c65e2a8c30f3436d94f86ebaa10382d01afb136bbde28c71d359fb57757ebbd44b1cef1bacd302023d0803a23697aee10f03ebac'
|
|
'e725fb41c9bdfd9952693c9c47be90c10a16a78ab91f80e74c40c5510a83325575ce95674a2e21282e9c300f2bc8d430c896fa379ef744b8a8a912729fa88827')
|
|
|
|
prepare() {
|
|
# remove tests that are only compatible with the (modified) vendored version
|
|
# of http-parser, but not with upstream http-parser
|
|
patch -d $pkgname-$pkgver -Np1 -i ../$pkgname-1.2.0-remove_http-parse_incompatible_tests.patch
|
|
}
|
|
|
|
build() {
|
|
cmake -DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DCMAKE_BUILD_TYPE=None \
|
|
-DUSE_HTTP_PARSER=system \
|
|
-DUSE_SSH=ON \
|
|
-DTHREADSAFE=ON \
|
|
-Wno-dev \
|
|
-B build \
|
|
-S $pkgname-$pkgver
|
|
make VERBOSE=1 -C build
|
|
}
|
|
|
|
check() {
|
|
make VERBOSE=1 test -C build
|
|
}
|
|
|
|
package() {
|
|
depends+=(libssh2.so)
|
|
|
|
make VERBOSE=1 DESTDIR="$pkgdir" install -C build
|
|
install -vDm 644 $pkgname-$pkgver/{AUTHORS,README.md} -t "$pkgdir/usr/share/doc/$pkgname"
|
|
}
|