Update pidgin

pidgin/pidgin-light/.SRCINFO

@@ -0,0 +1,40 @@
+pkgbase = pidgin-light
+	pkgdesc = A light pidgin version: msn, jabber, irc supported protocols without gstreamer, tcl, tk, xscreensaver support.No video/voice. Includes finch
+	pkgver = 2.14.1
+	pkgrel = 1
+	url = http://pidgin.im/
+	install = pidgin-light.install
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = ca-certificates
+	makedepends = perl-xml-parser
+	makedepends = intltool
+	makedepends = pkg-config
+	depends = startup-notification
+	depends = libidn
+	depends = nss
+	depends = python
+	depends = gtkspell
+	depends = hicolor-icon-theme
+	depends = libxml2
+	depends = gtk-update-icon-cache
+	optdepends = dbus-python: needed for purple-remote & purple-url-handler only
+	optdepends = gstreamer0.10-good: sound
+	provides = pidgin
+	provides = finch
+	provides = libpurple
+	conflicts = pidgin
+	conflicts = pidgin-msn
+	conflicts = pidin-light-msn
+	conflicts = finch
+	conflicts = libpurple
+	replaces = gaim
+	options = !libtool
+	source = http://downloads.sourceforge.net/project/pidgin/Pidgin/2.14.1/pidgin-2.14.1.tar.bz2
+	source = anti-flood.patch
+	sha256sums = f132e18d551117d9e46acce29ba4f40892a86746c366999166a3862b51060780
+	sha256sums = 0b792053434d686131d090e77fb1d6e0e1739c7feb0e8c277bda575adc24f16a
+
+pkgname = pidgin-light
+

pidgin/pidgin-light/PKGBUILD

@@ -0,0 +1,65 @@
+# Maintainer: Nissar Chababy <funilrys at outlook dot com>
+# Ex-Maintainer: Yaron de Leeuw < me@jarondl.net >
+# Maintained at : https://github.com/funilrys/PKGBUILD/tree/master/pidgin-light
+# Lately maintained at : https://github.com/jarondl/aur-pkgbuilds-jarondl
+# Contributor: J. W. Birdsong <jwbirdsong AT gmail DOT com>
+# Contributor: Frikilinux <frikilinux at frikilinux.com.ar>
+# Contributor: Adriano Foschi <adriano.src gmail com>
+# Contributor: Ismael Carnales <icarnales@gamail.com>
+# Contributor: Ian Chou <forendef2846 at gmail dot com>
+
+pkgname=pidgin-light
+pkgver=2.14.1
+pkgrel=1
+pkgdesc="A light pidgin version: msn, jabber, irc supported protocols without gstreamer, tcl, tk, xscreensaver support.No video/voice.  Includes finch "
+arch=('i686' 'x86_64')
+url="http://pidgin.im/"
+license=('GPL')
+depends=('nss' 'python' 'hicolor-icon-theme' 'libxml2' 'gtk-update-icon-cache')
+makedepends=('ca-certificates' 'perl-xml-parser' 'intltool' 'pkg-config')
+optdepends=('dbus-python: needed for purple-remote & purple-url-handler only' 'gstreamer0.10-good: sound')
+replaces=('gaim')
+provides=('pidgin' 'finch' 'libpurple')
+conflicts=('pidgin' 'pidgin-msn' 'pidin-light-msn' 'finch' 'libpurple')
+options=('!libtool')
+install='pidgin-light.install'
+source=("http://downloads.sourceforge.net/project/pidgin/Pidgin/${pkgver}/pidgin-${pkgver}.tar.bz2"
+        'anti-flood.patch' 'ru.patch')
+
+sha256sums=('f132e18d551117d9e46acce29ba4f40892a86746c366999166a3862b51060780'
+            '0b792053434d686131d090e77fb1d6e0e1739c7feb0e8c277bda575adc24f16a'
+            'SKIP')
+
+prepare() {
+  cd "$srcdir/pidgin-$pkgver"
+  patch -p0 < ../anti-flood.patch
+  patch -p1 < ../ru.patch
+}
+
+build() {
+
+    cd "$srcdir/pidgin-$pkgver"
+
+    # Pidgin doesn't explicitly link to libm
+    LDFLAGS+=' -Wl,--copy-dt-needed-entries'
+
+    ./configure --prefix=/usr --sysconfdir=/etc --disable-schemas-install\
+    --disable-meanwhile --disable-screensaver --disable-nm\
+    --disable-gnutls --disable-doxygen --disable-tcl --disable-tk --disable-vv\
+    --disable-avahi --disable-gstreamer\
+    --disable-perl --disable-gtkspell --disable-gestures \
+    --disable-consoleui --disable-gstreamer --disable-idn --disable-mono \
+    --with-dynamic-prpls=jabber,irc \
+    --disable-farstream --with-system-ssl-certs=/etc/ssl/certs      
+    
+    make
+}
+package() {
+cd "$srcdir/pidgin-$pkgver"
+   make DESTDIR="$pkgdir" install
+
+# Remove GConf schema file
+  rm -rf "$pkgdir/etc"
+}
+
+# vim:set ts=2 sw=2 et:

