{
  description = "An interactive, terminal-based markdown presenter ";
  inputs.nixpkgs.url = "nixpkgs";
  outputs = { self, nixpkgs }: {
    packages = nixpkgs.lib.mapAttrs (system: pkgs: {
      default = with pkgs.python311Packages;
        buildPythonPackage rec {
          pname = "lookatme";
          version = "2.5.5";
          pyproject = true;

          src = fetchPypi {
            inherit pname;
            inherit version;
            hash = "sha256-blmBPNa9xp6C3Xp5uyrBroKInpNDxJnWuxj3eoUkLes=";
          };

          propagatedBuildInputs = [
            click
            marshmallow
            (mistune.overrideAttrs (old: rec {
              version = "0.8.4";
              src = pkgs.fetchFromGitHub {
                owner = "lepture";
                repo = "mistune";
                rev = "v${version}";
                hash = "sha256-H9L2cJZVWvcbcWAF8ZMLGJGE7DO1h2wNZCbeFA02p7g=";
              };
            }))
            pygments
            (pyyaml.overrideAttrs (old: rec {
              version = "5.4.1";
              src = pkgs.fetchFromGitHub {
                owner = "yaml";
                repo = "pyyaml";
                rev = version;
                hash = "sha256-qLdAMqoyEXRIqcNuHBBtST8GWh5gmx5fBU/q3f4zaOw=";
              };
              installCheckPhase = "";
            }))
            urwid
          ];

          pythonImportsCheck = [ "lookatme" ];

          nativeBuildInputs = [ setuptools ];
        };
    }) nixpkgs.legacyPackages;
  };
}