Update google-breakpad

google-breakpad/depot-tools-git/.SRCINFO

@@ -0,0 +1,16 @@
+pkgbase = depot-tools-git
+	pkgdesc = Tools for working with Chromium development
+	pkgver = r8355.04d9c8345
+	pkgrel = 1
+	url = https://chromium.googlesource.com/chromium/tools/depot_tools
+	install = depot-tools-git.install
+	arch = x86_64
+	license = custom
+	depends = git
+	depends = glibc
+	depends = python
+	depends = java-runtime
+	source = git+https://chromium.googlesource.com/chromium/tools/depot_tools.git
+	sha512sums = SKIP
+
+pkgname = depot-tools-git

google-breakpad/depot-tools-git/.gitignore

@@ -0,0 +1,7 @@
+*
+!.gitignore
+
+!PKGBUILD
+!.SRCINFO
+
+!depot-tools-git.install

google-breakpad/depot-tools-git/PKGBUILD

@@ -0,0 +1,75 @@
+# Maintainer: Caleb Maclennan <caleb@alerque.com>
+# Contributor: relrel <relrelbachar@gmail.com>
+# Contributor: Luis Aranguren <pizzaman@hotmail.com>
+# Contributor: Adrian Perez <aperez@igalia.com>
+# Contributor: Chih-Hsuan Yen <yan12125@gmail.com>
+# Contributor: rway <rway07@gmail.com>
+# Contributor: wabi <aschrafl@jetnet.ch>
+# Contributor: Alexander Rødseth <rodseth@gmail.com>
+# Contributor: Andreas Schrafl <aschrafl@gmail.com>
+# Contributor: piojo <aur@zwell.net>
+# Contributor: hack.augusto <hack.augusto@gmail.com>
+
+pkgname=depot-tools-git
+pkgver=r8355.04d9c8345
+pkgrel=1
+pkgdesc='Tools for working with Chromium development'
+arch=(x86_64)
+url='https://chromium.googlesource.com/chromium/tools/depot_tools'
+license=(custom)
+depends=(git glibc python java-runtime)
+install="$pkgname.install"
+source=("git+$url.git")
+sha512sums=('SKIP')
+
+pkgver() {
+	cd "$srcdir/depot_tools/"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+package() {
+	install -d "$pkgdir/opt/"
+	cp -r "$srcdir/depot_tools/" "$pkgdir/opt/depot_tools/"
+	chmod 775 "$pkgdir/opt/depot_tools/"
+
+	rm -rf "$pkgdir/opt/depot_tools/.git/"
+
+	# Make Windows files non-executable
+	chmod a-x "$pkgdir/opt/depot_tools/"*.{bat,exe}
+
+	# TODO: Consider removing unneeded files, for example:
+	# .git{ignore,attributes}
+	# *OWNERS
+	# WATCHLISTS
+	# bootstrap/
+	# infra/
+	# ninja-{mac,linux32}
+	# *.{bat,exe}
+	# testing_support/
+	# tests/
+	# win32imports.py
+	# win_toolchain/
+
+	# Install license
+	install -d "$pkgdir/usr/share/licenses/$pkgname/"
+	mv "$pkgdir/opt/depot_tools/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/"
+
+	# Install man pages
+	install -d "$pkgdir/usr/share/man/"
+	mv "$pkgdir/opt/depot_tools/man/"man[0-8]/ "$pkgdir/usr/share/man/"
+
+	# Install docs
+	install -d "$pkgdir/usr/share/doc/$pkgname/"
+	mv "$pkgdir/opt/depot_tools/man/html/" "$pkgdir/usr/share/doc/$pkgname/"
+	mv "$pkgdir/opt/depot_tools/"README* "$pkgdir/usr/share/doc/$pkgname/"
+
+	# Remove man/ leftovers
+	rm -r "$pkgdir/opt/depot_tools/man/"
+
+	# Install bash completions
+	install -d "$pkgdir/usr/share/bash-completion/completions/"
+	mv "$pkgdir/opt/depot_tools/gclient_completion.sh" "$pkgdir/usr/share/bash-completion/completions/gclient"
+	mv "$pkgdir/opt/depot_tools/git_cl_completion.sh" "$pkgdir/usr/share/bash-completion/completions/git-cl"
+
+	# TODO: Install zsh-goodies/?
+}

google-breakpad/depot-tools-git/depot-tools-git.install

@@ -0,0 +1,15 @@
+post_install() {
+	cat <<- EOF
+	depot_tools is installed in /opt/depot_tools/.
+	This directory is not in \$PATH by default, so make sure to export PATH=/opt/depot_tools:\$PATH before using it.
+	Also, this directory has root permissions, so either use it as root, or if you want to use it as your currect user:
+
+	# groupadd depot_tools
+	# gpasswd -a \$(whoami) depot_tools
+	# setfacl -m g:depot_tools:rwX /opt/depot_tools/
+
+	Then re-login as your current user or log your terminal in to the newly created group:
+
+	$ newgrp depot_tools
+	EOF
+}

google-breakpad/google-breakpad-git/.SRCINFO

@@ -0,0 +1,16 @@
+pkgbase = google-breakpad-git
+	pkgdesc = An open-source multi-platform crash reporting system
+	pkgver = r1668.072f86ca
+	pkgrel = 1
+	url = https://chromium.googlesource.com/breakpad/breakpad/
+	arch = i686
+	arch = x86_64
+	arch = armv7h
+	license = BSD
+	makedepends = depot-tools-git
+	conflicts = google-breakpad-svn
+	options = staticlibs
+	options = !strip
+
+pkgname = google-breakpad-git
+

google-breakpad/google-breakpad-git/.gitignore

@@ -0,0 +1,4 @@
+src
+pkg
+*.pkg.tar.xz
+

google-breakpad/google-breakpad-git/PKGBUILD

@@ -0,0 +1,46 @@
+# Maintainer: Lars Hagström <lars@foldspace.nu>
+# Contributor: Nephyrin Zey <nephyrin@doublezen.net>
+# Contributor: John Schoenick <john@pointysoftware.net>
+# Contributor: Geoffrey Teale <tealeg@googlemail.com>
+pkgname=google-breakpad-git
+pkgver=r1668.072f86ca
+pkgrel=1
+pkgdesc="An open-source multi-platform crash reporting system"
+arch=('i686' 'x86_64' 'armv7h')
+url="https://chromium.googlesource.com/breakpad/breakpad/"
+license=('BSD')
+makedepends=('depot-tools-git')
+depends=()
+options=('staticlibs' '!strip')
+conflicts=('google-breakpad-svn')
+
+prepare() {
+  #remove any old source lying around, since I don't want to learn depot tools
+  if [ -d "$srcdir/${pkgname}" ]; then
+    rm -rf "$srcdir/${pkgname}"
+  fi
+
+  mkdir -p "$srcdir/${pkgname}"
+  cd "$srcdir/${pkgname}"
+  /opt/depot_tools/fetch breakpad
+}
+
+pkgver() {
+  cd "$srcdir/${pkgname}/src"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "$srcdir/${pkgname}/src"
+
+  msg2 "Configuring"
+  ./configure --prefix=/usr
+  msg2 "Building"
+  make
+}
+
+package() {
+  cd "$srcdir/${pkgname}/src"
+  make DESTDIR="$pkgdir" install
+  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
+}