pidgin/pidgin-light/anti-flood.patch

@@ -0,0 +1,10 @@
+--- libpurple/protocols/irc/irc.c	2016-06-03 01:44:50.000000000 +0800
++++ libpurple/protocols/irc/irc.c	2017-08-10 02:33:41.704448371 +0800
+@@ -744,6 +744,7 @@
+ 	struct irc_conn *irc = gc->proto_data;
+ 	const char *args[2];
+ 
++	g_usleep(500000);
+ 	args[0] = g_hash_table_lookup(data, "channel");
+ 	args[1] = g_hash_table_lookup(data, "password");
+ 	irc_cmd_join(irc, "join", NULL, args);

pidgin/pidgin-light/pidgin-light.install

@@ -0,0 +1,12 @@
+post_install() {
+  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}
+

pidgin/pidgin-light/ru.patch

@@ -0,0 +1,20 @@
+diff -cr src/pidgin-2.14.1/po/ru.po src/pidgin-2.14.1/po/ru.po
+*** a/po/ru.po	2020-06-10 06:13:22.000000000 +0300
+--- b/po/ru.po	2022-07-16 22:02:44.899899038 +0300
+***************
+*** 9090,9096 ****
+  
+  #. Accounts menu
+  msgid "/_Accounts"
+! msgstr "/_Уч.записи"
+  
+  msgid "/Accounts/Manage Accounts"
+  msgstr "/Уч.записи/Управление учётными записями"
+--- 9090,9096 ----
+  
+  #. Accounts menu
+  msgid "/_Accounts"
+! msgstr "Профили"
+  
+  msgid "/Accounts/Manage Accounts"
+  msgstr "/Уч.записи/Управление учётными записями"

pidgin/purple-discord-git/.SRCINFO

@@ -0,0 +1,22 @@
+# Generated by mksrcinfo(replacement shim) v8
+# Thu Nov 18 04:58:44 PM PST 2021
+pkgbase = purple-discord-git
+	pkgdesc = A libpurple/Pidgin plugin for Discord.
+	pkgver = v0.0.r757.99bdf6f
+	pkgrel = 1
+	url = https://github.com/EionRobb/purple-discord
+	arch = any
+	license = GPL3
+	makedepends = git
+	makedepends = imagemagick
+	makedepends = librsvg
+	makedepends = gettext
+	depends = libpurple
+	depends = json-glib
+	provides = purple-discord
+	conflicts = purple-discord
+	replaces = purple-discord
+	source = purple-discord::git+https://github.com/EionRobb/purple-discord.git
+	sha512sums = SKIP
+
+pkgname = purple-discord-git

pidgin/purple-discord-git/PKGBUILD

@@ -0,0 +1,37 @@
+# Maintainer: Malah <malah@neuf.fr>
+# Contributor: kaptoxic
+
+pkgname=purple-discord-git
+_pkgname=purple-discord
+pkgver=v0.0.r835.5502309b
+_pkgver=v0.0.
+pkgrel=1
+pkgdesc="A libpurple/Pidgin plugin for Discord."
+url='https://github.com/EionRobb/purple-discord'
+arch=(any)
+license=('GPL3')
+makedepends=('git' 'imagemagick' 'librsvg' 'gettext')
+depends=('libpurple' 'json-glib')
+replaces=('purple-discord')
+provides=('purple-discord')
+conflicts=('purple-discord')
+source=('purple-discord::git+https://github.com/EionRobb/purple-discord.git')
+sha512sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/${_pkgname}/"
+  printf "${_pkgver}r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "$srcdir/${_pkgname}/"
+  make
+}
+
+package() {
+  cd "$srcdir/${_pkgname}/"
+  make DESTDIR="$pkgdir" install
+  #installing license
+  install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}
+

