Add python-selenium

python-selenium/.SRCINFO

@@ -0,0 +1,22 @@
+pkgbase = python-selenium
+	pkgdesc = Python language bindings for Selenium WebDriver
+	pkgver = 4.6.0
+	pkgrel = 1
+	url = https://www.selenium.dev
+	arch = any
+	license = Apache
+	checkdepends = python-pytest
+	makedepends = python-setuptools
+	depends = python-urllib3
+	depends = python-certifi
+	depends = python-debugpy
+	depends = python-inflection
+	depends = python-multidict
+	depends = python-importlib-metadata
+	depends = python-trio-websocket
+	depends = geckodriver
+	options = !makeflags
+	source = https://github.com/SeleniumHQ/selenium/archive/refs/tags/selenium-4.6.0.tar.gz
+	sha256sums = 6361eade8ce119618bd1f9f6524b2ae106201e67730bbc15f622d4e1c204c1fd
+
+pkgname = python-selenium

python-selenium/.gitignore

@@ -0,0 +1,8 @@
+*~
+*.xz
+*.tar
+*.tgz
+*.tar.gz
+*.tar.bz2
+src
+pkg

python-selenium/PKGBUILD

@@ -0,0 +1,41 @@
+# Maintainer:  Anton Kudelin <kudelin at protonmail dot com>
+# Contributor: Jelle van der Waa <jelle@vdwaa.nl>
+# Contributor: Aaron DeVore <aaron.devore@gmail.com>
+
+_pkgname=selenium
+pkgname=python-$_pkgname
+pkgver=4.6.0
+pkgrel=1
+pkgdesc="Python language bindings for Selenium WebDriver"
+arch=('any')
+url="https://www.selenium.dev"
+license=('Apache')
+depends=('python-urllib3' 'python-certifi' 'python-debugpy' 'python-inflection'
+         'python-multidict' 'python-importlib-metadata' 'python-trio-websocket'
+         'geckodriver')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest')
+source=("https://github.com/SeleniumHQ/$_pkgname/archive/refs/tags/$_pkgname-$pkgver.tar.gz")
+sha256sums=('6361eade8ce119618bd1f9f6524b2ae106201e67730bbc15f622d4e1c204c1fd')
+options=(!makeflags)
+
+prepare() {
+  cd "$srcdir/$_pkgname-$_pkgname-$pkgver/py"
+  cp ../rb/lib/$_pkgname/webdriver/atoms/* $_pkgname/webdriver/remote
+  echo '{"frozen":{},"mutable":{}}' > $_pkgname/webdriver/firefox/webdriver_prefs.json
+}
+
+build() {
+  cd "$srcdir/$_pkgname-$_pkgname-$pkgver/py"
+  python setup.py build
+}
+
+check() {
+  cd "$srcdir/$_pkgname-$_pkgname-$pkgver/py"
+  pytest
+}
+
+package() {
+  cd "$srcdir/$_pkgname-$_pkgname-$pkgver/py"
+  python setup.py install --prefix=/usr --root="$pkgdir" -O1 --skip-build
+}