40 lines
1.2 KiB
Plaintext
40 lines
1.2 KiB
Plaintext
# Maintainer: David Runge <dvzrv@archlinux.org>
|
|
# Contributor: Dan McGee <dan@archlinux.org>
|
|
# Contributor: Florian Zeitz <florob at babelmonkeys dot de>
|
|
|
|
pkgname=numactl
|
|
pkgver=2.0.16
|
|
pkgrel=1
|
|
pkgdesc="Simple NUMA policy support"
|
|
arch=(x86_64)
|
|
url="https://github.com/numactl/numactl"
|
|
license=(LGPL2.1 GPL2)
|
|
depends=(glibc)
|
|
provides=(libnuma.so)
|
|
options=(debug)
|
|
source=($pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz)
|
|
sha512sums=('de89bd9f4a9be0e27b21d096aa17a554c209414b5d08b6a2dbd03f8f4830fe4fc5adc88fa8cb08ae1cf75884835dacbde5b6f5d31386244a2582924d2260fcb6')
|
|
b2sums=('bb19b771e2217cf39167877071623cfea14fa4560495e6c7d83b8f89b097ada93b142edbaba9f8ed1fdb61b20df075a8b0ca8898383d9ac34bb62bb9448447c0')
|
|
|
|
prepare(){
|
|
cd $pkgname-$pkgver
|
|
autoreconf -fiv
|
|
}
|
|
|
|
build() {
|
|
cd $pkgname-$pkgver
|
|
./configure --prefix=/usr
|
|
make
|
|
}
|
|
|
|
check() {
|
|
make -k test -C $pkgname-$pkgver || echo "Tests known to fail depending on system load."
|
|
}
|
|
|
|
package() {
|
|
make DESTDIR="$pkgdir" install -C $pkgname-$pkgver
|
|
install -vDm 644 $pkgname-$pkgver/README.md -t "$pkgdir/usr/share/doc/$pkgname/"
|
|
# move_pages(2) is provided by man-pages and is more up-to-date there anyway
|
|
rm -rf "$pkgdir/usr/share/man/man2"
|
|
}
|