pidgin/purple-gowhatsapp-git/.SRCINFO

@@ -0,0 +1,22 @@
+# Generated by mksrcinfo(replacement shim) v8
+# Fri Mar  4 08:30:29 AM PST 2022
+pkgbase = purple-gowhatsapp-git
+	pkgdesc = A libpurple/Pidgin plugin for WhatsApp, powered by whatsmeow
+	pkgver = 1.0.0r113_
+	pkgrel = 1
+	url = https://github.com/hoehermann/purple-gowhatsapp
+	arch = x86_64
+	arch = i686
+	license = GPLv3
+	makedepends = git
+	makedepends = go
+	makedepends = cmake
+	makedepends = make
+	makedepends = pkg-config
+	depends = libpurple
+	provides = purple-gowhatsapp
+	conflicts = purple-gowhatsapp
+	source = purple-gowhatsapp::git+https://github.com/hoehermann/purple-gowhatsapp.git#branch=whatsmeow
+	sha256sums = SKIP
+
+pkgname = purple-gowhatsapp-git

pidgin/purple-gowhatsapp-git/PKGBUILD

@@ -0,0 +1,38 @@
+# Maintainer: Hermann Höhne <hoehermann@gmx.de>
+# Contributor: GI_Jack <GI_Jack@hackermail.com>
+
+pkgname=purple-gowhatsapp-git
+pkgnam=${pkgname%-git}
+pkgver=1.5.0r145_
+pkgrel=1
+pkgdesc="A libpurple/Pidgin plugin for WhatsApp, powered by whatsmeow"
+arch=('x86_64' 'i686')
+url="https://github.com/hoehermann/purple-gowhatsapp"
+license=('GPLv3')
+groups=()
+depends=('libpurple')
+makedepends=('git' 'go' 'cmake' 'make' 'pkg-config')
+provides=("${pkgnam}")
+conflicts=("${pkgnam}")
+install=
+source=("${pkgnam}::git+https://github.com/hoehermann/purple-gowhatsapp.git#branch=whatsmeow")
+noextract=()
+sha256sums=('SKIP')
+
+pkgver() {
+  export GOPATH="$srcdir/${pkgnam}/build/src/go/go"
+  cd "$srcdir/${pkgnam}"
+  bash version.sh "$srcdir/${pkgnam}/build"
+}
+
+build() {
+  mkdir -p "$srcdir/${pkgnam}/build"
+  cd "$srcdir/${pkgnam}/build"
+  cmake -G "Unix Makefiles" ..
+  cmake --build .
+}
+
+package() {
+  cd "${srcdir}/${pkgnam}/build"
+  make DESTDIR="$pkgdir/" install/strip
+}

pidgin/purple-hangouts-hg/.SRCINFO

@@ -1,18 +0,0 @@
-pkgbase = purple-hangouts-hg
-	pkgdesc = A Pidgin plugin to support the proprietary protocol used by Google for the Hangouts service.
-	pkgver = r265.d6eb7fe69b1b
-	pkgrel = 1
-	url = https://bitbucket.org/EionRobb/purple-hangouts
-	arch = i686
-	arch = x86_64
-	arch = armv6h
-	license = unknown
-	makedepends = mercurial
-	depends = libpurple
-	depends = glib2
-	depends = json-glib
-	source = purple-hangouts::hg+https://bitbucket.org/EionRobb/purple-hangouts
-	md5sums = SKIP
-
-pkgname = purple-hangouts-hg
-

pidgin/purple-hangouts-hg/PKGBUILD

@@ -1,35 +0,0 @@
-pkgname=purple-hangouts-hg
-srcname=purple-hangouts
-pkgdesc='A Pidgin plugin to support the proprietary protocol used by Google for the Hangouts service.'
-url='https://bitbucket.org/EionRobb/purple-hangouts'
-arch=('i686' 'x86_64' 'armv6h')
-pkgver=r353.65f3f51d8faf
-pkgrel=1
-license=('unknown')
-depends=('libpurple' 'glib2' 'json-glib')
-makedepends=('mercurial')
-source=('purple-hangouts::hg+https://bitbucket.org/EionRobb/purple-hangouts')
-md5sums=('SKIP')
-
-pkgver() {
-	cd $srcdir/$srcname
-	printf "r%s.%s" "$(hg identify -n)" "$(hg identify -i)"
-}
-
-build() {
-	cd $srcdir/$srcname
-	make
-}
-
-package() {
-	cd $srcdir/$srcname
-	destdir=$pkgdir$(pkg-config --variable plugindir purple)
-	install -Dm755 -t $destdir libhangouts.so
-
-	icondir=$pkgdir/usr/share/pixmaps/pidgin/protocols
-	echo $icondir
-
-	for size in 16 22 24 48; do
-		install -TDm644 $srcdir/$srcname/hangouts$size.png $icondir/$size/hangouts.png
-	done
-}

