yambar

fcft/PKGBUILD

@@ -0,0 +1,39 @@
+# Maintainer: Caleb Maclennan <caleb@alerque.com>
+# Contributor: Daniel Eklöf <daniel at ekloef dot se>
+
+pkgname=fcft
+pkgver=3.0.1
+pkgrel=2
+pkgdesc='Simple library for font loading and glyph rasterization'
+arch=(x86_64)
+url=https://codeberg.org/dnkl/${pkgname}
+license=(MIT)
+depends=(fontconfig
+         freetype2
+         harfbuzz
+         libutf8proc
+         pixman)
+makedepends=(meson
+             scdoc
+             tllist)
+checkdepends=(ttf-dejavu)
+provides=(libfcft.so)
+options=(debug)
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+sha256sums=('0d9b9f3add24aef5efcf42a32e8ad0e50060e1441a491e04fff3d79a36a526ea')
+
+build() {
+	arch-meson $pkgname build \
+		-Dgrapheme-shaping=enabled \
+		-Drun-shaping=enabled
+}
+
+check() {
+	meson test -C build
+}
+
+package() {
+	meson install -C build --destdir "$pkgdir"
+	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" "$pkgname/LICENSE"
+	install -Dm0644 "$pkgname/unicode/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.unicode"
+}

tillist/PKGBUILD

@@ -0,0 +1,21 @@
+pkgname=tllist
+pkgver=1.0.5
+pkgrel=1
+pkgdesc="A C header file only implementation of a typed linked list"
+arch=('x86_64' 'aarch64')
+url=https://codeberg.org/dnkl/tllist
+license=(mit)
+makedepends=('meson')
+source=(https://codeberg.org/dnkl/tllist/archive/${pkgver}.tar.gz)
+sha256sums=('b0f32c9b2c2015c8d8dd068fd4e8b586aa91ca1670badc274ec962559ee0aadd')
+
+build() {
+  cd "$pkgname"
+  artix-meson build
+  meson compile -C build
+}
+
+package() {
+  cd "$pkgname"
+  DESTDIR="${pkgdir}/" meson install -C build
+}

yambar/PKGBUILD

@@ -0,0 +1,35 @@
+pkgname=yambar
+pkgver=1.8.0
+pkgrel=1
+pkgdesc="Simplistic and highly configurable status panel for X and Wayland"
+arch=('x86_64' 'aarch64')
+url=https://codeberg.org/dnkl/yambar
+license=(mit)
+makedepends=('meson' 'scdoc' 'tllist>=1.0.1' 'eudev')
+depends=(
+  'libxcb' 'xcb-util' 'xcb-util-cursor' 'xcb-util-wm'
+  'wayland'
+  'pixman'
+  'libyaml'
+  'alsa-lib'
+  'libudev.so'
+  'json-c'
+  'libmpdclient'
+  'fcft'
+  'xorgproto'
+  'wayland-protocols'
+  'libudev.so')
+optdepends=('xcb-util-errors: better X error messages')
+source=(https://codeberg.org/dnkl/yambar/archive/${pkgver}.tar.gz)
+sha256sums=('51127d20613666b9924deb9afd92c48d69815c5043d2996b3f0f6e9705fcabc8')
+
+build() {
+  cd "$pkgname"
+  artix-meson --buildtype=release --prefix=/usr --wrap-mode=nofallback -Db_lto=true -Dbackend-x11=enabled -Dbackend-wayland=enabled build
+  meson compile -C build  
+}
+
+package() {
+  cd "$pkgname"
+  DESTDIR="${pkgdir}/" meson install -C build
+}