87 lines
1.8 KiB
Plaintext
87 lines
1.8 KiB
Plaintext
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
|
|
# Contributor: Eric Belanger <eric@archlinux.org>
|
|
# Contributor: John Proctor <jproctor@prium.net>
|
|
|
|
pkgbase=libxslt
|
|
pkgname=(libxslt libxslt-docs)
|
|
pkgver=1.1.37
|
|
pkgrel=3
|
|
pkgdesc="XML stylesheet transformation library"
|
|
url="https://gitlab.gnome.org/GNOME/libxslt/-/wikis/home"
|
|
arch=(x86_64)
|
|
license=(custom:MIT)
|
|
depends=(
|
|
libgcrypt
|
|
libxml2
|
|
xz
|
|
)
|
|
makedepends=(
|
|
git
|
|
python
|
|
)
|
|
checkdepends=(
|
|
docbook-xml
|
|
)
|
|
_commit=5eca7fb65b7337409a02f9f94fde608edf7d1b0a # tags/v1.1.37^0
|
|
source=("git+https://gitlab.gnome.org/GNOME/libxslt.git#commit=$_commit"
|
|
0001-Make-generate-id-deterministic.patch)
|
|
sha256sums=('SKIP'
|
|
'605e0a0b2ca385a90226bc5b141d3f6bfeade13e43ab39f8dea863505d7cbf18')
|
|
|
|
pkgver() {
|
|
cd libxslt
|
|
git describe --tags | sed 's/-rc/rc/;s/^v//;s/[^-]*-g/r&/;s/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd libxslt
|
|
|
|
# Make xsltproc output reproducible for packages which use it to generate documentation
|
|
git apply -3 ../0001-Make-generate-id-deterministic.patch
|
|
|
|
NOCONFIGURE=1 ./autogen.sh
|
|
}
|
|
|
|
build() {
|
|
cd libxslt
|
|
|
|
./configure \
|
|
--prefix=/usr \
|
|
--sysconfdir=/etc \
|
|
--localstatedir=/var \
|
|
--with-python=/usr/bin/python \
|
|
--disable-static
|
|
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
make
|
|
}
|
|
|
|
check() {
|
|
cd libxslt
|
|
make check
|
|
}
|
|
|
|
package_libxslt() {
|
|
optdepends=('python: Python bindings')
|
|
provides=(lib{,e}xslt.so)
|
|
|
|
cd libxslt
|
|
|
|
make DESTDIR="$pkgdir" install
|
|
|
|
mkdir -p ../doc/usr/share
|
|
mv "$pkgdir"/usr/share/{doc,gtk-doc} -t ../doc/usr/share
|
|
|
|
install -Dm644 Copyright -t "$pkgdir/usr/share/licenses/$pkgname"
|
|
}
|
|
|
|
package_libxslt-docs() {
|
|
pkgdesc+=" (documentation)"
|
|
depends=()
|
|
|
|
mv doc/* "$pkgdir"
|
|
|
|
install -Dm644 libxslt/Copyright -t "$pkgdir/usr/share/licenses/$pkgname"
|
|
}
|
|
|
|
# vim:set sw=2 sts=-1 et:
|