pidgin/purple-skypeweb-git/.gitignore

@@ -0,0 +1,15 @@
+# ignore everything
+*
+!.gitignore
+
+# except PKGBUILD needed files
+!PKGBUILD
+!.SCRINFO
+!*.install
+!ChangeLog
+
+# common wing-man files
+!*.diff
+!*.patch
+
+# add files that don't have an online source

pidgin/purple-skypeweb-git/PKGBUILD

@@ -0,0 +1,35 @@
+# Maintainer : Colin Arnott <arnottcr@gmail.com>
+# Maintainer : Björn Bidar <bjorn.bidar@thaodan.de>
+# Contributer : Jo De Boeck <deboeck.jo@gmail.com>
+
+pkgname=purple-skypeweb-git
+pkgver=1.7.r18.g8b29d7b3
+pkgrel=1
+arch=('x86_64')
+license=('GPL3')
+pkgdesc="SkypeWeb Plugin for Pidgin"
+url="https://github.com/EionRobb/skype4pidgin/tree/master/skypeweb"
+depends=('json-glib')
+makedepends=('git' 'cmake')
+conflicts=('purple-skypeweb' 'skype4pidgin')
+provides=('purple-skypeweb')
+
+source=("$pkgname"::'git+https://github.com/EionRobb/skype4pidgin')
+md5sums=('SKIP')
+
+pkgver() {
+    cd "$srcdir/$pkgname"
+    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+    cmake -B build -S "$srcdir/$pkgname/skypeweb" \
+        -DCMAKE_BUILD_TYPE='None' \
+        -DCMAKE_INSTALL_PREFIX='/usr' \
+        -Wno-dev
+    cmake --build build
+}
+
+package() {
+    DESTDIR="$pkgdir" cmake --install build
+}

pidgin/telegram-purple/.SRCINFO

@@ -0,0 +1,20 @@
+pkgbase = telegram-purple
+	pkgdesc = Adds support for Telegram to Pidgin, Adium, Finch and other Libpurple based messengers.
+	pkgver = 1.4.7
+	pkgrel = 1
+	url = https://github.com/majn/telegram-purple
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	depends = glib2
+	depends = libgcrypt>=1.6.0
+	depends = libpurple
+	depends = zlib
+	depends = libwebp
+	conflicts = telegram-purple-git
+	source = https://github.com/majn/telegram-purple/releases/download/v1.4.7/telegram-purple_1.4.7.orig.tar.gz
+	sha256sums = daf826471cebaab88e7f1f586ee1ab9db664b6c02867998fe339144ccbc7c769
+
+pkgname = telegram-purple
+

pidgin/telegram-purple/PKGBUILD

@@ -0,0 +1,25 @@
+# Maintainer: Zhuoyun Wei <wzyboy@wzyboy.org>
+
+pkgname=telegram-purple
+pkgver=1.4.7
+pkgrel=1
+pkgdesc="Adds support for Telegram to Pidgin, Adium, Finch and other Libpurple based messengers."
+arch=('i686' 'x86_64')
+url="https://github.com/majn/telegram-purple"
+license=("GPL")
+makedepends=("git")
+depends=('glib2' 'libgcrypt>=1.6.0' 'libpurple' 'zlib' 'libwebp')
+conflicts=('telegram-purple-git')
+source=("https://github.com/majn/${pkgname}/releases/download/v${pkgver}/telegram-purple_${pkgver}.orig.tar.gz")
+sha256sums=('daf826471cebaab88e7f1f586ee1ab9db664b6c02867998fe339144ccbc7c769')
+
+build() {
+  cd "${srcdir}/${pkgname}"
+  ./configure --prefix=/usr CFLAGS="$CFLAGS -w"
+  make
+}
+
+package() {
+  cd "${srcdir}/${pkgname}"
+  make DESTDIR="$pkgdir" install
+}